CheckTokenMembership в VB6 - сбой FreeSID в Windows 7 и Windows 2008 - PullRequest
Новая
       22

CheckTokenMembership в VB6 - сбой FreeSID в Windows 7 и Windows 2008

0 голосов
/ 16 декабря 2009

Я использую CheckTokenMembership Windows API для проверки, является ли пользователь администратором.

Вот код: 

Option Explicit

Private Const SECURITY_BUILTIN_DOMAIN_RID       As Long = &H20
Private Const DOMAIN_ALIAS_RID_ADMINS           As Long = &H220

Private Declare Function AllocateAndInitializeSid Lib "advapi32.dll" (pIdentifierAuthority As Any, ByVal nSubAuthorityCount As Byte, ByVal nSubAuthority0 As Long, ByVal nSubAuthority1 As Long, ByVal nSubAuthority2 As Long, ByVal nSubAuthority3 As Long, ByVal nSubAuthority4 As Long, ByVal nSubAuthority5 As Long, ByVal nSubAuthority6 As Long, ByVal nSubAuthority7 As Long, lpPSid As Long) As Long
Private Declare Sub FreeSid Lib "advapi32.dll" (ByVal pSid As Long)
Private Declare Function CheckTokenMembership Lib "advapi32.dll" (ByVal hToken As Long, ByVal pSidToCheck As Long, pbIsMember As Long) As Long

Private Type SID_IDENTIFIER_AUTHORITY
    Value(0 To 5)            As Byte
End Type

Private Function pvIsAdmin() As Boolean
    Dim uAuthNt         As SID_IDENTIFIER_AUTHORITY
    Dim pSidAdmins      As Long
    Dim lResult         As Long

    uAuthNt.Value(5) = 5
    If AllocateAndInitializeSid(uAuthNt, 2, SECURITY_BUILTIN_DOMAIN_RID, DOMAIN_ALIAS_RID_ADMINS, 0, 0, 0, 0, 0, 0, pSidAdmins) <> 0 Then
        If CheckTokenMembership(0, pSidAdmins, lResult) <> 0 Then
            pvIsAdmin = (lResult <> 0)
        End If
        Call FreeSid(pSidAdmins)
    End If
End Function

Проблема в том, что в Windows 7 и Windows 2008 SP2 вызов FreeSID вызывает сбой приложения. Авария прерывистая.

Кто-нибудь сталкивался с этой проблемой?

Спасибо!

EDIT:

Я просто перепроверил свой код и обнаружил, что объявил FreeSID как таковой: 

Private Declare Sub FreeSid Lib "advapi32.dll" (pSid As Long)

По сравнению с приведенным выше кодом параметр pSid здесь не помечен как ByVal. Я добавил флаг ByVal, и проблема больше не присутствует. Почему-то я не уверен, что это решило проблему. Возможно, это решило проблему?

1 Ответ

1 голос
/ 17 декабря 2009

Отделяйте pvIsAdmin в совершенно отдельный модуль и дословно копируйте объявления функций из фрагмента. В AllocateAndInitializeSid lpPSid - это ByRef. В FreeSid параметр равен ByVal.

...