Подсчет строк во всех таблицах, соответствующих условиям

Question

У меня есть база данных с 7000 таблиц, большинство из них имеют столбец DataAreaId, но не все таблицы, поскольку некоторые являются глобальными.

Я хотел бы перечислить все таблицы, в которых есть столбец DataAreaId, и их количество строк, где столбец DataAreaId содержит "FR".

Так для одной таблицы это будет:

SELECT COUNT(*)
FROM Table
WHERE DataAreaId = 'FR'

Есть предложения?

Answer 1

Вы можете использовать следующее

CREATE TABLE T1(
  Dataareaid  VARCHAR(45)
);

CREATE TABLE T2(
  Dataareaid  VARCHAR(45)
);

INSERT INTO T1 VALUES
('FR'),
('ALG'),
('FR');

DECLARE @SQL NVARCHAR(max) = N'';

SELECT @SQL = (
   SELECT CONCAT(
        N'UNION ALL ',
        N'SELECT ''',
        t.name,
        N''' AS TableName, ',
        N'Cnt = (SELECT COUNT(1)',
        ' FROM ',
        QUOTENAME(t.name),
        N' WHERE [Dataareaid] = ''FR'')'
   )
   FROM sys.columns c
   JOIN sys.tables t ON c.object_id = t.object_id
   WHERE c.name = 'Dataareaid'
   FOR XML PATH('')
)
SET @SQL = STUFF(@SQL, 1, 10, N'');

EXEC sp_executesql @SQL;

Возвраты:

+-----------+-----+
| TableName | Cnt |
+-----------+-----+
| T1        |   2 |
| T2        |   0 |
+-----------+-----+

Live Demo

Answer 2

Мой ответ получает метаданные столбца, выполняет инструкцию в цикле и публикует результаты в табличной переменной:

if object_id('tempdb..#LoopList') is not null
    drop table #LoopList

select 
s.[name] as SchemaName
,t.[name] as TableName
,row_number() over (order by t.[object_id] asc) as RowNumber
into #LoopList
from sys.columns as c
inner join sys.tables as t
    on c.[object_id] = t.[object_id]
inner join sys.schemas as s
    on t.[schema_id] = s.[schema_id]
where c.[name] = 'Dataareaid'

declare 
    @a int = 1
    ,@b int = (select max(RowNumber) from #LoopList)
    ,@c nvarchar(max)
    ,@d nvarchar(max)
    ,@e int


declare @count table (RowCounter int)

declare @resultsTable table (TableName nvarchar(500), RowCounter int)


while @a <= @b

begin

    delete from @count
    set @c = concat ((select quotename(SchemaName) from #LoopList where RowNumber = @a)
                    ,'.'
                    ,(select quotename(TableName) from #LoopList where RowNumber = @a)
                    )

    set @d = concat(N'select count(*) from ' 
                    ,@c
                    ,N' where Dataareaid = ''FR'''
                    )
    insert into @count (
            RowCounter
            )
    exec sp_executesql @d

    set @e = (select top 1 RowCounter from @count)

    insert into @resultsTable (
        TableName
        ,RowCounter
        )
    values (@c,@e)

    set @a += 1;

end

select * from @resultsTable

Answer 3

Один из способов сделать это - запросить все таблицы, содержащие этот столбец, и создать оператор запроса для каждой

select 'union all select ' + QUOTENAME(t.name,N'''') + ', count(1) from ' + t.name + ' where Dataareaid = ''FR'''
from sys.columns c
  join sys.tables t ON c.object_id = t.object_id
where c.name = 'Dataareaid'

, каждая строка будет выглядеть так:

union all select 'SomeTable', count(1) from SomeTable where Dataareaid = 'FR'

Теперь простособрать все операторы и удалить первое объединение all