Как найти последний раз, когда определенное слово появляется как элемент в массиве в VbScript

Question

Я пытаюсь в последний раз найти строку со словом «Subtot» в массиве «arrFileLines». В настоящее время он просто просматривает и отображает каждый раз, когда он появляется, а не только в последний раз, и я пробовал множество других способов и не могу решить эту проблему.

Sub FileSubTot

    Dim arrFileLines()
    Dim choice
    choice="SUBTOT"
    i = 0
    'opens txt file and makes each line an element in an array called arrFileLines
    Set objFSO = CreateObject("Scripting.FileSystemObject")
    Set objFile = objFSO.OpenTextFile("C:\stuff\etc\etc...", 1)
    Do Until objFile.AtEndOfStream
     Redim Preserve arrFileLines(i)
     arrFileLines(i) = objFile.ReadLine
     i = i + 1
  Loop
  objFile.Close

  'iterates through the array looking for the word SUBTOT then grabs the subtotal value and compares to the (TTP)
For i = Ubound(arrFileLines) to LBound(arrFileLines) Step -1
    If InStr(arrFileLines(i), choice) <> 0 Then

    Log.Message "Found " & choice 
    Log.Message arrFileLines(i)
    Total=Split(arrFileLines(i),"     ",-1)
    Log.Message"TOTAL TO PAY: €"& Total(1)

    End If

Next

End Sub

Если «Subtot» появляется в файле несколько раз, я хочу получить его только с момента последнего появления в файле. Любая помощь с благодарностью.

Answer 1

Filter - полезная функция для такого рода вещей

' build a test string
dim a(4), i
for i = 0 to 4
    if i mod 2 = 1 then
        a(i) = "Subtot " & (i + 1)
    else
        a(i) = "Something else"
    end if
next

WScript.Echo Join(a, vbNewLine)

'reduce the array to a subset that just contains "subtot"
dim b: b = Filter(a, "subtot", true, vbTextCompare)
' use the last item in the array
i = UBound(b)
WScript.Echo b(i)

Выходы

Что-то еще
Подытог 2
Что-то еще
Подытог 4
Что-то еще

Подытог 4

Answer 2

Все, что вам нужно сделать, так как вы читаете массив в обратном направлении (от UBound до LBound), это выйти из цикла, как только вы найдете искомый текст, а не продолжать его.

Sub FileSubTot

    Dim arrFileLines()
    Dim choice
    choice="SUBTOT"
    i = 0
    'opens txt file and makes each line an element in an array called arrFileLines
    Set objFSO = CreateObject("Scripting.FileSystemObject")
    Set objFile = objFSO.OpenTextFile("C:\stuff\etc\etc...", 1)
    Do Until objFile.AtEndOfStream
        Redim Preserve arrFileLines(i)
        arrFileLines(i) = objFile.ReadLine
        i = i + 1
    Loop
    objFile.Close

    'iterates through the array looking for the word SUBTOT then grabs the subtotal value and compares to the (TTP)
    For i = Ubound(arrFileLines) to LBound(arrFileLines) Step -1
        If InStr(arrFileLines(i), choice) <> 0 Then

            Log.Message "Found " & choice 
            Log.Message arrFileLines(i)
            Total=Split(arrFileLines(i),"     ",-1)
            Log.Message "TOTAL TO PAY: €"& Total(1)
            Exit For    ' This will exit the For Loop once the choice is found
        End If

    Next

End Sub