Найти конкретную подстроку с помощью Transact-SQL

Question

Мне нужно вытащить определенную подстроку из строки вида:

foo=abc;bar=def;baz=ghi

Например, как я могу получить значение "bar" из этой строки?

Answer 1

У меня есть обобщенное решение, которое работает для этой проблемы:

CREATE FUNCTION [dbo].[fn_StringBetween]
(
    @BaseString varchar(max),
    @StringDelim1 varchar(max),
    @StringDelim2 varchar(max)
)
RETURNS varchar(max)
AS
BEGIN
    DECLARE @at1 int
    DECLARE @at2 int
    DECLARE @rtrn varchar(max)

    SET @at1 = CHARINDEX(@StringDelim1, @BaseString)
    IF @at1 > 0
    BEGIN
        SET @rtrn = SUBSTRING(@BaseString, @at1
         + LEN(@StringDelim1), LEN(@BaseString) - @at1)
        SET @at2 = CHARINDEX(@StringDelim2, @rtrn)
        IF @at2 > 0
            SET @rtrn = LEFT(@rtrn, @at2 - 1)
    END

    RETURN @rtrn
END

поэтому, если вы запустите (просто оберните исходную строку для поиска с помощью ';' в начале и в конце):

PRINT dbo.fn_StringBetween(';foo=abc;bar=def;baz=ghi;', ';bar=', ';')

вы получите 'def'.

Answer 2

Вы можете использовать charindex и подстрока .Например, чтобы найти значение «baz»:

declare @str varchar(128)
set @str = 'foo=abc;bar=def;baz=ghi'

-- Make sure @str starts and ends with a ;
set @str = ';' + @str + ';'

select substring(@str, 
    charindex(';baz=',@str) + len(';baz='),
    charindex('=',@str,charindex(';baz=',@str)) - charindex(';baz=',@str) - 1)

или значение «foo» в начале строки:

select substring(@str, 
    charindex(';foo=',@str) + len(';foo='),
    charindex('=',@str,charindex(';foo=',@str)) - charindex(';foo=',@str) - 1)

Вот UDF дляВыполните это (более читаемая версия, вдохновленная ответом BlackTigerX):

create function dbo.FindValueInString(
    @search varchar(256),
    @name varchar(30))
returns varchar(30)
as
begin
    declare @name_start int
    declare @name_length int
    declare @value_start int
    declare @value_end int

    set @search = ';' + @search

    set @name_start = charindex(';' + @name + '=',@search)
    if @name_start = 0
        return NULL

    set @name_length = len(';' + @name + '=')
    set @value_start = @name_start + @name_length
    set @value_end = charindex(';', @search, @value_start)

    return substring(@search, @value_start, @value_end - @value_start)
end

Как вы можете видеть, это не так просто в Sql Server :) Лучше сделать это на языке клиента или нормализовать базу данных, чтобыподстроки идут в своих собственных столбцах.

Answer 3

Этого можно добиться простым способом

DECLARE  @str VARCHAR(30)

DECLARE  @start INT

SET @str='foo=abc;bar=def;baz=ghi'

SET @start=CHARINDEX('bar',@str)

PRINT SUBSTRING(@str,@start,3)

Answer 4

это предполагает, что строка будет иметь такой же формат строки, просто замените имя столбца на 'foo = abc; bar = def; baz = ghi'

select substring('foo=abc;bar=def;baz=ghi',patindex('%bar=%','foo=abc;bar=def;baz=ghi')+4, len('foo=abc;bar=def;baz=ghi')-patindex('%;baz=%','foo=abc;bar=def;baz=ghi')-4)

Answer 5

Вы можете использовать эту функцию

alter function FindValue(@txt varchar(200), @find varchar(200)) 
returns varchar(200)
as
begin
declare 
    @firstPos int,
    @lastPos int

select @firstPos = charindex(@find, @txt), @lastPos = charindex(';', @txt, @firstPos+5)

select @lastPos = len(@txt)+1 where @lastPos = 0

return substring(@txt, @firstPos+len(@find)+1, @lastPos-@firstPos-len(@find)-1)
end


select dbo.FindValue('foo=abc;bar=def;baz=ghi', 'bar')

обновление: не использовалась длина @ find

Answer 6

посмотрите в функцию PATINDEX. У него есть сопоставление с подстановочными знаками, которое должно вам помочь.