Как я могу создать файл XML с vb.net?

Question

Мне нужно создать файл XML, в котором хранятся маршруты всех файлов, которые копирует моя программа.

Я пытаюсь использовать тот же код, который мне нужен для создания журнала.

Public Sub XMLRoutes(ByVal routeAs String)
    Dim xmlPath As String = "C:\Log\"

    'Create route if it doesn't exist
    If Directory.Exists(xmlPath) = False Then
        Directory.CreateDirectory(xmlPath)
    End If

    Dim xmlSW As System.IO.StreamWriter

    Dim Path As String = "C:\Log\CopiedRoutes.xml"

    If File.Exists(Path) = False Then
        Dim fs As FileStream = File.Create(Path)
    End If

    xmlSW.WriteLine("<route>" + route + "</route>")
    xmlSW.Flush()
    xmlSW.Close()

End Sub

Но я не знаю, будет ли он работать правильно, и я не знаю, как разместить начальные теги

Я бы хотел, чтобы мой результат получился таким:

<?xml version='1.0' encoding='iso-8859-1'?>
<parameters>
  <route>route 1</route>
  <route>route 2</route>
  ...
</parameters>

Answer 1

Использование литералов XElement и XML облегчает это, ИМХО.

''' <summary>
''' adds route to xml file
''' </summary>
''' <param name="route"></param>
''' <param name="pathToXML">the route xml file, will be created if does not exist</param>
Public Sub XMLRoutes(pathToXML As String, route As String)
    Dim xe As XElement
    If Not IO.File.Exists(pathToXML) Then
        'create the file
        xe = <ROUTES></ROUTES>
        xe.Save(pathToXML)
    Else
        xe = XElement.Load(pathToXML)
    End If
    Dim newRoute As XElement = <route><%= route %></route>

    xe.Add(newRoute)
    xe.Save(pathToXML)
End Sub

Чтобы использовать его

    Dim path As String = "C:\Log\CopiedRoutes.xml"
    XMLRoutes(path, "one")
    XMLRoutes(path, "two")