Получение «Удаленный сервер не существует или недоступен» в Outlook VBScript

Question

Я написал в Outlook VBScript, который загружает вложение из Outlook. Но сейчас я сталкиваюсь с ошибкой

Удаленный сервер не существует или недоступен

Я получаю эту ошибку несколько раз, а иногда и этот код выполняется без ошибок. Я смог отследить точную точку отказа. Линия

Set olns = olApp.GetNameSpace("MAPI")

Я почти все перепробовал, но не могу найти решение.

Set Arg = WScript.Arguments
Dim item1
Dim objsubject
Dim intcount
Dim i
Dim savename
Dim vTextFile
Dim filename
Dim extension
Dim t
Dim Itimestamp
Dim savefolder
Dim vSenderEmailAddress
Dim vFlagTextFileCreate

vFlagTextFileCreate = True
savefolder = "C:\Users\SANxSAxAABOTDEV\Documents\Automation Anywhere Files\Automation Anywhere\My Tasks\ThrdOutlookTest"
vTextFile = savefolder & "\File Report.txt"

Set fso = CreateObject("Scripting.FileSystemObject")
On Error Resume Next
Set olApp = GetObject(, "Outlook.Application")
If Err.Number <> 0 Then    'Could not get instance of Outlook, so create a new one
    Err.Clear
    Set olApp = CreateObject("Outlook.Application")
End If
On Error Goto 0
Set olns = olApp.GetNameSpace("MAPI")
olns.Logon "Outlook", , False, True
Set objFolder = olns.GetDefaultFolder(6)

'objFolder.InAppFolderSyncObject = True
'syc.Start
For Each item1 In objFolder.Items
    If item1.Unread = True Then
        objsubject = item1.Subject
        If InStr(UCase(objsubject) ,"RPA BOT") Then
            intCount = item1.Attachments.Count
            If intcount > 0 Then
                For i = 1 To intcount
                    If InStr(item1.Attachments(i).filename, ".xls") Then
                        t = Now()
                        'Adding timestamp to the file to make it unique
                        Itimestamp = Right("0" & Hour(t), 2) & _
                                     Right("0" & Minute(t), 2) & _
                                     Right("0" & Second(t), 2)
                        fileName   = Left(item1.Attachments(i).filename, InStr(item1.Attachments(i).filename, ".xl") - 1)
                        extension  = Right(item1.Attachments(i).filename, Len(item1.Attachments(i).filename) - InStr(item1.Attachments(i).filename, ".xl"))
                        savename   = saveFolder & "\" & fileName & "_" & Itimestamp & "." & extension
                        item1.Attachments(i).SaveAsFile savename
                        WScript.Sleep 1000
                        If item1.SenderEmailType = "SMTP" Then
                            vSenderEmailAddress = item1.SenderEmailAddress
                        ElseIf item1.SenderEmailType = "EX" Then
                            vSenderEmailAddress = item1.Sender.GetExchangeUser.PrimarySmtpAddress
                        End If 'If item1.SenderEmailType
                        'Create InfoFile If does not exist
                        If vFlagTextFileCreate = True Then
                            vFlagTextFileCreate = False
                            fso.CreateTextFile vTextFile
                        End If
                        Set ts = fso.OpenTextFile(vTextFile, 8, True, 0)
                        ts.WriteLine fileName & "_" & Itimestamp & "." & extension & "|" & item1.Subject & "|" & vSenderEmailAddress & vbLf
                        ts.Close
                    End If 'If InStr(item1.Attachments(i).filename
                Next
                'Turning the unread mail to read
                item1.Unread = False
            End If 'If intcount > 0 Then
        End If 'If Instr(objsubject ,
    End If 'If item1.Unread=True
Next
olns.Logoff
Set olns  = Nothing
Set olApp = Nothing
WScript.Quit

Я провел некоторое исследование и узнал, что эта проблема может быть вызвана тем, что сеанс Outlook уже открыт перед запуском сценария. Поэтому я добавил патч перед Set fso = CreateObject("Scripting.FileSystemObject"), чтобы убить весь сеанс outlook.exe. Я не получил никакой ошибки в течение некоторого времени. Я не знаю, правильно ли это. Буду рад узнать ваше мнение об этом.

Answer 1

Завершение сеанса outlook.exe перед созданием объекта для Outlook. Приложение решило мою ошибку.Я добавил патч перед Set fso = CreateObject ("Scripting.FileSystemObject"), чтобы убить сеансы outlook.exe.Ниже приведен патч

strComputer = "."
Set Arg  = WScript.Arguments
Process = "outlook.exe"
Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2") 
Set colProcess = objWMIService.ExecQuery ("Select * from Win32_Process Where Name like '" & Process & "%'")
For Each p in colProcess
  On Error Resume Next
          p.Terminate   
  On Error GoTo 0          
Next
SET objWMIService = Nothing
SET colProcess = Nothing