Xslt отличный выбор / сгруппировать по

Question

<statisticItems>
    <statisticItem id="1" frontendGroupId="2336" caseId="50264"  />
    <statisticItem id="2" frontendGroupId="2336" caseId="50264"  />
    <statisticItem id="3" frontendGroupId="2337" caseId="50265"  />
    <statisticItem id="4" frontendGroupId="2337" caseId="50266"  />
    <statisticItem id="5" frontendGroupId="2337" caseId="50266"  />
</statisticItems>

<?xml version="1.0" encoding="utf-8"?>
  <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" omit-xml-declaration="yes"/>

  <xsl:key name="statistic-by-frontendGroupId" match="statisticItem" use="@frontendGroupId" />

  <xsl:for-each select="statisticItems/statisticItem[count(.|key('statistic-by-frontendGroupId', @frontendGroupId)[1]) = 1]">
       <xsl:value-of select="@frontendGroupId"/>
  </xsl:for-each>

Что я сделал, так это проехал все районы frontendGroupIds. То, что я хотел бы сделать сейчас, это подсчитать все регистры CaseId для каждого района frontendGroupId, но я не могу заставить эту работу работать. Может кто-нибудь помочь мне здесь, плз?

Answer 1

Вы были близки:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:output method="text" />

  <xsl:key 
    name="statistic-by-frontendGroupId" 
    match="statisticItem" 
    use="@frontendGroupId" 
  />

  <xsl:template match="statisticItems">
    <xsl:for-each select="
      statisticItem[
        count(
          . | key('statistic-by-frontendGroupId', @frontendGroupId)[1]
        ) = 1
      ]
    ">
      <xsl:value-of select="@frontendGroupId"/>
      <xsl:value-of select="' - '"/>
      <!-- simple: the item count is the node count of the key -->
      <xsl:value-of select="
        count(
          key('statistic-by-frontendGroupId', @frontendGroupId)
        )
      "/>
      <xsl:value-of select="'&#10;'"/>
    </xsl:for-each>
  </xsl:template>

</xsl:stylesheet>

В результате:

2336 - 2
2337 - 3

---

РЕДАКТИРОВАТЬ - О, я вижу, вы хотите четкий счет в группе. Это будет:

<!-- the other key from the above solution is still defined -->

<xsl:key 
  name="kStatisticItemByGroupAndCase" 
  match="statisticItem" 
  use="concat(@frontendGroupId, ',', @caseId)"
/>

<xsl:template match="statisticItems">
  <xsl:for-each select="
    statisticItem[
      count(
        . | key('kStatisticItemByGroup', @frontendGroupId)[1]
      ) = 1
    ]
  ">
    <xsl:value-of select="@frontendGroupId"/>
    <xsl:value-of select="' - '"/>
    <xsl:value-of select="
      count(
        key('kStatisticItemByGroup', @frontendGroupId)[
          count(
            . | key('kStatisticItemByGroupAndCase', concat(@frontendGroupId, ',', @caseId))[1]
          ) = 1
        ]
      )
    "/>
    <xsl:value-of select="'&#10;'"/>
  </xsl:for-each>
</xsl:template>

Что выглядит (по общему признанию) немного пугающе. Выводит:

2336 - 1
2337 - 2

Основное выражение:

count(
  key('kStatisticItemByGroup', @frontendGroupId)[
    count(
      . | key('kStatisticItemByGroupAndCase', concat(@frontendGroupId, ',', @caseId))[1]
    ) = 1
  ]
)

сводится к:

Подсчитайте узлы из "key('kStatisticItemByGroup', @frontendGroupId)", которые удовлетворяют следующему условию: они являются первыми в соответствующей группе "kStatisticItemByGroupAndCase".

Если присмотреться, вы обнаружите, что это не сложнее, чем то, что вы уже делаете. : -)

---

РЕДАКТИРОВАТЬ: последний совет. Лично я нахожу это намного более выразительным, чем приведенные выше выражения, потому что оно подчеркивает равенство узлов намного больше, чем подход "count(.|something) = 1":

count(
  key('kStatisticItemByGroup', @frontendGroupId)[
    generate-id()
    =
    generate-id(
      key('kStatisticItemByGroupAndCase', concat(@frontendGroupId, ',', @caseId))[1]
    )
  ]
)

Результат тот же.

Answer 2

Вы пытаетесь отсортировать с помощью страшного метода 'MUENCHIAN' - что я нашел настолько запутанным, что не стоит пытаться - поэтому я разработал свой собственный метод.

Использует два преобразования вместо одного.

Первый сортирует данные в правильном порядке на основе ваших требований к группировке - ваши образцы данных уже в правильном порядке, поэтому я оставлю это вне этого объяснения (спросите, нужна ли вам помощь здесь)

Второе преобразование выполняет группировку, просто сравнивая один узел с другим:

    <?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl"
>
    <xsl:output method="xml" indent="yes"/>


    <xsl:template match="statisticItems">
        <groupedItem>
            <xsl:apply-templates select="statisticItem"></xsl:apply-templates>
        </groupedItem>
    </xsl:template>

    <xsl:template match="statisticItem">
        <xsl:choose>

            <xsl:when test="position()=1">
                <xsl:apply-templates select="@frontendGroupId" />
            </xsl:when>

            <xsl:when test="@frontendGroupId!=preceding-sibling::statisticItem[1]/@frontendGroupId">
                <xsl:apply-templates select="@frontendGroupId" />
            </xsl:when>

        </xsl:choose>

        <xsl:apply-templates select="@caseId" />


    </xsl:template>

<xsl:template match="@frontendGroupId">
    <group>
        <xsl:variable name="id" select="." ></xsl:variable>
        <xsl:attribute name="count">
            <xsl:value-of select="count(//statisticItem/@frontendGroupId[.=$id])"/>
        </xsl:attribute>        
        <xsl:value-of select="." />
    </group>
</xsl:template>

    <xsl:template match="@caseId">
        <value>
            <xsl:value-of select="." />
        </value>
    </xsl:template>

</xsl:stylesheet>

С помощью этого метода вы можете углубиться в несколько групп и при этом иметь поддерживаемый код.