Как разделить даты с помощью XSLT

Question

У меня есть группа дат, и я хотел бы создать разделы с таким критерием, как "ровно через 7 дней". Например, это мой источник xml:

<root>
  <entry date="2019-05-12" />
  <entry date="2019-05-19" />
  <entry date="2019-05-26" />
  <entry date="2019-06-16" />
  <entry date="2019-06-23" />
</root>

Результат должен выглядеть следующим образомэто:

<root>
   <group>
      <val>12.5.</val>
      <val>19.5.</val>
      <val>26.5.</val>
   </group>
   <group>
      <val>16.6.</val>
      <val>23.6.</val>
   </group>
</root>

, так как первые три и последние две даты все в воскресенье без перерыва.

Что я имею до сих пор это:

<xsl:stylesheet version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:sd="urn:someprefix"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  exclude-result-prefixes="#all"
  >

  <xsl:output indent="yes"/>

  <xsl:template match="root">
    <root>
      <xsl:copy-of select="sd:partition(distinct-values(for $i in entry/@date return $i cast as xs:date))"/>
    </root>
  </xsl:template>

  <xsl:function name="sd:partition">
    <xsl:param name="dates" as="xs:date*"/>
    <xsl:for-each-group select="$dates" group-adjacent="format-date(., '[F]')">
      <group>
        <xsl:for-each select="current-group()">
          <val>
            <xsl:value-of select="format-date(.,'[D].[M].')"/>
          </val>
        </xsl:for-each>
      </group>
    </xsl:for-each-group>
  </xsl:function>
</xsl:stylesheet>

Который генерирует только одну группу.

Как я могу попросить предыдущий элемент разделить на 7 дней?Я знаю длительность (xs:dayTimeDuration('P1D')), но не знаю, как сравнить ее с предыдущим значением.

Я использую Saxon 9.8 HE.

Answer 1

Я думаю, вы также можете сделать это, используя group-adjacent:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    exclude-result-prefixes="#all"
    expand-text="yes"
    version="3.0">

  <xsl:output method="xml" indent="yes"/>

  <xsl:template match="root">
      <xsl:copy>
          <xsl:for-each-group select="entry/@date/xs:date(.)"
            group-adjacent=". -  (position() - 1) * xs:dayTimeDuration('P7D')">
              <group>
                  <xsl:apply-templates select="current-group()"/>
              </group>
          </xsl:for-each-group>
      </xsl:copy>
  </xsl:template>

  <xsl:template match=".[. instance of xs:date]">
      <val>{format-date(.,'[D].[M].')}</val>
  </xsl:template>

</xsl:stylesheet>

https://xsltfiddle.liberty -development.net / ncdD7mM

Answer 2

Чтобы выполнить группировку, вам действительно нужно знать разницу в днях с предыдущим элементом, затем вы можете группировать, начиная с дат, где разница не равна 7 дням.Таким образом, вы можете объявить переменную, в которой вы создадите новый XML-файл с датами и различиями, а затем использовать его для группировки.

Вместо этого попробуйте эту функцию в вашем XSLT.

<xsl:function name="sd:partition">
    <xsl:param name="dates" as="xs:date*"/>

    <xsl:variable name="datesWithDiff" as="element()*">
      <xsl:for-each select="$dates">
        <xsl:variable name="pos" select="position()" />
        <date diff="{(. - $dates[$pos - 1]) div xs:dayTimeDuration('P1D')}">
          <xsl:value-of select="." />
        </date>   
      </xsl:for-each>
    </xsl:variable>

    <xsl:for-each-group select="$datesWithDiff" group-starting-with="date[@diff = '' or xs:int(@diff) gt 7]">
      <group>
        <xsl:for-each select="current-group()">
          <val>
            <xsl:value-of select="format-date(.,'[D].[M].')"/>
          </val>
        </xsl:for-each>
      </group>
    </xsl:for-each-group>
</xsl:function>