С emacs, как поменять местами 2 окна

Question

В Emacs у меня открыто 2 окна, и я бы хотел поменять их местами.

Т.е. подумайте о наличии REPL над исходным файлом, и я бы хотел поменять их местами, чтобы REPL находился ниже исходного файла.

Я также хотел бы сохранить размеры окон

Answer 1

Я бесстыдно украл это у .emacs Стива Йегге

(defun swap-windows ()
  "If you have 2 windows, it swaps them." 
  (interactive)
  (cond ((not (= (count-windows) 2)) (message "You need exactly 2 windows to do this."))
        (t
         (let* ((w1 (first (window-list)))
                (w2 (second (window-list)))
                (b1 (window-buffer w1))
                (b2 (window-buffer w2))
                (s1 (window-start w1))
                (s2 (window-start w2)))
           (set-window-buffer w1 b2)
           (set-window-buffer w2 b1)
           (set-window-start w1 s2)
           (set-window-start w2 s1)))))

Проверено на Emacs 23.1.1 на Gentoo. Это сохраняет размеры окна.

Я также нашел это немного чище.

(defun transpose-windows ()
  (interactive)
  (let ((this-buffer (window-buffer (selected-window)))
        (other-buffer (prog2
                          (other-window +1)
                          (window-buffer (selected-window))
                        (other-window -1))))
    (switch-to-buffer other-buffer)
    (switch-to-buffer-other-window this-buffer)
    (other-window -1)))

Также протестирован на Emacs 23.1.1

Answer 2

Следующая версия работает с любым количеством окон. Если имеется более двух окон, повторные вызовы заставят выбранный буфер появляться в каждом окне последовательно.

(defun swap-buffer ()
  (interactive)
  (cond ((one-window-p) (display-buffer (other-buffer)))
        ((let* ((buffer-a (current-buffer))
                (window-b (cadr (window-list)))
                (buffer-b (window-buffer window-b)))
           (set-window-buffer window-b buffer-a)
           (switch-to-buffer buffer-b)
           (other-window 1)))))

Answer 3

Я считаю библиотеку TransposeFrame полезной. Я в основном использую его для замены двух окон, согласно этому вопросу; но он обеспечивает более общую функциональность, чем просто.

Перейдите по ссылке, чтобы увидеть ascii диаграммы различных преобразований.

Answer 4

См. http://www.emacswiki.org/cgi-bin/wiki/buffer-move.el. Вы можете установить его через elpa