Как я могу получить список всех файлов с определенным расширением из определенного каталога?

Question

Я использую этот код для получения списка всех файлов в определенном каталоге:

opendir DIR, $dir or die "cannot open dir $dir: $!";
my @files= readdir DIR;
closedir DIR;

Как я могу изменить этот код или добавить что-то к нему, чтобы он только просматривал текстовые файлы и загружал массив только с префиксом имени файла?

Пример содержимого каталога:

.
..
923847.txt
98398523.txt
198.txt
deisi.jpg
oisoifs.gif
lksdjl.exe

Пример содержимого массива:

files[0]=923847 
files[1]=98398523
files[2]=198

Answer 1

my @files = glob "$dir/*.txt";
for (0..$#files){
  $files[$_] =~ s/\.txt$//;
}

Answer 2

достаточно изменить одну строку:

my @files= map{s/\.[^.]+$//;$_}grep {/\.txt$/} readdir DIR;

Answer 3

Если вы можете использовать новые функции Perl 5.10, я бы так написал.

use strict;
use warnings;
use 5.10.1;
use autodie; # don't need to check the output of opendir now

my $dir = ".";

{
  opendir my($dirhandle), $dir;
  for( readdir $dirhandle ){ # sets $_
    when(-d $_ ){ next } # skip directories
    when(/^[.]/){ next } # skip dot-files

    when(/(.+)[.]txt$/){ say "text file: ", $1 }
    default{
      say "other file: ", $_;
    }
  }
  # $dirhandle is automatically closed here
}

Или, если у вас очень большие каталоги, вы можете использовать цикл while.

{
  opendir my($dirhandle), $dir;
  while( my $elem = readdir $dirhandle ){
    given( $elem ){ # sets $_
      when(-d $_ ){ next } # skip directories
      when(/^[.]/){ next } # skip dot-files

      when(/(.+)[.]txt$/){ say "text file: ", $1 }
      default{
        say "other file: ", $_;
      }
    }
  }
}

Answer 4

Это самый простой способ, который я нашел (как в удобочитаемом для человека), используя функцию glob:

 # Store only TXT-files in the @files array using glob
 my @files = grep ( -f ,<*.txt>);
 # Write them out
 foreach $file (@files) {
  print "$file\n";
 }

Кроме того, "-f" гарантирует, что в массиве хранятся только фактические файлы (а не каталоги).

Answer 5

Чтобы получить только файлы ".txt", вы можете использовать оператор проверки файлов (-f: обычный файл) и регулярное выражение.

my @files = grep { -f && /\.txt$/ } readdir $dir;

В противном случае вы можете искать только текстовые файлы, используя perl's -T (оператор проверки текстового файла ascii)

my @files = grep { -T } readdir $dir;

Answer 6

Просто используйте это:

my @files = map {-f && s{\.txt\z}{} ? $_ : ()} readdir DIR;