Нахождение GCD массива из n чисел в сборке без внешних переменных - PullRequest
Новая
       22

Нахождение GCD массива из n чисел в сборке без внешних переменных

1 голос
/ 14 мая 2019

У меня есть домашнее задание по поиску GCD массива из n чисел в сборке (я использую asm в Visual Studio 2017) без использования внешних переменных в C. Единственная переменная, которую я получил, это длинамассив из n чисел.У меня нет проблем с поиском GCD первых двух чисел массива, но я не уверен, как сделать цикл, в котором я постоянно обновляю свои регистры следующим номером массива, поскольку GCD из 3 чисел a, b, c является GCD (GCD (a, b), c).Я надеюсь на некоторую помощь. 

#include <stdio.h>

void main()
{
    unsigned int intArray[] = {12,24,3};
    int num = sizeof(intArray) / sizeof(intArray[0]);
    unsigned int MCD;

    __asm
    {
        xor ebx,ebx
        xor edx,edx
        xor eax,eax
        mov eax, intArray[0]
        mov ebx, intArray[1]
        jmp major

    zerob:
        mov MCD, eax
        jmp fine

    major:
        cmp eax,ebx
        jg nextstep
        xchg eax,ebx
        jmp major

    nextstep:
        cmp ebx,0
        je zerob
        jne modulus

    modulus:
        div ebx
        mov MCD,edx
        mov eax,ebx
        mov ebx,MCD
        jmp nextstep

    fine:

    }

    printf("M.C.D.: %d \n", MCD);
    getchar();
}

1 Ответ

2 голосов
/ 16 мая 2019

Шаг 1, очистка и исправления

Удаление избыточных инструкций, перестановка кода для меньшего количества переходов, удаление потенциального бесконечного цикла, если используются 2 одинаковых числа, и обнуление EDX перед каждым делением: 

    mov  eax, intArray[0]
    mov  ebx, intArray[1]

major:
    cmp  eax, ebx
    jg   nextstep
    xchg eax, ebx
nextstep:
    cmp  ebx, 0
    je   zerob
modulus:
    xor  edx, edx
    div  ebx
    mov  eax, ebx
    mov  ebx, edx
    jmp  nextstep

zerob:
    mov  MCD, eax
fine:

Шаг 2, создание цикла

Использование количества элементов в num , выборка чисел с помощью указателя в ESI и превращение внутреннего цикла в DO-Круглый цикл (условно прыгает на вершину): 

    mov  ecx, num       ;Number of elements
    lea  esi, intArray[0]
    lodsd               ;First number in array
    dec  ecx
    jz   DONE

AGAIN:
    mov  ebx, [esi]     ;Next number in array
    add  esi, 4

major:
    cmp  eax, ebx
    jg   nextstep
    xchg eax, ebx
    jmp  nextstep
modulus:                ;Inner loop
    xor  edx, edx
    div  ebx
    mov  eax, ebx
    mov  ebx, edx
nextstep:
    test ebx, ebx
    jnz  modulus

    dec  ecx
    jnz  AGAIN

DONE:
    mov  MCD, eax
fine:
...