Эрланг распределил обратную строку

Question

Я новичок в erlang, я не могу понять, как решить это упражнение.
Мне нужно перевернуть длинную строку, разбив ее на N подстрок, перевернуть отдельные подстроки и затем соединить их, чтобы получитьобратная сторона исходной строки.Каждая подстрока должна быть обращена другим процессом.

Мои проблемы:
1) Как разбить строку на N подстрок одинакового размера?
2) Как соединить строку, полученнуюдругие процессы?

Может кто-нибудь дать мне пример кода?Это то, что я сделал, но в нем отсутствуют основные части:

% This function should split the string, spawn the processes
% and recombine the results
reverse(Str, N) -> % ...

sub_reverse() ->
    receive
        { From, SubStr } -> From ! { self(), lists:reverse(SubStr) }
    end.

Answer 1

Попробуйте что-то вроде этого.

-module(stackoverflow).
-export([reverse/2, join/0, sub_reverse/2]).

reverse(Str, N) ->
    % A process joining the reversed substrings.
    JoinPID = spawn(stackoverflow, join, []),

    % The step size is the length of Str divided by N.
    % TODO Handle remainder.
    Step = string:length(Str) div N,

    % The split points are calculated from end to start of Str.
    SplitPoints = lists:seq(string:length(Str) - Step, 0, -Step),

    % For each split point, spwan a process that reverts the substring for the
    % split point.
    lists:foreach(fun(From) ->
                    Substr = string:slice(Str, From, Step),
                    spawn(stackoverflow, sub_reverse, [JoinPID, Substr])
                  end,
                  SplitPoints).

join() ->
    receive
        {reverse_str, ReverseStr} ->
            io:format("~s", [ReverseStr]),
            join()
    end.

sub_reverse(JoinPID, SubStr) ->
    JoinPID ! {reverse_str, lists:reverse(SubStr)}.

Редактировать

Этот подход работает, но зависит от порядка процессов спаунда. Если они возвращаются не по порядку, join() получает детали не по порядку. Таким образом, возможное улучшение может заключаться в том, чтобы пометить каждую часть From, чтобы join() мог присоединиться к ним в правильном порядке. Это оставлено читателю в качестве упражнения.

Answer 2

Вот моя версия после ответа:

-module(reverse).
-export([reverse/1, join/3, sub_reverse/3]).

reverse("") -> "";
reverse(Str) ->
    Step = ceil(string:length(Str) / 10),
    SplitPoints = lists:seq(0, string:length(Str) - 1, Step),

    JoinPid = spawn(reverse, join, [self(), [], length(SplitPoints)]),

    lists:foreach(
        fun (Start) ->
            IndexPos = Start div Step,
            SubStr = string:slice(Str, Start, Step),
            spawn(reverse, sub_reverse, [JoinPid, IndexPos, SubStr])
        end,
    SplitPoints),

    receive
        { joined, ReversedStr } -> io:format("~p", [ReversedStr])
    end.

join(ReversePid, Acc, N) ->
    case length(Acc) of
        N ->
            Parts = lists:sort(fun ({A, _}, {B, _}) -> A > B end, Acc),
            Str = string:join(lists:map(fun ({_, SubStr}) -> SubStr end, Parts), ""),
            ReversePid ! { joined, Str };
        _ ->
            receive
                {reversed, X} -> join(ReversePid, [X | Acc], N)
            end
    end.


sub_reverse(JoinPid, IndexPos, SubStr) ->
    JoinPid ! {reversed, { IndexPos, string:reverse(SubStr) } }.