Delphi - предварительный просмотр Rave отчета на форме

Question

Как мне просмотреть предварительный отчет в форме Delphi? У меня есть элемент управления страницы с 2 страницами: на первой пользователь вводит некоторые данные (имя, адрес ...), и я хочу на второй странице просмотреть отчет, созданный с данными с первой страницы.

Answer 1

Вы можете отобразить предварительный просмотр для любого TScrollBox с TRvRenderPreview:

С TRvSystem:

   RvRenderPreview1.ScrollBox := ScrollBox1; // a scrollbox on a TTabSheet

   RvSystem1.DefaultDest := rdFile;
   RvSystem1.SystemSetups := RvSystem1.SystemSetups - [ssAllowSetup];

   RvSystem1.RenderObject := RvRenderPreview1;
   RvSystem1.DoNativeOutput := false;

   RvSystem1.Execute;

Answer 2

Вы можете использовать компонент TRvNDRWriter вместо TRvSystem.

procedure TForm1.Button1Click(Sender: TObject);
begin
  RvProject1.Execute;
  RvRenderPreview1.Render;
end;

procedure TForm1.FormCreate(Sender: TObject);
var
  ms: TMemoryStream;
begin
//  RvNDRWriter1.StreamMode := smUser;
//  RvRenderPreview1.ScrollBox := ScrollBox1;
  ms := TMemoryStream.Create;
  RvNDRWriter1.Stream := ms;
  RvRenderPreview1.NDRStream := ms;
end;

Answer 3

Использование TRvProject + TRvNDRWriter + TRvRenderPreview + TMemoryStream + TScrollBox

procedure TForm1.FormCreate(Sender: TObject);
begin
  FNdrStream := TMemoryStream.Create;
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  FNdrStream.Free;
end;

procedure TForm1.btnPreviewClick(Sender: TObject);
begin
  //load report project file. You can use stored RAV instead
  rvProject.ProjectFile := 'C:\ExecutaveisGerados\Exemplos\sampleRave\sampleRave.rav';
  rvProject.Open;

  //tells rave we will write the report result to a NDR
  rvProject.Engine := rvNdrWriter;

  //ensure empty memory stream
  FNdrStream.Clear;

  //tells NDRWriter where to store ndr file (memory stream)
  rvNdrWriter.StreamMode := smUser;
  rvNdrWriter.Stream := FNdrStream;

  //execute the report using the NDRWriter. Now the Stream holds the NDR file
  rvProject.Execute;

  //tells RenderPreview where to display
  rvRenderPreview.ScrollBox := sbReportPreview;

  //display NDR file from memory stream
  rvRenderPreview.Render(FNdrStream);
end;

Answer 4

Я использовал предварительный просмотр, это не совсем то же самое, но в моем приложении этого было достаточно. Я не знаю, возможно ли это встроить в управление страницей.