Экспорт PDF в Excel

Question

В Adobe DC Pro у вас есть возможность экспортировать электронную таблицу pdf в Excel 2003, сначала перейдя в «Экспорт PDF», затем выбрав «XML Spreadsheet 2003» и, наконец, выбрав параметр «Создать рабочую таблицу для каждой страницы». "

Я не могу найти код, который делает это в Excel VBA.

Мой вопрос: как мне сделать, чтобы excel выполнил эту опцию через VBA? Просто сохраните его как SaveAS FileFormat: = XlFileFormat.xlXMLSpreadsheet только делает его электронной таблицей XML, а не «создает рабочий лист для каждой страницы», который создает Adobe Pro.

Спасибо

Answer 1

У меня все еще есть проблема с Page_Text - Ничто.Несмотря на то, что у меня открыт PDF, кажется, что он не читает Page_Text.Вот код:

.Open "C:\User\test.pdf"
Count_Page=.GetNumPages

For I=1 to Count_Page
PDF_Text_Str=""
Set PDF_Page=.AcquirePage(i-1)
Set Page_Text=PDF_Page.CreateWordHilite(Hilight_Text)
If Not Page_Text is Nothing then
With Page_Text
For j=0 to .GetNumText  -1
PDF_Text_Str=PDF_Text_Str & .GetText(j)
Next j
End With
End if

Спасибо

Answer 2

Вы можете сделать это, используя справочную библиотеку типов Adobe Acrobat 10.0 , поставляемую с Adobe Acrobat Pro.

Вот пример:

Этот код откроет файл PDF и назначит каждую страницу PDF отдельным листам.

Option Explicit
Sub PDF_To_Excel()

Dim PDF_ As Acrobat.AcroPDDoc
Dim Hilight_Text As Acrobat.AcroHiliteList
Dim PDF_Page As Acrobat.AcroPDPage
Dim Page_Text As Acrobat.AcroPDTextSelect
Dim ws As Worksheet
Dim Count_Page As Long
Dim i As Long, j As Long, k As Long
Dim PDF_Text_Str As String
Dim Hold_Txt As Variant

Set PDF_ = New Acrobat.AcroPDDoc
Set Hilight_Text = New Acrobat.AcroHiliteList

Hilight_Text.Add 0, 32767

With PDF_

.Open "C:\ED5049PX2.pdf"
Count_Page = .GetNumPages

For i = 1 To Count_Page

PDF_Text_Str = ""

Set PDF_Page = .AcquirePage(i - 1)
Set Page_Text = PDF_Page.CreateWordHilite(Hilight_Text)

If Not Page_Text Is Nothing Then

With Page_Text

For j = 0 To .GetNumText - 1
PDF_Text_Str = PDF_Text_Str & .GetText(j)
Next j

End With

End If

Set ws = Worksheets.Add(, Worksheets(Sheets.Count))

With ws
.Name = "Page-" & i

If PDF_Text_Str <> "" Then

Hold_Txt = Split(PDF_Text_Str, vbCrLf)

For k = 0 To UBound(Hold_Txt)

PDF_Text_Str = CStr(Hold_Txt(k))
If Left(PDF_Text_Str, 1) = "=" Then PDF_Text_Str = "'" & PDF_Text_Str
.Cells(k + 1, 1).Value = PDF_Text_Str

Next k

Else
.Cells(1, 1).Value = "No text found in page " & i
End If

.Cells.Select
.Cells.EntireColumn.AutoFit

End With

Next

.Close

End With

MsgBox ("Done")

End Sub