Query Subset из двух вкладок возвращает только # N / A

Question

Я пытаюсь объединить две вкладки данных для планирования распорядка дня.Одна вкладка предназначена для повторяющихся задач, а другая - для специальных задач.Данные на вкладках в основном аналогичны, за исключением того, что на Листе 1 Col4 - это день недели, тогда как на Листе 2 - Col4 - это дата

. Я бы хотел выбрать текущий день недели и получить запрос возврата.все повторяющиеся задачи на этот день, а также любые специальные задачи на эту конкретную дату

Я могу вернуть оба набора данных по отдельности, однако не могу получить запрос на возврат обоих подмножеств вместе

Sheet1 Data
ID,TASK NAME,LOCATION,TASK DAY
REC1,Task 1,Office,Monday
REC2,Task 2,Office,Tuesday
REC3,Task 3,Field,Wednesday
REC4,Task 4,Office,Thursday
REC5,Task 5,Field,Friday
REC6,Task 6,Field,Monday
REC7,Task 7,Field,Tuesday

---

Sheet2 Data
ID,TASK NAME,LOCATION,TASK DATE
ADH1,AdHoc 1,Office,25/Jun/2019
ADH2,AdHoc 2,Office,26/Jun/2019
ADH3,AdHoc 3,Field,27/Jun/2019
ADH4,AdHoc 4,Office,28/Jun/2019
ADH5,AdHoc 5,Field,29/Jun/2019
ADH6,AdHoc 6,Field,30/Jun/2019
ADH7,AdHoc 7,Field,1/Jul/2019

Это извлекает данные из листа 1 на основе дня недели в ячейке J1

=query({Sheet1!A:D}, "select Col1,Col2,Col3,Col4 where Col4 = """&J1&""" ",0)

Это извлекает данные из листа 2 на основе today()

=query({Sheet2!A:D}, "select Col1,Col2,Col3,Col4 where Col4 = date '" & text(today(),"yyyy-mm-dd") & "' ",0)

Думал, что это сработает, но просто возвращает пустой набор

=query({Sheet2!A:D;Sheet1!A:D}, "select Col1,Col2,Col3,Col4 where Col4 = date '" & text(today(),"yyyy-mm-dd") & "' OR Col4="""&J1&""" and Col1<>'' ",0)

Когда J1 = Tuesday и дата = 25/Jun/2019, я должен получить

ID,TASK NAME,LOCATION,TASK DAY
ADH1,AdHoc 1,Office,25/Jun/2019
REC2,Task 2,Office,Tuesday
REC7,Task 7,Field,Tuesday

, новместо этого просто получите #N/A

Answer 1

Может быть слишком поздно, но проблема была в столбце даты после преобразования его в текстовый запрос, также работает:

 =query({Sheet2!A:D; Sheet1!A:D}, "select Col2,Col1,Col3,Col4 where (Col4='"&Sheet1!J1&"' OR Col4 = '" & to_text(today()) & "')",0)

Answer 2

У тебя почти было это.
Вместо того, чтобы помещать массив в запросы; поместите запросы в массив.

---

={QUERY(Sheet1!A:D, "SELECT A, B, C, D WHERE D = """&J1&""" ");
  QUERY(Sheet2!A2:D, "SELECT A, B, C, D WHERE D = date '" & text(today(),"yyyy-mm-dd") & "'")}

---

Кредит - Объединение вывода нескольких запросов на одном листе :