переключать видимость с помощью сочетания клавиш

Question

Как я могу переключать видимость панели поиска с помощью сочетаний клавиш?

По умолчанию я хочу, чтобы панель поиска была скрыта.Однако затем пользователь нажимает Ctrl + F, я хочу, чтобы это было видно.Когда они затем нажимают кнопку «X», она снова ее скрывает.

MyContent.qml

import QtQuick 2.7
import QtQuick.Controls 2.0
import QtQuick.Layouts 1.3


ColumnLayout {
    anchors.fill: parent

    RowLayout {
        width: parent.width
        visible: true

        TextField {
            text: ""
            placeholderText: qsTr("Search...")
            selectByMouse: true
            Layout.fillWidth: true
        }

        Button {
            text: "x"
        }
    }


    Label {
        wrapMode: Text.Wrap
        font.pixelSize: Qt.application.font.pixelSize * 1.1

        Layout.fillWidth: true
        Layout.fillHeight: true

        text: qsTr("<h1>Stuff goes here</h1><p>this is just some sample text</p>")
    }

}

main.qml

import QtQuick 2.7
import QtQuick.Controls 2.0
import QtQuick.Layouts 1.3

ApplicationWindow {
    visible: true
    width: 640
    height: 480
    title: qsTr("Hello World")

    MyContent {
        anchors.centerIn: parent
    }
}

Answer 1

Вы должны использовать компонент Shortcut:

// ...
RowLayout {
    id: row
    width: parent.width
    visible: false

    Shortcut {
        sequence: "Ctrl+F"
        onActivated: {
            row.visible = true
            tf.focus = true
        }
    }

    TextField {
        id: tf
        text: ""
        placeholderText: qsTr("Search...")
        selectByMouse: true
        Layout.fillWidth: true
    }

    Button {
        text: "x"
        onClicked: row.visible = false
    }
}
// ...