Ошибки API проигрывателя YouTube as3 - PullRequest
Новая
       11

Ошибки API проигрывателя YouTube as3

1 голос
/ 23 октября 2009

Я пытаюсь заставить работать проигрыватель youtube as3 chromeless. Я следовал за примерами youtube as3 API , и вот что я получил до сих пор: 

public class Main extends Sprite 
{
    Security.allowDomain("*");

    private var player:Sprite;
    private var loader:Loader;

    public function Main():void 
    {
        if (stage) init();
        else addEventListener(Event.ADDED_TO_STAGE, init);
    }

    private function init(e:Event = null):void 
    {
        removeEventListener(Event.ADDED_TO_STAGE, init);

        loader = new Loader();
        loader.contentLoaderInfo.addEventListener(Event.INIT, onLoaderInit);
        loader.load(new URLRequest("http://www.youtube.com/apiplayer?version=3"));
    }

    private function onLoaderInit(e:Event):void
    {
        player = Sprite(loader.content);
        addChild(player);
        player.addEventListener("onReady", onPlayerReady);
        player.addEventListener("onError", onPlayerError);
        player.addEventListener("onStateChange", onPlayerStateChange);
        player.addEventListener("onPlayerQualityChange", onVideoPlaybackQualityChange);
    }

    private function onPlayerReady(e:Event):void
    {
        trace("Player ready: " + Object(e.target).Data);
        // player.loadVideoById("uad17d5hR5s");
    }
    private function onPlayerError(e:Event):void
    {
        trace("Player error: " + Object(e).Data);
    }
    private function onPlayerStateChange(e:Event):void
    {
        // trace("Player state: " + Object(e).Data);
    }
    private function onVideoPlaybackQualityChange(e:Event):void
    {
        trace("Video quality: " + Object(e).Data);
    }
}

События onPlayerReady и onStateChange запускаются, но я получаю ошибки. При трассировке объекта (e). Данные я получаю эту ошибку: ReferenceError: Error #1069: the property Data was not found for com.google.youtube.event.ExternalEvent and there is no standard value. (переведено со шведского)

При изменении на Object(e.target).Data он отслеживает «неопределенное» и Object(e.target) отслеживает «[объект SwfProxy]».

Если я попытаюсь player.loadVideoById("uad17d5hR5s");, я получу эту ошибку:

1061: Call to a possibly undefined method loadVideoById through a reference with static type flash.display:Sprite.

1 Ответ

1 голос
/ 25 октября 2009

Не думаю, что вы должны разыгрывать loader.content как Sprite. Вместо этого вы должны привести игрока к типу объекта. Переменная player предназначена только для доступа к вызовам API. С точки зрения размещения, перемещения и добавления в список отображения используйте объект Loader, содержащий объект SwfProxy. Попробуйте этот код: 

package
{
 import flash.display.*;
 import flash.events.*;
 import flash.system.Security;
 import flash.net.*;

 public class Main extends MovieClip 
 {
  Security.allowDomain("*");

  private var player:Object;
  private var loader:Loader;

  public function Main():void 
  {
   if (stage) init();
   else addEventListener(Event.ADDED_TO_STAGE, init);
  }

  private function init(e:Event = null):void 
  {
   removeEventListener(Event.ADDED_TO_STAGE, init);

   loader = new Loader();
   loader.contentLoaderInfo.addEventListener(Event.INIT, onLoaderInit);
   loader.load(new URLRequest("http://www.youtube.com/apiplayer?version=3"));
  }

  private function onLoaderInit(e:Event):void
  {
   player = Sprite(loader.content);
   addChild(loader);
   player.addEventListener("onReady", onPlayerReady);
   player.addEventListener("onError", onPlayerError);
   player.addEventListener("onStateChange", onPlayerStateChange);
   player.addEventListener("onPlayerQualityChange", onVideoPlaybackQualityChange);
  }

  private function onPlayerReady(e:Event):void
  {
   trace("Player ready: " + Object(e.target).Data);
   player.loadVideoById("uad17d5hR5s");
   player.setSize(480, 365);
  }
  private function onPlayerError(e:Event):void
  {
   trace("Player error: " + Object(e).Data);
  }
  private function onPlayerStateChange(e:Event):void
  {
   // trace("Player state: " + Object(e).Data);
  }
  private function onVideoPlaybackQualityChange(e:Event):void
  {
   trace("Video quality: " + Object(e).Data);
  }
 }
}
...