Реализация через делегирование интерфейса не передается потомку - PullRequest
Новая
       23

Реализация через делегирование интерфейса не передается потомку

1 голос
/ 14 марта 2019

Рассмотрим этот интерфейс и его реализации. 

unit utest;

interface

{$MODE OBJFPC}

type

    IIntfA = interface
        procedure writeA();
    end;

    IIntfB = interface(IIntfA)
        procedure writeB();
    end;

    TADelegateClass = class(TInterfacedObject, IIntfA)
    public
        procedure writeA();
    end;

    TAClass = class(TInterfacedObject, IIntfA)
    private
        delegateA : IIntfA;
    public
        constructor create(const AInst : IIntfA);
        destructor destroy(); override;

        property A : IIntfA read delegateA implements IIntfA;
    end;

    TBClass = class(TAClass, IIntfB)
    public
        procedure writeB();
    end;

implementation

    procedure TADelegateClass.writeA();
    begin
        writeln('Implement IIntfA through delegation');
    end;

    constructor TAClass.create(const AInst : IIntfA);
    begin
        delegateA := AInst;
    end;

    destructor TAClass.destroy();
    begin
        inherited destroy();
        delegateA := nil;
    end;

    procedure TBClass.writeB();
    begin
        writeln('Implement IIntfB');
    end;

end.

Следующая программа не будет компилироваться. 

program test;

{$MODE OBJFPC}
uses
    utest;

var b : IIntfB;
begin
    b := TBClass.create(TADelegateClass.create());
    b.writeA();
    b.writeB();
end.

Free Pascal (версия 3.0.4) жалуется

Error: No matching implementation for interface method "writeA;" found.

в строке, где объявлено TBClass.

Конечно, я могу успешно скомпилировать его, внедрив writeA в TAClass или TBClass и вызвав writeA методTADelegateClass оттуда.

TAClass является конкретной реализацией интерфейса IIntfA через делегирование интерфейса, но почему TBClass, который является потомком TAClass, не считается конкретной реализацией IIntfAинтерфейс

1 Ответ

2 голосов
/ 18 марта 2019

TAClass является конкретной реализацией интерфейса IIntfA через делегирование интерфейса, но почему TBClass, который является потомком TAClass, не считается конкретной реализацией IIntfA интерфейса?

Краткий ответ: проблема не в IIntfA, а в неполном IIntfB.

Длинный ответ: Наследование интерфейса - это наследуемое наследование C ++, которое иногда не является интуитивно понятным.

В примере: 

IIntfB = interface(IIntfA)
    procedure writeB();
end;

на самом деле можно записать как 

IIntfB = interface
    procedure writeA();
    procedure writeB();
end;

При реализации нескольких интерфейсов общие части не используются повторно. Компилятор устанавливает отдельные таблицы из методов реализации, таких как: 

TADelegateClass:
   QueryInterface(IIntfA) =  Self.vtable_IIntfA
   vtable_IIntfA.writeA   <- Self.writeA

TAClass:
   QueryInterface(IIntfA) =  delegateA.vtable_IIntfA

TBClass:
   QueryInterface(IIntfA) =  inherited delegateA.vtable_IIntfA
   QueryInterface(IIntfB) =  vtable_IIntfB
   vtable_IIntfB.writeA   <- (this is missing!)
   vtable_IIntfB.writeB   <- Self.writeB

TBClass действительно не имеет реализации IIntfB.writeA. Это можно проверить, вручную назначив метод для определенного интерфейса и наблюдая за исчезновением ошибки: 

TBClass = class(TAClass, IIntfB)
public
    procedure IIntfB.writeA = writeB;
    // dummy method, shows IIntfB.writeA is missing

К сожалению, я не знаю, как сказать компилятору доступ к отображению из другого интерфейса. Кстати, у Delphi та же ошибка / недостаток.

...