Как включить DocLink в электронную почту MIME в Lotus Notes? - PullRequest
Новая
       19

Как включить DocLink в электронную почту MIME в Lotus Notes?

0 голосов
/ 13 мая 2019

Я хочу получить DocLink или значение ссылки о документе для включения в MIME электронное письмо с использованием LotusScript, но я не знаю, как это сделать.

У меня есть это: 

Sub Click(Source As Button)

    Dim s As New NotesSession 
    Dim db As NotesDatabase 
    Dim doc As NotesDocument
    Dim body As NotesMIMEEntity 
    Dim header As NotesMIMEHeader 
    Dim stream As NotesStream

    Set db = s.CurrentDatabase 
    Set stream = s.CreateStream 
    s.ConvertMIME = False

    Set doc = db.CreateDocument 
    doc.Form = "Memo"

    Set body = doc.CreateMIMEEntity 
    Set header = body.CreateHeader("Subject")

    Call header.SetHeaderVal("HTML message") 
    Set header = body.CreateHeader("To")
    Call header.SetHeaderVal("email_domain")

    Call stream.writetext(|<HTML>|) 
    Call stream.writetext(|<body>|) 
    user$ = s.CommonUserName 
    Call stream.writetext(|<br><font size="+5" color="red">| & user$ &|</font>|) 
    Call stream.WriteText(|<br><a href="notes:///server/etc/etc">Notes</a><br>|)    
    Call stream.writetext(|</body>|) 
    Call stream.writetext(|</html>|)

    Call body.SetContentFromText(stream, "text/HTML;charset=UTF-8", ENC_IDENTITY_7BIT) 
    Call doc.Send(False) 
    s.ConvertMIME = True 

End Sub

В этот код я могу включить теги <a></a> с URL-адресом Notes, но я действительно хочу создать ссылку на этот документ, например, используя AppendDocLink.

Возможно ли это?

1 Ответ

0 голосов
/ 14 мая 2019

Наконец-то я нашел решение с UniversalID. Я извлекаю этот ID документа и добавляю к URL, как это. 

Sub Click(Source As Button)

    Dim ws As New NotesUIWorkspace
    Dim s As New NotesSession 
    Dim db As NotesDatabase 
    Dim doc As NotesDocument
    Dim doc2 As NotesDocument
    Dim body As NotesMIMEEntity 
    Dim header As NotesMIMEHeader 
    Dim stream As NotesStream
    Dim urldoc As String

    Set doc2 = ws.CurrentDocument.Document

    Set db = s.CurrentDatabase 
    Set stream = s.CreateStream 
    s.ConvertMIME = False

    urldoc = doc2.UniversalID

    Set doc = db.CreateDocument 
    doc.Form = "Memo"

    Set body = doc.CreateMIMEEntity 
    Set header = body.CreateHeader("Subject")

    Call header.SetHeaderVal("HTML message") 
    Set header = body.CreateHeader("To")
    Call header.SetHeaderVal("email")

    Call stream.writetext(|<HTML>|) 
    Call stream.writetext(|<body>|) 
    user$ = s.CommonUserName 
    Call stream.writetext(|<br><font size="+5" color="red">| & user$ &|</font>|) 
    Call stream.WriteText(|<br><a href="Notes://Server/Replica/View/| & urldoc & |">Notes</a><br>|)
    Call stream.writetext(|</body>|) 
    Call stream.writetext(|</html>|)

    Call body.SetContentFromText(stream, "text/HTML;charset=UTF-8", ENC_IDENTITY_7BIT) 
    Call doc.Send(False) 
    s.ConvertMIME = True 

End Sub
...