SCILAB Добавление легенды в сюжет, созданный в цикле - PullRequest
Новая
       102

SCILAB Добавление легенды в сюжет, созданный в цикле

0 голосов
/ 23 марта 2019

Мне бы хотелось узнать, как добавить легенду в график, сгенерированный циклом в SciLab. Есть 4 цикла, и каждый цикл имеет свою легенду (и цвета).

Я попробовал код ниже. Тем не менее, дает мне 4 легенды, но с тем же цветом (в случае красного). 

inta=read("H_intacta_num.txt",-1,1500)
d1=read("H_dano1_num.txt",-1,1500)
d2=read("H_dano2_num.txt",-1,1500)
d3=read("H_dano3_num.txt",-1,1500)
leia1=read("Dados_MagN1.txt",-1,3);
frequ=leia1(:,1)

\\loop1 - red (label: healthy)
for i=48:94
    plot(frequ,inta(i,:),'r')
end

\\loop 2 - blue (label: Damaged_L1)
for j=48:94
    plot(frequ,d1(j,:),'b')
end

\\loop 3 - black (label: Damaged_L2)
for j=37:72
    plot(frequ,d2(j,:),'k')
end

\\loop 4 - ciano (label: Damaged_L3)
for j=36:70
    plot(frequ,d3(j,:),'c')
end

ylabel("Amplitude (m/s^2)/N")
xlabel("Frequency (Hz)")
p=legend(['Healthy';'Damaged_L1';'Damaged_L2';'Damaged_L3'],[2])

1 Ответ

1 голос
/ 24 марта 2019

Здесь legend рассмотрит первые 4 полилинии в стеке, следовательно, красные. Вы можете изменить ссылки таким образом (кстати, комментарий к строке // не \\) 

//loop1 - red (label: healthy)
for i=48:94
    plot(frequ,inta(i,:),'r')
end
h(1)=gce()

//loop 2 - blue (label: Damaged_L1)
for j=48:94
    plot(frequ,d1(j,:),'b')
end
h(2)=gce()

//loop 3 - black (label: Damaged_L2)
for j=37:72
    plot(frequ,d2(j,:),'k')
end
h(3)=gce()

//loop 4 - ciano (label: Damaged_L3)
for j=36:70
    plot(frequ,d3(j,:),'c')
end
h(4)=gce()

ylabel("Amplitude (m/s^2)/N")
xlabel("Frequency (Hz)")
p=legend(h, ['Healthy';'Damaged_L1';'Damaged_L2';'Damaged_L3'],[2])
...