Можете ли вы иметь 2 разных временных диапазона в одном запросе? - PullRequest
Новая
       17

Можете ли вы иметь 2 разных временных диапазона в одном запросе?

1 голос
/ 04 апреля 2019

Я хочу выполнить следующий запрос: 

( requests
| where timestamp > ago(-24h)
| summarize day = avg(duration) 
)
| union ( requests
| where timestamp > ago(-10m)
| summarize now = avg(duration)
)

Я хочу получить среднюю продолжительность запроса за последний день и за последние 10 минут.Я делаю это сейчас в 2 разных запросах, но мне нравится иметь их в 1 запрос на производительность.

Когда я запускаю этот запрос, я не получаю ответа, вижу столбец "день" и "сейчас", но он не имеет значения.

1 Ответ

2 голосов
/ 04 апреля 2019

с точки зрения языка запросов, то, что вы делаете, является действительным и должно работать.

вам следует проверить, действительно ли вы собираетесь использовать знак минус (-) при вызове ago() function.

Если вы хотите получить результат в одной строке, вы также можете использовать join вместо union

print ago(24h), ago(-24h)

, которое будет выдавать: 

| print_0                     | print_1                     |
|-----------------------------|-----------------------------|
| 2019-04-03 15:04:24.0178923 | 2019-04-05 15:04:24.0178923 |

и: 

let requests = datatable(timestamp:datetime, duration:timespan)
[
    datetime(2019-03-03 14:00), 123s,
    datetime(2019-03-03 15:00), 12s,
    datetime(2019-04-03 16:00), 13s,
    datetime(2019-04-03 17:00), 456s,
    datetime(2019-04-03 18:00), 56s,
    datetime(2019-04-03 19:00), 45s,
    datetime(2019-04-03 20:00), 43s,
    datetime(2019-04-04 16:55), 77s,
]
;
requests
| where timestamp > ago(24h)
| summarize day = avg(duration) 
| union ( 
    requests
    | where timestamp > ago(10m)
    | summarize now = avg(duration)
)

выведет: 

| day      | now      |
|----------|----------|
| 00:01:55 |          |
|          | 00:01:17 |

и: 

let requests = datatable(timestamp:datetime, duration:timespan)
[
    datetime(2019-03-03 14:00), 123s,
    datetime(2019-03-03 15:00), 12s,
    datetime(2019-04-03 16:00), 13s,
    datetime(2019-04-03 17:00), 456s,
    datetime(2019-04-03 18:00), 56s,
    datetime(2019-04-03 19:00), 45s,
    datetime(2019-04-03 20:00), 43s,
    datetime(2019-04-04 16:55), 77s,
]
;
requests
| where timestamp > ago(24h)
| summarize day = avg(duration) by dummy = 1
| join kind=inner 
( 
    requests
    | where timestamp > ago(10m)
    | summarize now = avg(duration) by dummy = 1
) on dummy
| project day, now

выведет: 

| day      | now      |
|----------|----------|
| 00:01:55 | 00:01:17 |
...