Как выровнять текст в файле, чтобы он выглядел как таблица в bash на основе текстового шаблона?

Question

У меня есть следующий текст

'   14411.7647 e0       - 2647.0588 e3       + 7352.9412 e12      + 14411.7647 e123       21828.2063'
' - 2647.0588 e3       + 7352.9412 e12        7814.9002'
'   14411.7647 e0       + 14411.7647 e123       20381.3131'
'   14411.7647 e0       + 14411.7647 e123       20381.3131'
'   0.0000 e0       + 0.0000 e123       1.9293e-12'
'   14411.7647'

и я хотел бы выровнять, чтобы выглядеть как таблица, основанная на терминах eXXX. Это может быть пример вывода:

' 14411.7647 e0     - 2647.0588 e3      + 7352.9412 e12     + 14411.7647 e123   21828.2063'                 
'                   - 2647.0588 e3      + 7352.9412 e12                          7814.9002'                 
' 14411.7647 e0                                             + 14411.7647 e123   20381.3131'                 
' 14411.7647 e0                                             + 14411.7647 e123   20381.3131'                 
'     0.0000 e0                                                 + 0.0000 e123   1.9293e-12'                 
'                                                                               14411.7647'                                                                                                                                                                         

Самая важная часть - выровнять термины eXXX и их коэффициенты.

ОБНОВЛЕНИЕ: столбцы изначально разделены пробелами. Вывод может быть разделен вкладками, например.

ОБНОВЛЕНИЕ2: первая строка указывает общее количество столбцов. Нет больше столбцов, чем в первом ряду. Значение exxx во второй и последующих строках может быть таким же или не таким, как в первой строке, но вы никогда не найдете больше терминов, чем первая строка, и не будете неупорядоченными (т. Е. E12 будет всегда после e3)

Может ли это быть достигнуто с помощью awk или аналогичного?

Answer 1

$ cat tst.awk
BEGIN { OFS="\t" }
{
    # Get rid of all single quotes at the start/end of lines
    gsub(/^\047|\047$/,"")

    # Attach the +/- sign when present to the number to its right
    # to normalize how the fields are presented on each line.
    gsub(/\+ /,"+")
    gsub(/- /,"-")
}
NR==1 {
    # Consider each pair like "14411.7647 e0" to be one field with
    # "e0" as the key that determines the output order for that field
    # and "14411.7647" as the value associated with that key. Here
    # we create an array that remembers the order of the keys.
    for (i=1; i<=NF; i+=2) {
        key = $(i+1)
        fldNr2key[++numFlds] = key
    }
}
{
    # Populate an array that maps the key to its value
    delete key2val
    for (i=1; i<=NF; i+=2) {
        key = $(i+1)
        val = $i
        key2val[key] = val
    }

    # Print the values by the order of the keys
    out = ""
    for (fldNr=1; fldNr<=numFlds; fldNr++) {
        key = fldNr2key[fldNr]
        fld = ""
        if (key in key2val) {
            val = key2val[key]
            fld = val (key ~ /./ ? " " key : "")
            sub(/^[-+]/,"& ",fld) # restore the blank after a leading +/-
        }
        out = out fld (fldNr<numFlds ? OFS : "")
    }
    print "\047 " out "\047"
}

Вывод через табуляцию:

$ awk -f tst.awk file
' 14411.7647 e0 - 2647.0588 e3  + 7352.9412 e12 + 14411.7647 e123       21828.2063'
'       - 2647.0588 e3  + 7352.9412 e12         7814.9002'
' 14411.7647 e0                 + 14411.7647 e123       20381.3131'
' 14411.7647 e0                 + 14411.7647 e123       20381.3131'
' 0.0000 e0                     + 0.0000 e123   1.9293e-12'
'                               14411.7647'

Визуально табличный вывод (или использовать printfs с соответствующей шириной для каждого поля в скрипте):

$ awk -f tst.awk file | column -s$'\t' -t
' 14411.7647 e0  - 2647.0588 e3  + 7352.9412 e12  + 14411.7647 e123  21828.2063'
'                - 2647.0588 e3  + 7352.9412 e12                     7814.9002'
' 14411.7647 e0                                   + 14411.7647 e123  20381.3131'
' 14411.7647 e0                                   + 14411.7647 e123  20381.3131'
' 0.0000 e0                                       + 0.0000 e123      1.9293e-12'
'                                                                    14411.7647'

Answer 2

Похоже, что поля могут быть разделены на несколько пробелов, затем вы можете попробовать использовать FS = "*\047 *| +", таким образом, ваши окончательные ожидаемые строки (на основе NR==1) могут быть разбиты на столбцы eXXX (из *)От 1003 * до $(NF-2)), обычный столбец, если существует в $(NF-1).и $ 1, и $ NF всегда ПУСТО..

$ cat t17.1.awk
BEGIN{ FS = " *\047 *|  +"; OFS = "\t"; }

# on the first line, set up the total N = NF
# the keys and value lengths for the 'eXXX' cols 
# to sort and format fields for all rows
NR == 1 {
    N = NF
    for (i=2; i < N-1; i++) {
        n1 = split($i, a, " ")
        e_cols[i] = a[n1]
        e_lens[i] = length($i)
    }
    # the field-length of the regular column which is non eXXX-cols
    len_last = length($(NF-1))
}

{
    printf "\047 "
    # hash the e-key for field from '2' to 'NF-1'
    # include NF-1 in case the last regular column is missing
    for (i=2; i < NF; i++) {
        n1 = split($i, a, " ")
        hash[a[n1]] = $i
    }

    # print the eXXX-cols based on the order as in NR==1
    for (i=2; i < N-1; i++) {
        printf("%*s%s", e_lens[i], hash[e_cols[i]], OFS)
    }

    # print the regular column at $(NF-1) or EMPTY if it is an eXXX-cols
    printf("%*s\047\n", len_last, match($(NF-1),/ e[0-9]+$/)?"":$(NF-1))

    # reset the hash
    delete hash
}

Запустите приведенный выше скрипт, и вы получите следующий результат: (Обратите внимание, я добавил одну дополнительную строку, так что eXXX-cols + 14411.7647 e123 находится наконец строки перед трейлингом ')

$ awk -f t17.1.awk file.txt 
' 14411.7647 e0 - 2647.0588 e3  + 7352.9412 e12 + 14411.7647 e123       21828.2063'
'               - 2647.0588 e3  + 7352.9412 e12                          7814.9002'
' 14411.7647 e0                                 + 14411.7647 e123       20381.3131'
' 14411.7647 e0                                 + 14411.7647 e123       20381.3131'
'     0.0000 e0                                     + 0.0000 e123       1.9293e-12'
'                                                                       14411.7647'
'                                               + 14411.7647 e123                 '

Примечание:

• вам может понадобиться gawk чтобы "%*s" работал для printf(), в случае, если он не работает, попробуйте фиксированное число, например: printf("%18s%s", hash[e_cols[i]], OFS)

• некоторые значения в электронных полях могут иметьбольшего размера, чем соответствующий в NR == 1, чтобы исправить это, вы можете вручную указать массив для длин или просто использовать фиксированное число