Сохранить переменную после endlocal в партии

Question

У меня есть структура папок, которая похожа, например, на C: \ Temp \, там много папок и файлов, и внутри каждой папки есть «callme.bat». Я хотел бы создать так называемый main.bat, который один за другим вызывает файлы callme в главном окне. Но есть проблема, в файлах callme есть некоторое эхо, которое содержит "!" отметьте, что создает для меня проблему.

Я понял проблему с комбо setlocal-endlocal, потому что пакетный скрипт хочет интерпретировать сообщение внутри "!" метки, поэтому я должен использовать endlocal, но если я это сделал, я не смог запустить летучие мыши callme.

callme.bat

@echo off
echo !!! hidden message !!! not hidden message
pause

---

main.bat вариант 1

@echo off
setlocal enabledelayedexpansion

set PATH=C:\Temp
for /F %%x in ('dir /B/A:D %PATH%') do (
    set CURR_DIR=%PATH%\%%x
    set ACTUAL_BATCH=!CURR_DIR!\callme.bat
    echo !ACTUAL_BATCH!

    call !ACTUAL_BATCH!
    pause
)
pause
exit

---

main.bat вариант 2

@echo off
set PATH=C:\Temp
for /F %%x in ('dir /B/A:D %PATH%') do (
    setlocal enabledelayedexpansion

    set CURR_DIR=%PATH%\%%x
    set ACTUAL_BATCH=!CURR_DIR!\callme.bat
    echo !ACTUAL_BATCH!

    ENDLOCAL & SET VAR=!ACTUAL_BATCH!
    echo %VAR%
    pause
)
pause
exit

---

main.bat вариант 3

@echo off
set PATH=C:\Temp
for /F %%x in ('dir /B/A:D %PATH%') do (
    setlocal enabledelayedexpansion

    set CURR_DIR=%PATH%\%%x
    set ACTUAL_BATCH=!CURR_DIR!\callme.bat
    echo !ACTUAL_BATCH!

    REM source: /3390967/zastavte-peremennuy-okruzheniya-vyzhit-endlocal
    for /f "delims=" %%A in (""!ACTUAL_BATCH!"") do endlocal & set "VAR=%%~A"
    echo %VAR%

    call %VAR%
    pause
)
pause
exit

Так что я не знаю, что делать. У кого-нибудь есть идея?

выход варианта 1:

C:\Temp\1\callme.bat
 not hidden message
C:\Temp\2\callme.bat
 not hidden message

выход варианта 2-3:

C:\Temp\1\callme.bat
ECHO is off.
C:\Temp\2\callme.bat
ECHO is off.

Answer 1

Некоторые замечания по поводу вашего кода:

1. Никогда не используйте PATH в качестве имени переменной, так как оно уничтожает переменную PATH для поиска исполняемых файлов.

2. Используйте расширенный синтаксис SET set "varname=content", чтобы избежать проблем с пробелами.

3. Вам нужно только отключить режим отложенного расширения, используя setlocal DisableDelayedExpansion

@echo off
setlocal EnableDelayedExpansion

set MY_PATH=C:\Temp
for /F %%x in ('dir /B/A:D %PATH%') do (
    set "CURR_DIR=%MY_PATH%\%%x"
    set "ACTUAL_BATCH=!CURR_DIR!\callme.bat"

    call :execute ACTUAL_BATCH
    pause
)
pause
exit /b

:execute ACTUAL_BATCH
set "batFile=!%~1!"
echo Calling !batFile!

setlocal DisableDelayedExpansion
call %batFile%
endlocal

exit /b

Answer 2

TL; DR

ENDLOCAL&set "varname=%sourcevarname%"

возможно, где varname - это имя переменной, которую нужно установить, а sourcevarname - это переменная, значение которой должно быть присвоено varname - и они CAN могут быть одинаковыми, даже если оператор выглядит логически нулевым - он экспортирует переменную из блока setlocal/endlocal.

Ключевой момент: ДОЛЖЕН быть на одной физической линии и может повторяться при необходимости (например,

 ENDLOCAL&set "varname=%sourcevarname%"&set "varname2=%sourcevarname2%"

So

 ENDLOCAL&set "fred=%fred%"&set "bill=%george%"

совершенно допустимо, чтобы установить значение fred вне скобки setlocal / endlocal равным его окончательному значению внутри и bill снаружи конечному значению george внутри.