Как пропустить теги с такими символами, как двоеточие (:) и т. Д. В XML, используя XSLT.? - PullRequest
Новая
       40

Как пропустить теги с такими символами, как двоеточие (:) и т. Д. В XML, используя XSLT.?

0 голосов
/ 02 мая 2019

Я использую XSLT 1.0 для преобразования входного XML в желаемый вывод, но не могу этого сделать. Код XSlt должен пропускать теги с ":". Пожалуйста, помогите мне здесь.

У меня есть входной XML: - 

<Request name="BXML">
    <first>10</first>
    <second>20</second>
    <third>:</third>
    <fourth>:::</fourth>
</Request>

Я хочу, чтобы вывод XML был таким: - 

<Request name="BXML">
    <first>10</first>
    <second>20</second>
</Request>

Ответы [ 2 ]

0 голосов
/ 02 мая 2019

Чтобы удалить любой элемент, содержащий двоеточие:

XSLT 1.0 

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="*[contains(text(), ':')]"/>

</xsl:stylesheet>

Чтобы удалить любой элемент, который содержит только двоеточия:

XSLT 1.0 

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="*[not(translate(., ':', ''))]"/>

</xsl:stylesheet>
0 голосов
/ 02 мая 2019

Вы можете использовать translate для достижения того же, что и ниже: 

<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" omit-xml-declaration="no" indent="yes" />
<xsl:strip-space elements="*" />

<xsl:template match="node() | @*">
    <xsl:copy>
        <xsl:apply-templates select="node() | @*" />
    </xsl:copy>
</xsl:template>

<xsl:template match="Request">
    <Request>
        <xsl:apply-templates select="@*" />
        <xsl:for-each select="*">
            <xsl:if test="translate(., ':', '') != ''">
                <xsl:copy>
                    <xsl:apply-templates />
                </xsl:copy>
            </xsl:if>
        </xsl:for-each>
    </Request>
</xsl:template>

</xsl:stylesheet>

http://xsltfiddle.liberty -development.net / gWvjQfC

Примечание: Функция translate заменяет отдельные символы строки другими отдельными символами. Таким образом, здесь в этом случае translate() заменит каждый символ ':' (двоеточие) на символ '' (пустой) и проверяет, содержит ли тег текст или он пуст. На основании этого он будет заполнять теги.

...