Проверка результата перед выполнением запроса - PullRequest
Новая
       6

Проверка результата перед выполнением запроса

3 голосов
/ 27 мая 2019

При запуске хранимой процедуры для извлечения некоторых строк, во-первых, я хочу проверить, вернет ли запрос строку перед отправкой результата, и, во-вторых, можно ли проверить, не выполняя один и тот же запрос дважды.

Я использую курсор для сохранения полученного результата, поэтому я попробовал атрибут курсора %ROWCOUNT & %NOTFOUND. Но не совсем работает. Плюс я хочу сделать это без запуска цикла на курсоре. 

procedure MODULE_LIST_GK(p_module_Id IN MODULE_LIST.MODULE_ID% TYPE,
                                     p_Error_Code     out nvarchar2,
                                     p_Error_Msg      out nvarchar2,
                                     p_Cursor         out sys_refcursor)   IS
 BEGIN
    OPEN p_Cursor FOR
       SELECT A.MODULE_ID,
         A.MODULE_NM,
         A.AUTH_STATUS_ID
         FROM MODULE_LIST A
         WHERE A.MODULE_ID=p_module_Id;

       SELECT COUNT(MODULE_ID)
       INTO v_row_num
        FROM MODULE_LIST A
        WHERE A.MODULE_ID=p_module_Id;

       IF v_row_num=0 THEN
         p_Error_Code := SQLCODE;
         p_Error_Msg := 'Does not Exists';
         Return;
       end IF;
    EXCEPTION
      WHEN OTHERS THEN
        p_error_code:= SQLCODE;
        p_error_msg := SQLERRM;
  END MODULE_LIST_GK;

Ответы [ 2 ]

3 голосов
/ 27 мая 2019

Ваша реализация имеет несколько моментов, которые можно улучшить.

Сначала , если вы ожидаете, что для множества параметров возвращаемый курсор будет пустым, чем сначала проверьте пустой курсор и только после этой проверки откройте курсор. Вы делаете это наоборот.

Как проверить, пуст ли курсор? К сожалению, вы должны получить первый ряд, чтобы иметь возможность проверить это. 

 open l_cur for
   select id, status from tab where id = p_id; 
 fetch l_cur into l_id, l_status;
 if l_cur%NOTFOUND then
    p_Error_Msg := 'Does not Exists';
    Return;
 end if;

Эта проверка гораздо более эффективна, чем часто используемая count(*), поскольку она учитывает только первые (несколько) строк и не учитывает все строки в курсоре.

Если проверка не пройдена, вы готовы, иначе просто откройте курсор и верните его. 

 open  l_cur for
   select id, status from tab where id = p_id; 
   p_Cursor := l_cur;

На ум приходят две дополнительные мысли.

Вам следует изменить общий подход, если база данных очень динамична. Как бы вы справились со случаем, когда другой сеанс удаляет некоторую строку между проверкой и вторым открытием курсора?

Наконец, рассмотрите возможность возврата исключения вместо кода возврата.

1 голос
/ 27 мая 2019

Чтобы узнать, содержит ли курсор строки, вы должны открыть его и получить первую строку. После того, как вы это сделаете, возвращать этот курсор больше не имеет смысла, поскольку получатель не сможет извлечь эту первую строку, поскольку курсор уже указывает за нее.

Итак, вы должны выбрать дважды. То, что вы должны сделать, это использовать ROWNUM или предложение EXISTS здесь, чтобы показать СУБД, что вы больше не интересуетесь строками. Это может значительно ускорить запрос. 

PROCEDURE module_list_gk(p_module_id   IN   MODULE_LIST.MODULE_ID%TYPE,
                         p_error_code  OUT  NVARCHAR2,
                         p_error_msg   OUT  NVARCHAR2,
                         p_cursor      OUT  SYS_REFCURSOR) IS
  v_count INTEGER;
BEGIN
  SELECT COUNT(*)
  INTO v_count
  FROM module_list
  WHERE module_id = p_module_Id
  AND ROWNUM = 1;

  IF v_count = 0 THEN
    p_error_code := 0; -- Or -1403 for NO DATA FOUND if you like
    p_error_msg := 'Does not Exists';
    RETURN;
  END IF;

  OPEN p_Cursor FOR
    SELECT module_id, module_nm, auth_status_id
    FROM module_list
    WHERE module_id = p_module_id;

EXCEPTION WHEN OTHERS THEN
  p_error_code:= SQLCODE;
  p_error_msg := SQLERRM;
END module_list_gk;

Кстати, SQLCODE для первого запроса будет 0 (SELECT COUNT(*) возвращает одну строку с количеством найденных записей - без ошибок, следовательно). Вот почему вы должны решить либо вернуть ноль явно, либо какой-либо код ошибки, например -1403.

Здесь то же самое с EXISTS: 

BEGIN
  SELECT CASE WHEN EXISTS
  (
    SELECT NULL
    FROM module_list
    WHERE module_id = p_module_Id
  ) THEN 1 ELSE 0 END
  INTO v_count
  FROM DUAL;

  IF v_count = 0 THEN
...