Гнуплот, столбцы в гистограмме перекрываются, не могут быть разделены, почему

Question

Я попытался построить лист данных, подобный этому, от Gnuplot.

Area_height MIC PCC_SQRT    
Power   0.734852672 0.618902589 1
"Powder size (D90)" 0.712130033 0.702902099 2
"Powder size (D50)" 0.712130033 0.384749485 2
"Powder size (D10)" 0.712130033 0.448956759 2
Speed   0.590181886 0.582894451 1
"Energy density"    0.519402585 0.598153661 1
Cr  0.44654505  0.584812588 4
Liquidus    0.44654505  0.584812588 3
Ni  0.44654505  0.584812588 4
Mn  0.44654505  0.584812588 4
Mo  0.44654505  0.584812588 4

Столбец 4 используется для определения цветов для панели.

Я построил с помощью следующих команд:

set style data histograms

plot "new/Area_height_MIC_PCC_New.txt" using 0:2:4:xtic(1) \
with boxes lc variable fill pattern 1, "" using 0:3:4:xtic(1) \
with boxes lc variable fill solid 1

или

set style histogram clustered

plot "new/Area_height_MIC_PCC_New.txt" using 0:2:4:xtic(1) \
with boxes lc variable fill pattern 1, "" using 0:3:4:xtic(1) \
with boxes lc variable fill solid 1

, но полученная цифра такая,

столбцы в сплошной и в шаблоне перекрываются.Это не то, что я хочу.Я хочу, чтобы они отображались рядом друг с другом.

Может кто-нибудь сказать мне, в чем проблема?

Answer 1

у тебя почти было это.Вы должны сдвинуть прямоугольники в некотором направлении.Это вы можете сделать, например, ($0-0.2) и ($0+0.2).

Код:

### box plot with color from column
reset session

$Data <<EOD
# Area_height MIC PCC_SQRT
Power   0.734852672 0.618902589 1
"Powder size (D90)" 0.712130033 0.702902099 2
"Powder size (D50)" 0.712130033 0.384749485 2
"Powder size (D10)" 0.712130033 0.448956759 2
Speed   0.590181886 0.582894451 1
"Energy density"    0.519402585 0.598153661 1
Cr  0.44654505  0.584812588 4
Liquidus    0.44654505  0.584812588 3
Ni  0.44654505  0.584812588 4
Mn  0.44654505  0.584812588 4
Mo  0.44654505  0.584812588 4
EOD

set xrange[-0.5:]
set yrange[0:]
set boxwidth 0.3
set xtics rotate by 45 right offset first 0.2
plot $Data u ($0-0.2):2:4:xtic(1) w boxes lc var fill pattern 1, \
     '' u  ($0+0.2):3:4 w boxes lc var fill solid 1.0
### end of code

Результат: