Приостановка кода VBS до завершения сценария оболочки - PullRequest
Новая
       18

Приостановка кода VBS до завершения сценария оболочки

0 голосов
/ 22 марта 2019

Я пытаюсь создать скрипт, который будет автоматически устанавливать принтер. Я нашел некоторый код, который я изменил, чтобы дать пользователю некоторые подсказки. Я думаю, что оригинал был командным файлом. Для запуска команды cscript необходимо выполнить 4 процесса. Это те, которые мне нужно сделать, пока они не закончили. Я думал, что параметр WaitOnReturn в команде оболочки заставил бы их ждать, но я не пометил их в коде надписью «Нужно ждать здесь ...»
Вот код 

Dim fso
Dim Folder
Dim ProgramPath
Dim WshShell
Dim ProgramArgs
Dim WaitOnReturn
Dim intWindowStyle

'Dim objShell
'strInput = UserInput( "Enter some input:" )
strInput = MsgBox("This will install the default HP Print driver?",1,"Windows 7 Print Driver Install")
'WScript.Echo "You entered: " & strIpAddress
If strInput = 2 Then
    WScript.Echo "Please run again when you are ready"
Else '=1 Prompt for IP Address
    'WScript.Echo "You entered: " & strInput
    strIpCheck = MsgBox("Do you have the Printers IP Address?",1,"Choose options")
    If strIpCheck = 2 Then 'Does not have IP Address
        WScript.Echo "Please run again when have the IP Address"
    Else 'Start install routine
        strIpAddress = InputBox("Enter the IP Address", "IP Address")
        Set WshShell = CreateObject("WScript.Shell")
        'Create directories
        Set FSO = CreateObject("Scripting.FileSystemObject")
        If NOT (fso.FolderExists("C:\DRIVERS")) Then
            fso.CreateFolder("C:\DRIVERS")
        End If
        If NOT (fso.FolderExists("C:\SCRIPTS")) Then
            fso.CreateFolder("C:\SCRIPTS")
        End If
        'Location of Windows 7 HP print drivers
        strSourceDriver = "C:\Windows\System32\DriverStore\FileRepository\hpoa1so.inf_amd64_neutral_4f1a3f1015001339"
        'Location of Win7 built in printer scripts
        strSourceScripts = "C:\Windows\System32\Printing_Admin_Scripts\en-US"
        If (fso.FolderExists(strSourceDriver)) Then
            fso.copyFolder strSourceDriver, "C:\DRIVERS"
        End If
        If (fso.FolderExists(strSourceScripts)) Then
            fso.copyFolder strSourceScripts, "C:\SCRIPTS"
        End If
    'Delete existing printer named HP Printer   
    ProgramPath = "C:\SCRIPTS\prnmngr.vbs"
    ProgramArgs = "-d -p " & Chr(34) & "HP Printer" & Chr(34) & ""
    intWindowStyle = 1
    WaitOnReturn = true
    WshShell.Run "cscript.exe " & Chr(34) & ProgramPath & Chr(34) & Space(1) & ProgramArgs, intWindowStyle, WaitOnReturn
'Need to wait here until the above shell process is done
    ProgramPath = "C:\SCRIPTS\Prnport.vbs"
    ProgramArgs = "-a -r " &  strIpAddress & "Port -h " & strIpAddress & " -o raw -n 9100"
    intWindowStyle = 1
    WaitOnReturn = true
    WshShell.Run "cscript.exe " & Chr(34) & ProgramPath & Chr(34) & Space(1) & ProgramArgs, intWindowStyle, WaitOnReturn
'Need to wait here until the above shell process is done
    ProgramPath = "C:\SCRIPTS\Prndrvr.vbs"
    ProgramArgs = "-a -m " & Chr(34) & "HP Photosmart C8100" & Chr(34) & "-i C:\DRIVERS\hpoa1so.inf -h C:\DRIVERS"
    intWindowStyle = 1
    WaitOnReturn = true
    WshShell.Run "cscript.exe " & Chr(34) & ProgramPath & Chr(34) & Space(1) & ProgramArgs, intWindowStyle, WaitOnReturn    
'Need to wait here until the above shell process is done    
    ProgramPath = "C:\SCRIPTS\Prnmngr.vbs"
    ProgramArgs = "-a -p " & Chr(34) & "HP Printer" & Chr(34) & "-m" & Chr(34) & "HP Photosmart C8100" & Chr(34) & "-r " &  strIpAddress
    intWindowStyle = 1
    WaitOnReturn = true
    WshShell.Run "cscript.exe " & Chr(34) & ProgramPath & Chr(34) & Space(1) & ProgramArgs, intWindowStyle, WaitOnReturn    
'Need to wait here until the above shell process is done
    End If
End If

1 Ответ

0 голосов
/ 22 марта 2019

Все WshShell.Run "cscript.exe " & …, intWindowStyle, WaitOnReturn должны подождать, пока вызванный процесс оболочки завершится, предоставив WaitOnReturn = true.Однако выходные данные из следующего упрощенного сценария (где назначения ProgramArgs равны Скопировано & Вставлено из исходного кода) показывают некоторые пропущенные пробелы в предоставленных параметрах: 

strIpAddress = "10.10.10.10"

ProgramArgs = "-d -p " & Chr(34) & "HP Printer" & Chr(34) & ""
Wscript.Echo ProgramArgs
ProgramArgs = "-a -r " &  strIpAddress & "Port -h " & strIpAddress & " -o raw -n 9100"
Wscript.Echo ProgramArgs
ProgramArgs = "-a -m " & Chr(34) & "HP Photosmart C8100" & Chr(34) & "-i C:\DRIVERS\hpoa1so.inf -h C:\DRIVERS"
Wscript.Echo ProgramArgs
ProgramArgs = "-a -p " & Chr(34) & "HP Printer" & Chr(34) & "-m" & Chr(34) & "HP Photosmart C8100" & Chr(34) & "-r " &  strIpAddress
Wscript.Echo ProgramArgs

Выходные данные: cscript D:\bat\SO\55303301.vbs

-d -p "HP Printer"
-a -r 10.10.10.10Port -h 10.10.10.10 -o raw -n 9100
-a -m "HP Photosmart C8100"-i C:\DRIVERS\hpoa1so.inf -h C:\DRIVERS
-a -p "HP Printer"-m"HP Photosmart C8100"-r 10.10.10.10

Более того, метод Run возвращает целое число .Вы можете получить код возврата процесса в переменную RetCode и затем проверить, равно ли его значение нулю (когда все прошло нормально), используя 

RetCode = WshShell.Run ( "cscript.exe " & _
        Chr(34) & ProgramPath & Chr(34) & Space(1) & ProgramArgs _
  , intWindowStyle, WaitOnReturn )
...