Как динамически кодировать последнюю строку и последний столбец

Question

Я создаю код, который поможет мне объединить разные файлы в одной папке в одну уникальную электронную таблицу.(Вывод должен быть простым файлом со всей информацией во всех электронных таблицах).

Количество столбцов всех электронных таблиц будет одинаковым, но число строк может отличаться. Это числострок должен быть динамическим.(Однако, на всякий случай, я хотел бы, чтобы строки и столбцы были динамически кодированы из источника).

Я мог бы кодировать только определенный диапазон, но при вставке в данные есть несколько пробелов (между каждымэлектронная таблица скопирована в новую созданную).

Есть ли какие-либо предложения по динамическому кодированию всех строк и столбцов из источника и вставке их в новую электронную таблицу без каких-либо пустых строк?

Sub MergeAllWorkbooks()
    Dim MyPath As String, FilesInPath As String
    Dim MyFiles() As String
    Dim SourceRcount As Long, FNum As Long
    Dim wb As Workbook, ws As Worksheet
    Dim sourceRange As Range, destrange As Range
    Dim rnum As Long, CalcMode As Long

    ' Change this to the path\folder location of your files.
    MyPath = "C:\Users\Dianear\Desktop\Test"

    ' Add a slash at the end of the path if needed.
    If Right(MyPath, 1) <> "\" Then
        MyPath = MyPath & "\"
    End If

    ' If there are no Excel files in the folder, exit.
    FilesInPath = Dir(MyPath & "*.xl*")
    If FilesInPath = "" Then
        MsgBox "No files found"
        Exit Sub
    End If

    ' Fill the myFiles array with the list of Excel files
    ' in the search folder.
    FNum = 0
    Do While FilesInPath <> ""
        FNum = FNum + 1
        ReDim Preserve MyFiles(1 To FNum)
        MyFiles(FNum) = FilesInPath
        FilesInPath = Dir()
    Loop

    ' Set various application properties.
    With Application
        CalcMode = .Calculation
        .Calculation = xlCalculationManual
        .ScreenUpdating = False
        .EnableEvents = False
    End With

    ' Add a new workbook with one sheet.
    Set ws = Workbooks.Add(xlWBATWorksheet).Worksheets(1)
    rnum = 1

    ' Loop through all files in the myFiles array.
    If FNum > 0 Then
        For FNum = LBound(MyFiles) To UBound(MyFiles)
            Set wb = Nothing
            On Error Resume Next
            Set wb = Workbooks.Open(MyPath & MyFiles(FNum))
            On Error GoTo 0

            If Not wb Is Nothing Then
                On Error Resume Next

                ' Change this range to fit your own needs.
                With wb.Worksheets(1)
                    Set sourceRange = .Range("A1:AA15741")
                End With

                If Err.Number > 0 Then
                    Err.Clear
                    Set sourceRange = Nothing
                Else
                    ' If source range uses all columns then
                    ' skip this file.
                    If sourceRange.Columns.Count >= ws.Columns.Count Then
                        Set sourceRange = Nothing
                    End If
                End If
                On Error GoTo 0

                If Not sourceRange Is Nothing Then

                    SourceRcount = sourceRange.Rows.Count

                    If rnum + SourceRcount >= ws.Rows.Count Then
                        MsgBox "There are not enough rows in the target worksheet."
                        ws.Columns.AutoFit
                        wb.Close savechanges:=False
                        GoTo ExitTheSub
                    Else


                        ' Set the destination range.
                        Set destrange = ws.Range("A" & rnum)

                        ' Copy the values from the source range
                        ' to the destination range.
                        With sourceRange
                            Set destrange = destrange. _
                                            Resize(.Rows.Count, .Columns.Count)
                        End With
                        destrange.Value = sourceRange.Value

                        rnum = rnum + SourceRcount
                    End If
                End If
                wb.Close savechanges:=False
            End If

        Next FNum
        ws.Columns.AutoFit
    End If

ExitTheSub:
    ' Restore the application properties.
    With Application
        .ScreenUpdating = True
        .EnableEvents = True
        .Calculation = CalcMode
    End With
End Sub

Answer 1

Это одно из возможных решений:

Option Explicit

Sub test()

    Dim ws As Worksheet
    Dim LastColumn As Long, LastRow As Long, MaxRow As Long, i As Long
    Dim rng As Range

    For Each ws In ThisWorkbook.Worksheets '<- Loop sheets

        With ws

            MaxRow = 0
            LastColumn = .Cells(1, .Columns.Count).End(xlToLeft).Column '<- Find last column of row 1

            For i = 1 To LastColumn '<- Loop from column 1 to last column

                LastRow = .Cells(.Rows.Count, i).End(xlUp).Row '<- Find last row of column i

                If MaxRow < LastRow Then '<- Check if max row if smallers than last row
                    MaxRow = LastRow '<- if max row is small that last row, max row get the value of last row
                End If

            Next i

            Set rng = .Range(Cells(1, 1), Cells(MaxRow, LastColumn)) '<- Set the range to be copy. range if from A1 to last column last row

        End With

    Next ws

End Sub