CPLEX не может прочитать данные из файла Excell, потому что матрица слишком большая? - PullRequest
Новая
       18

CPLEX не может прочитать данные из файла Excell, потому что матрица слишком большая?

0 голосов
/ 18 апреля 2019

Я решаю задачу оптимизации, используя европейскую электросеть с 9241 узлом.Для этого я создал матрицу подключения и вставил ее в файл Excel.Используя код из более мелких задач (меньше узлов), который берет информацию из файла Excel для записи матрицы CPLEX, я попытался применить ее к этой более крупной проблеме, и я получил следующую ошибку:

Exception from IBM ILOG Concert: Can not read data from excel. PEGASE-9241data.dat /Teste 8:36-37 E:\Program Files\IBM\ILOG\CPLEX_Studio129\opl\oplide\workspace\Teste\PEGASE-9241data.dat OPL Problem Marker

Некоторые важные вещи, которые нужно знать:

- Файл Excel: .xlsx

- Я записал матрицу подключения вФайл Excel с использованием Matlab (работал для небольших проблем)

Когда я пытаюсь использовать тот же код с меньшей проблемой (3120 узлов), он работает нормально.

Модель: 

range n = 1..9241;

dvar boolean x[n];
dvar boolean y[n][n];

 //Conectivity matrix
 int A[n][n] =...;

 //Vector ZIB
 int z[n] =...;

 //Objective Function
 dexpr int total = sum (p in n) x[p];


 minimize (total);

 subject to {

   forall (i in n)
      sum (j in n)             
       (A[i][j]*x[j] +A[i][j]*z[j]*y[i][j]) >= 1;

    forall (j in n)
      sum(i in n)
        A[i][j]*y[i][j] == z[j];

 }

Данные: 

SheetConnection sheet("E:\\Program Files\\IBM\\ILOG\\CPLEX_Studio129\\opl\\oplide\\workspace\\Teste\\PEGASEmatriz9241.xlsx");
A from SheetRead(sheet,"matriz9241");

z from SheetRead(sheet,"zib9241");

1 Ответ

1 голос
/ 19 апреля 2019

Я думаю, у вас проблема с памятью.Мне удалось запустить масштабируемый пример

https://www.ibm.com/developerworks/community/forums/html/topic?id=c2469c56-db27-4816-9cf2-f596513ce555&ps=25

до n = 7000

Так что в вашем случае я бы разделил ваш квадрат на 4 квадрата.Позвольте мне поделиться полной моделью, чтобы сделать это.

Сначала запишите в файл Excel, чтобы позволить вам тестировать.

.mod 

execute
{

// http://cwestblog.com/2013/09/05/javascript-snippet-convert-number-to-column-name/
function toColumnName(num) {
  for (var ret = '', a = 1, b = 26; (num -= a) >= 0; a = b, b *= 26) {
    ret = String.fromCharCode(parseInt((num % b) / a) + 65) + ret;
  }
  return ret;
}

// 1,1 => A1  1,4 => D1 2,27 => AA2
function convertR1C1toA1(r,c)
{
return(toColumnName(c)+r);
}

}

int n=4;

int cell[i in 1..n][j in 1..n]=i*j;

int cell1[i in 1..n div 2][j in 1..n div 2]=cell[i][j];
int cell2[i in 1..n div 2][j in n div 2+1..n]=cell[i][j];
int cell3[i in n div 2+1..n][j in 1..n div 2]=cell[i][j];
int cell4[i in n div 2+1..n][j in n div 2+1 ..n]=cell[i][j];

string sheetWriteString1;
string sheetWriteString2;
string sheetWriteString3;
string sheetWriteString4;



execute
{
sheetWriteString1=convertR1C1toA1(1,1)+":"+convertR1C1toA1(n/2,n/2);
writeln("sheetWriteString1=",sheetWriteString1);
sheetWriteString2=convertR1C1toA1(1,n/2+1)+":"+convertR1C1toA1(n/2,n);
writeln("sheetWriteString2=",sheetWriteString2);
sheetWriteString3=convertR1C1toA1(n/2+1,1)+":"+convertR1C1toA1(n,n/2);
writeln("sheetWriteString3=",sheetWriteString3);
sheetWriteString4=convertR1C1toA1(n/2+1,n/2+1)+":"+convertR1C1toA1(n,n);
writeln("sheetWriteString4=",sheetWriteString4);

}

.dat 

SheetConnection s("f2.xlsx");

    cell1 to SheetWrite(s,sheetWriteString1);
    cell2 to SheetWrite(s,sheetWriteString2);
    cell3 to SheetWrite(s,sheetWriteString3);
    cell4 to SheetWrite(s,sheetWriteString4);

, а затем для чтения f2.xls

.mod 

int n=...;
    string sheetWriteString1=...;
    string sheetWriteString2=...;
    string sheetWriteString3=...;
    string sheetWriteString4=...;

    int cell1[i in 1..n div 2][j in 1..n div 2]=...;
    int cell2[i in 1..n div 2][j in n div 2+1..n]=...;
    int cell3[i in n div 2+1..n][j in 1..n div 2]=...;
    int cell4[i in n div 2+1..n][j in n div 2+1..n]=...;

    int cell[i in 1..n][j in 1..n]=
    (i<=n div 2)?((j<=n div 2)?cell1[i][j]:cell2[i][j]):((j<=n div 2)?cell3[i][j]:cell4[i][j]);



    assert forall(i,j in 1..n) cell[i][j]==i*j;

.dat 

SheetConnection s("f2.xlsx");

    n=4;
    sheetWriteString1="A1:B2";
    sheetWriteString2="C1:D2";
    sheetWriteString3="A3:B4";
    sheetWriteString4="C3:D4";

    cell1 from SheetRead(s,sheetWriteString1);
    cell2 from SheetRead(s,sheetWriteString2);
    cell3 from SheetRead(s,sheetWriteString3);
    cell4 from SheetRead(s,sheetWriteString4);
...