Навигация по XML для доступа к CDATA с использованием XML :: TWIG - PullRequest
Новая
       31

Навигация по XML для доступа к CDATA с использованием XML :: TWIG

0 голосов
/ 23 марта 2019

У меня есть этот XML-файл, и мне нужно обращаться к определенным узлам по одному.Ниже приведен пример моего XML вместе с моим примером кода.

Мой код работает нормально, за исключением того, что я перебираю все теги Message / Content вместо того, чтобы просто получать определенный тег Message / Content под текущим Message.тег.Например, я получу 3 тэга Message / Content, когда обрабатывается текущий тэг Message (тэг с refid = "123991123"), когда я хочу вернуть только 1 ().Надеюсь, это имеет смысл.Любая помощь здесь будет оценена.

Код: 

my $twig = XML::Twig->new(
twig_handlers => {
    Selection => sub {
        foreach my $message ($_->findnodes('./Contents/Message')) {

            if($message->att('custom')){
                $Message_custom = $message->att('custom');
                foreach my $Content ($_->findnodes('./Contents/Message/Content')) {
                    print $Selection_id.": ".$Message_refid.": ".$TotalContents++."\n";
                    if($Content->att('language') eq "en"){
                        if($Content->att('imagelibraryid')){
                            $Message_Content_language_en_imagelibraryid = $Content->att('imagelibraryid');
                        }else{
                            $Message_Content_language_en = substr($message->field('Content'), 0, 20);
                        }
                    }
                }
            }
        }
    },
}
);

XML: 

<?xml version="1.0" encoding="UTF-8"?>
<Root>
  <Selection id="54008473">
    <Name>Master</Name>
    <Contents>
      <Message refid="125796458" suppress="true" status="Unchanged"/>
      <Message refid="123991123" suppress="true" status="Unchanged">
        <Content language="en" imagelibraryid="5492396"/>
      </Message>
      <Message refid="128054778" custom="true" status="New">
        <Content language="en"><![CDATA[<p>Some English content</p>]]></Content>
        <Content language="fr"><![CDATA[<p>Some French content</p>]]></Content>
      </Message>
    </Contents>
  </Selection>
  <Selection id="54008475" datavaluerefid="54008479">
    <Name>RMBC</Name>
    <Contents>
      <Message refid="125796458" sameasparent="true" parentrefid="54008473" status="Unchanged"/>
      <Message refid="123991123" sameasparent="true" parentrefid="54008473" status="Unchanged"/>
      <Message refid="128054778" custom="true" status="New">
        <Content language="en"><![CDATA[<p>ada</p>]]></Content>
      </Message>
    </Contents>
  </Selection>
</Root>

1 Ответ

1 голос
/ 23 марта 2019

Вот первая попытка понять, что должен делать ваш код, основываясь на структуре XML:

  • обработчик для Selection узлов ищет дочерние Content узлыс атрибутом language == 'en' под Message узлами под Content узлами
    • преобразуется в XPath ./Contents/Message/Content[@language='en']
    • , если он имеет атрибут imagelibraryid, сохраните значение этого
    • в противном случае сохраните содержимое CDATA первого дочернего элемента
    • установите refid в значение атрибута из родительского Message узла
  • и добавьте его ксписок содержимого для узла Selection
  • , чтобы показать, что было собрано, используйте Data :: Dumper в массиве ref 
#!/usr/bin/perl
use warnings;
use strict;

use XML::Twig;
use Data::Dumper;

my %selections;

my $twig = XML::Twig->new(
    twig_handlers => {
        Selection => sub {
            #$_->print();
            print "selection id: ", $_->att('id'), "\n";

            my @contents;
            foreach my $content ($_->findnodes("./Contents/Message/Content[\@language='en']")) {
                my $result = {
                    refid => $content->parent->att('refid'),
                };
                my $id     = $content->att('imagelibraryid');
                if (defined $id) {
                    $result->{library} = $id;
                } else {
                    $result->{cata}    = $content->first_child->cdata;
                }
                push(@contents, $result);
            }

            # store collected Content nodes under selection ID
            $selections{ $_->att('id') } = \@contents;
        },
    }
);

$twig->parse(\*DATA);

while (my($id, $contents) = each %selections) {
    my $dump = Dumper($contents);
    print "Selection '${id}' messages: $dump\n";
}

exit 0;

__DATA__
<?xml version="1.0" encoding="UTF-8"?>
... the rest of your XML left out ...

Тестовый прогон:

$ perl dummy.pl
selection id: 54008473
selection id: 54008475
Selection '54008473' messages: $VAR1 = [
          {
            'refid' => '123991123',
            'library' => '5492396'
          },
          {
            'cata' => '<p>Some English content</p>',
            'refid' => '128054778'
          }
        ];

Selection '54008475' messages: $VAR1 = [
          {
            'cata' => '<p>ada</p>',
            'refid' => '128054778'
          }
        ];
...