series_fir не генерирует скользящее среднее на диаграмме понимания приложения - PullRequest
Новая
       37

series_fir не генерирует скользящее среднее на диаграмме понимания приложения

0 голосов
/ 25 июня 2019

Учитывая следующее запрос Кусто : 

range t from bin(now(), 1h)-23h to bin(now(), 1h) step 1h
| summarize t=make_list(t)
| project id='TS', val=dynamic([0,0,0,0,0,0,0,0,0,10,20,40,100,40,20,10,0,0,0,0,0,0,0,0]), t
| extend 5h_MovingAvg=series_fir(val, dynamic([1,1,1,1,1])),
     5h_MovingAvg_centered=series_fir(val, dynamic([1,1,1,1,1]), true, true)
| render timechart

Я не могу получить представление о приложении, чтобы фактически нарисовать линии скользящего среднего, показанные в этом документе

Я также пытался применить статью к одному из наших реальных приложений, и мне тоже не повезло. Там нет ошибок или что-то, что могло бы дать понять, почему скользящие средние не рисуются. Я предполагаю, что где-то есть настройка, которую, скорее всего, нужно установить. Вот мой пользовательский запрос: 

let timeGrain=1d;
let ago = ago(7d);
let mAvgParm = repeat(1, 5);
let dataset=requests
// additional filters can be applied here
| where timestamp >= ago and cloud_RoleName == "recalculateordercombination" and resultCode == 500
| where client_Type != "Browser" ;
// calculate failed request count for all requests
dataset
| make-series dailyFailure=sum(itemCount) default=0 on timestamp in range(ago, now(), timeGrain) by resultCode
// render result in a chart
| extend SMA = series_fir(dailyFailure, mAvgParm)
| render timechart

Чего не хватает этим запросам, чтобы нарисовать линии скользящего среднего с помощью series_fir?

ссылки на статьи, использованные в моем исследовании

1 Ответ

0 голосов
/ 25 июня 2019

Веб-клиенты для обеих служб различны, и это также верно для их логики рендеринга.

В Azure Data Explorer (Kusto) вы можете просто использовать render timechart для данных временных рядов (что являетсянабирается как dynamic).

В других случаях вам может понадобиться сначала mv-expand серия ( ссылка на документ ) перед ее рендерингом.

Вотпример, который соответствует первому запросу в вашем вопросе: 

range t from bin(now(), 1h)-23h to bin(now(), 1h) step 1h
| summarize t=make_list(t)
| project id='TS', val=dynamic([0,0,0,0,0,0,0,0,0,10,20,40,100,40,20,10,0,0,0,0,0,0,0,0]), t
| extend 5h_MovingAvg=series_fir(val, dynamic([1,1,1,1,1])),
     5h_MovingAvg_centered=series_fir(val, dynamic([1,1,1,1,1]), true, true)
| mv-expand val to typeof(long), t to typeof(datetime), 5h_MovingAvg to typeof(long), 5h_MovingAvg_centered to typeof(long)
| project t, 5h_MovingAvg, 5h_MovingAvg_centered, val
| render timechart
...