Sparql находит объекты с типом dbo и сортирует их по количеству - PullRequest
Новая
       23

Sparql находит объекты с типом dbo и сортирует их по количеству

1 голос
/ 12 марта 2019

Мне нужно выполнить запрос sparql к конечной точке dbpedia, который должен:

  1. Найти все сущности, содержащие "вену" в label и "город" в abstract
  2. Отфильтруйте их, сохранив только те из них, которые имеют хотя бы один dbo rdf:type
  3. Сортировка результатов по количеству типов dbo (например, если у объекта 5 dbo rdf:type это должно быть показано перед сущностями с 4 dbo rdf:type)

Я сделал несколько попыток, ближайший к результату: 

select distinct (str(?s) as ?s) count(?t) as ?total where {{ ?s rdfs:label "vienna"@en. ?s rdf:type ?t.} 
UNION { ?s rdfs:label ?l. ?s rdf:type ?t . ?l <bif:contains> '("vienna")'
. FILTER EXISTS { ?s dbo:abstract ?cc. ?cc <bif:contains> '("city")'. FILTER(lang(?cc) = "en").}} 
FILTER (!strstarts(str(?s), str("http://dbpedia.org/resource/Category:")))
. FILTER (!strstarts(str(?s), str("http://dbpedia.org/property/")))
. FILTER (!strstarts(str(?s), str("http://dbpedia.org/ontology/")))
. FILTER (strstarts(str(?t), str("http://dbpedia.org/ontology/"))).} 
LIMIT 50

Что будет (неправильно) подсчитайте rdf:type перед тем, как его отфильтровать.Я не хочу считать rdf:type, которые не dbo (онтология).

1 Ответ

1 голос
/ 12 марта 2019

Идея состоит в том, чтобы использовать подзапрос, в котором вы ищете сущности, и выполнять подсчет во внешнем запросе: 

PREFIX  dbo:  <http://dbpedia.org/ontology/>
PREFIX  rdf:  <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX  rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT  ?s (count(*) AS ?cnt)
WHERE
  { { SELECT DISTINCT  ?s
      WHERE
        { ?s  rdfs:label      ?l .
          ?l  <bif:contains>  '"vienna"'
          FILTER langMatches(lang(?l), "en")
          FILTER EXISTS { ?s   dbo:abstract    ?cc .
                          ?cc  <bif:contains>  '"city"'
                          FILTER langMatches(lang(?cc), "en")
                        }
          ?s  rdf:type  ?t
          FILTER ( ! strstarts(str(?s), str("http://dbpedia.org/resource/Category:")) )
          FILTER ( ! strstarts(str(?s), str("http://dbpedia.org/property/")) )
          FILTER ( ! strstarts(str(?s), str(dbo:)) )
          FILTER strstarts(str(?t), str(dbo:))
        }
    }
    ?s  ?p  ?o
    FILTER strstarts(str(?p), str(dbo:))
  }
GROUP BY ?s
ORDER BY DESC(?cnt)
...