Макро-цикл SAS для обхода наборов данных в операторе Set - PullRequest
Новая
       16

Макро-цикл SAS для обхода наборов данных в операторе Set

0 голосов
/ 12 марта 2019

У меня есть 2 макро цикла SAS - 1 для создания набора данных временных рядов и один для добавления наборов данных в основной набор данных.Макрос Date_loop1 создает наборы данных временных рядов.В этом примере я создаю фиктивные наборы данных.На самом деле реальные наборы данных имеют размер несколько МБ.Поэтому использование proc add в пределах Date_loop1 к основному набору данных приводит к медленному прогрессу.Поэтому я создал второй макрос Date_loop2, чтобы накапливать все вышеперечисленные наборы данных в операторе SET.Проблема в том, что второй цикл работает не так, как задумано.Можете ли вы помочь?

Примечание: если вы запустите Date_loop1, вы увидите, как создаются наборы данных.Date_loop2 также должен работать аналогичным образом. 

%MACRO LOOP1;
DATA ROLLRATE_&ST_YYYYMM._&ED_YYYYMM.;
ST_YYYYMM = &ST_YYYYMM;
ED_YYYYMM = &ED_YYYYMM;
RUN;
%MEND; 

%MACRO DATE_LOOP1(START,END);

%LET START_YEAR = %SYSFUNC(FLOOR(&START/100));
%LET START_MONTH = %SYSFUNC(MOD(&START,100));
%LET END_YEAR = %SYSFUNC(FLOOR(&END/100));
%LET END_MONTH = %SYSFUNC(MOD(&END,100));

%LET START_DATE = %SYSFUNC(MDY(&START_MONTH,01,&START_YEAR));
%LET END_DATE = %SYSFUNC(MDY(&END_MONTH,01,&END_YEAR));
%LET DIF=%EVAL(%SYSFUNC(INTCK(MONTH,&START_DATE,&END_DATE)));
/*DATA MASTER_ROLLRATE;RUN;DATA ROLLRATE;RUN;*/
%DO I=0 %TO &DIF;
    %DO J=&I %TO &DIF;

    %LET ST_DT = %SYSFUNC(INTNX(MONTH,&START_DATE,&I,B)); /*B - DATE AT THE BEGINNING OF THE WEEK/MONTH/YEAR */
    %LET ST_YEAR = %SYSFUNC(YEAR(&ST_DT));
    %LET ST_MONTH = %SYSFUNC(MONTH(&ST_DT));
    %LET ST_YYYYMM = %EVAL(&ST_YEAR*100+&ST_MONTH);

    %LET ED_DT = %SYSFUNC(INTNX(MONTH,&START_DATE,&J,B));
    %LET ED_YEAR = %SYSFUNC(YEAR(&ED_DT));
    %LET ED_MONTH = %SYSFUNC(MONTH(&ED_DT));
    %LET ED_YYYYMM = %EVAL(&ED_YEAR*100+&ED_MONTH);

    %PUT &ST_YYYYMM &ED_YYYYMM;

    %LET START_YYYYMM = &ST_YYYYMM;%LET END_YYYYMM = &ED_YYYYMM;%LOOP1;RUN;

    %END;
%END;
%MEND DATE_LOOP1;

%DATE_LOOP1(201901,201902);


%MACRO DATE_LOOP2(START,END);

%LET START_YEAR = %SYSFUNC(FLOOR(&START/100));
%LET START_MONTH = %SYSFUNC(MOD(&START,100));
%LET END_YEAR = %SYSFUNC(FLOOR(&END/100));
%LET END_MONTH = %SYSFUNC(MOD(&END,100));

