Как вы можете определить пользовательские кварталы в формуле без вспомогательных столбцов? - PullRequest
Новая
       24

Как вы можете определить пользовательские кварталы в формуле без вспомогательных столбцов?

0 голосов
/ 29 апреля 2019

Я пытаюсь подсчитать, сколько еще осталось закрыть с точки зрения бизнеса в текущем квартале.

Для этого мне нужно определить, где мы находимся в квартале, сколько было закрыто и сколько осталось до конца квартала.

Проблема в том, что наш финансовый год начинается 1 февраля и заканчивается 31 января -

Я попробовал эту формулу, но в моем случае это не сработает.

=ROUNDUP(MONTH(*reference or date*)/3;0)

Есть мысли о том, как я могу обойти это?Кроме того, как я могу определить, где в квартале мы должны рассчитать квоту для Q минус QTD?

Ответы [ 2 ]

0 голосов
/ 30 апреля 2019

Стандартная формула 

=int((month(A2)+2)/3)

Таким образом, скорректированная формула (в B2) будет получена, если вернуться на один месяц назад: 

=int((month(eomonth(A2,-1))+2)/3)

Конец квартала задается умножением квартала на 3 для получения месяца и переходом на один месяц вперед: 

=eomonth(date(year(A2),B2*3,1),1)

enter image description here

EDIT

Год для конца квартала января в C2 явно неверен - вы можете исправить это, поставив 

=eomonth(date(year(A2)-(month(A2)<2),B2*3,1),1)

enter image description here

0 голосов
/ 29 апреля 2019

наш финансовый год начинается 1 февраля и заканчивается 31 января 

="Q"&QUERY(DATE(YEAR(A1), MONTH(A1)-1, DAY(A1)), 
 "select quarter(Col1) label quarter(Col1)''")

0

рассчитать, сколько еще осталось закрыть с точки зрения бизнеса в текущем квартале 

=VLOOKUP(TODAY(), {DATE(YEAR(TODAY()),  2, 1), DATE(YEAR(TODAY()),  2+3, 1);
                   DATE(YEAR(TODAY()),  5, 1), DATE(YEAR(TODAY()),  5+3, 1);
                   DATE(YEAR(TODAY()),  8, 1), DATE(YEAR(TODAY()),  8+3, 1);
                   DATE(YEAR(TODAY()), 11, 1), DATE(YEAR(TODAY()), 11+3, 1)}, 2, 1)-
 DATEVALUE(TODAY())

0

...