Terraform Shared VPC на GCP - статический внутренний IP-адрес - PullRequest
Новая
       21

Terraform Shared VPC на GCP - статический внутренний IP-адрес

0 голосов
/ 26 марта 2019

Я пытаюсь написать автоматизацию для развертывания экземпляров в общем VPC на GCP. У меня есть проект сети хоста и сервисный проект. Я могу создать ресурс статического внутреннего IP-адреса в хост-проекте (ресурс "google_compute_address" "internal"), в котором я указываю хост-проект VPC (NET_HUB_PROJ), но я не могу использовать его при создании экземпляра. Я получаю следующую ошибку: 

google_compute_instance.compute: Error creating instance: googleapi: 
Error 400: Invalid value for field 
'resource.networkInterfaces[0].networkIP': '10.128.0.10'. IP address 
'projects/prototype-network-hub/regions/us-central1/addresses/bh-int- 
ip' (10.128.0.10) is reserved by another project., invalid

Мой вычислительный модуль: 

data "google_compute_image" "image" {
  name    = "${var.IMAGE_NAME}"
  project = "${var.IMAGE_PROJECT}"
}

resource "google_compute_address" "internal" {
  name         = "${var.NAME}-int-ip"
  address_type = "INTERNAL"
  address      = "${var.PRIVATE_IP}"
  subnetwork   = "${var.NET_HUB_SUBNETWORK}"
  region       = "${var.NET_HUB_REGION}"
  project      = "${var.NET_HUB_PROJ}"
}

resource "google_compute_address" "external" {
  count        = "${var.EXT_IP_CREATE ? 1 : 0}"
  name         = "${var.NAME}-ext-ip"
  address_type = "EXTERNAL"
  region       = "${var.REGION}"
}

resource "google_compute_instance" "compute" {
   depends_on  = ["google_compute_address.external"] 
   name = "${var.NAME}"
   machine_type = "${var.MACHINE_TYPE}"
   zone = "${var.ZONE}"
   can_ip_forward = "${var.CAN_IP_FORWARD}"
   deletion_protection ="${var.DELETION_PROTECTION}"
   allow_stopping_for_update = "${var.ALLOW_STOPPING_FOR_UPDATE}"
   tags = ["allow-ssh"]
   metadata = {
    "network" = "${var.NETWORK}"
    "env" = "${var.ENV}"
    "role" = "${var.ROLE}"
    "region" = "${var.REGION}"
    "zone" = "${var.ZONE}"
   }
   labels = {
    "network" = "${var.NETWORK}"
    "env" = "${var.ENV}"
    "role" = "${var.ROLE}"
    "region" = "${var.REGION}"
    "zone" = "${var.ZONE}"
    }
   boot_disk {
      device_name = "${var.NAME}"
      auto_delete = "${var.BOOT_DISK_AUTO_DELETE}"
      initialize_params {
      size = "${var.BOOT_DISK_SIZE}"
      type = "${var.BOOT_DISK_TYPE}"
      image = "${data.google_compute_image.image.self_link}"
      }
   }

network_interface {
   network_ip = "${google_compute_address.internal.address}"
   subnetwork_project = "${var.NET_HUB_PROJ}"
   subnetwork   = "projects/prototype-network-hub/regions/us-central1/subnetworks/custom"
   access_config {
      nat_ip = "${element(concat(google_compute_address.external.*.address, list("")), 0)}"
   }
}
service_account {
   scopes = ["service-control", "service-management", "logging-write", "monitoring-write", "storage-ro", "https://www.googleapis.com/auth/trace.append" ]
   }
}

Конечной целью было бы достичь следующего: enter image description here

1 Ответ

1 голос
/ 03 апреля 2019

РЕДАКТИРОВАТЬ (новый ответ) : Согласно документации GCP, статический внутренний IP-адрес должен принадлежать сервисному проекту (а не проекту хост-сети, как в вашем коде), если вы хотите зарезервировать внутренний IP-адрес для общего VPC в другом проекте. Посмотреть здесь: https://cloud.google.com/vpc/docs/provisioning-shared-vpc#reserve_internal_ip

Видение shared-vpc вряд ли можно найти в вашей кодовой базе TF, вам придется использовать data, чтобы получить self_link подсети для использования для google_compute_address. Примерно так: 

data "google_compute_subnetwork" "subnet" {
  name    = "${var.NET_HUB_SUBNETWORK}"
  project = "${var.NET_HUB_PROJ}"
  region  = "${var.NET_HUB_REGION}"
}

resource "google_compute_address" "internal" {
  name         = "${var.NAME}-int-ip"
  address_type = "INTERNAL"
  address      = "${var.PRIVATE_IP}"
  subnetwork   = "${data.google_compute_subnetwork.subnet.self_link}"
}

Это должно создать ресурс под вашим сервисным проектом, но с адресом в указанной подсети.

При развертывании своего экземпляра вы должны увидеть его в столбце internal_ip на вкладке экземпляров виртуальной машины для назначенного экземпляра.

(старый ответ для потомков) : К сожалению, google_compute_address не содержит subnetwork_project как google_compute_instance. Для устранения этой проблемы необходимо указать полный URL-адрес для поля subnetwork в google_compute_address. Примерно так: 

resource "google_compute_address" "internal" {
  name         = "${var.NAME}-int-ip"
  address_type = "INTERNAL"
  address      = "${var.PRIVATE_IP}"
  subnetwork   = "https://www.googleapis.com/compute/v1/projects/${var.NET_HUB_PROJ}/regions/${var.NET_HUB_REGION}/subnetworks/${var.NET_HUB_SUBNETWORK}"
}
...