QML: Как выбрать радио-кнопку из списка?

Question

У меня есть следующий компонент просмотра списка:

CustomListRadio.qml

import QtQuick 2.12
import QtQuick.Controls 2.12
import "."

Rectangle {
    id: radio_content
    x: 0
    y: 40
    width: 320
    height: 158
    color: "black"

    property int counter: 0
    property int savedIndex: 0
    property int checkedIndex: 0
    property variant internalModel

    ButtonGroup {
        id: buttonGroup
    }

    ListView {
        id: list
        x: 0
        y: 0
        width: 320
        height: 158
        model: parent.internalModel
        anchors.fill: radio_content

        delegate: RadioDelegate {

            text: modelData
            checked: index == radio_content.savedIndex
            ButtonGroup.group: buttonGroup

            font.pixelSize: 23
            font.family: "Futura Condensed"
            font.styleName: "Medium"

            MouseArea {
                anchors.fill: parent
                onClicked: {
                    parent.checked = true
                    radio_content.checkedIndex = model.index
                }
            }

        }
    }
}

RadioDelegate.qml

import QtQuick 2.12
import QtQuick.Controls 2.12

RadioDelegate {
    id: control
    text: qsTr("RadioDelegate")
    checked: true

    contentItem: Text {
        leftPadding: control.indicator.width + control.spacing
        text: control.text
        font: control.font
        opacity: enabled ? 1.0 : 0.3
        color: "white"
        elide: Text.ElideRight
        verticalAlignment: Text.AlignVCenter
    }

    indicator: Rectangle {
        implicitWidth: 30
        implicitHeight: 30
        x: control.leftPadding
        y: parent.height / 2 - height / 2
        radius: 15
        color: control.checked ? "#0088FF" : "white"
        border.color: "#0088FF"

        Rectangle {
            width: 10
            height: 10
            x: parent.width / 2 - width / 2
            y: parent.height / 2 - height / 2
            radius: 5
            color: "white"
            visible: control.checked
        }
    }

    background: Rectangle {
        implicitWidth: 320
        implicitHeight: 40
        color: "black"

        border {
            color: "#383838"
            width: 1
        }

    }
}

Как добавить компонент

CustomListRadio {
    id: radio_list
    internalModel: msg.languageVariantList
    savedIndex: msg.language
}

Создает список радиокнопок. Это работает хорошо. Но я не могу выбрать переключатель по умолчанию. Выбор переключателя с помощью мыши, работает. Но из кода, в лучшем случае, мое решение выбирает переключатель, только если длина списка равна количеству видимых элементов.

Answer 1

Проблема в RadioDelegate.qml , необходимо удалить следующую строку:

checked: true