%LET START_DATE = %SYSFUNC(MDY(&START_MONTH,01,&START_YEAR));
%LET END_DATE = %SYSFUNC(MDY(&END_MONTH,01,&END_YEAR));
%LET DIF=%EVAL(%SYSFUNC(INTCK(MONTH,&START_DATE,&END_DATE)));
DATA MASTER_ROLLRATE;
SET
%DO I=0 %TO &DIF;
    %DO J=&I %TO &DIF;

    %LET ST_DT = %SYSFUNC(INTNX(MONTH,&START_DATE,&I,B)); /*B - DATE AT THE BEGINNING OF THE WEEK/MONTH/YEAR */
    %LET ST_YEAR = %SYSFUNC(YEAR(&ST_DT));
    %LET ST_MONTH = %SYSFUNC(MONTH(&ST_DT));
    %LET ST_YYYYMM = %EVAL(&ST_YEAR*100+&ST_MONTH);

    %LET ED_DT = %SYSFUNC(INTNX(MONTH,&START_DATE,&J,B));
    %LET ED_YEAR = %SYSFUNC(YEAR(&ED_DT));
    %LET ED_MONTH = %SYSFUNC(MONTH(&ED_DT));
    %LET ED_YYYYMM = %EVAL(&ED_YEAR*100+&ED_MONTH);
    %LET START_YYYYMM = &ST_YYYYMM;%LET END_YYYYMM = &ED_YYYYMM;

    ROLLRATE_&START_YYYYMM._&END_YYYYMM;

    %END;
%END;
;
RUN;
%MEND DATE_LOOP1;

%DATE_LOOP2(201901,201902);

Ответы [ 3 ]

2 голосов
/ 13 марта 2019

Вы можете использовать списки имен в операторе SET и вообще избегать макросов.

Каждый набор данных, имя которого начинается с rollrate, будет составлен: 

data want;
  set work. rollrate:;
run;
1 голос
/ 13 марта 2019

Включите опцию MPRINT, чтобы увидеть, какой код генерирует ваш макрос.Второй генерирует код, подобный следующему: 

MPRINT(DATE_LOOP2):   data master_rollrate;
MPRINT(DATE_LOOP2):   set rollrate_201901_201901;
NOTE: Line generated by the macro variable "ED_YYYYMM".
1         rollrate_201901_201902
          ----------------------
          180
MPRINT(DATE_LOOP2):   rollrate_201901_201902;
NOTE: Line generated by the macro variable "ED_YYYYMM".
1         rollrate_201902_201902
          ----------------------
          180
MPRINT(DATE_LOOP2):   rollrate_201902_201902;
MPRINT(DATE_LOOP2):   ;
MPRINT(DATE_LOOP2):   run;

Удалите лишнюю точку с запятой в середине вложенных циклов %do, так как вы генерируете только часть оператора в этих циклах.

Вы можете значительно упростить свой код макроса, используя информацию и форматы для преобразования строк цифр ГГГГММ в реальные значения даты и обратно. 

%macro date_loop2(start,end);
%local start_date end_date dif i j st_yyyymm ed_yyyymm;

%let start_date = %sysfunc(inputn(&start.01,yymmdd8));
%let end_date = %sysfunc(inputn(&end.01,yymmdd8));
%let dif=%sysfunc(intck(month,&start_date,&end_date));

data master_rollrate;
  set

%do i=0 %to &dif;
  %do j=&i %to &dif;
    %let st_yyyymm = %sysfunc(intnx(month,&start_date,&i,b),yymmn6);
    %let ed_yyyymm = %sysfunc(intnx(month,&start_date,&j,b),yymmn6);

  rollrate_&st_yyyymm._&ed_yyyymm

  %end;
%end;
  ;
run;
%mend date_loop2;
1 голос
/ 13 марта 2019

Есть две проблемы, которые я сейчас вижу

  1. Исправлено% для второго цикла: date_loop1 вместо date_loop2 (Вторая последняя строка кода)

    % MEND DATE_LOOP1; / Должно быть DATE_LOOP2 /

    % DATE_LOOP2 (201901,201902);

  2. Пожалуйста, удалите точку с запятой после ROLLRATE_ & START_YYYYMM ._ & END_YYYYMM в макросе date_loop2, потому что есть; после окончания заявления

...