Динамический диапазон VBA

Question

Довольно новый для VBA.У меня есть макрос, который я хотел бы изменить, чтобы иметь возможность работать с любым количеством строк, содержащих данные, а не в жестко заданном значении (46).

Sub test1calc()
'
' test1calc Macro
'

'
'1 - UNSTRESSED POSTED PRODUCT LEVEL BREAKDOWN SUMMED AT NETTING SET
    Columns("AS:AS").Select
    Selection.Insert Shift:=xlToRight, CopyOrigin:=xlFormatFromLeftOrAbove
    Range("AS1").Select
    Selection.Interior.Pattern = xlSolid
    Selection.Interior.PatternColorIndex = 2
    Selection.Interior.Color = 65535
    ActiveCell.FormulaR1C1 = "Unstressed Posted Total"
    Range("AS2").Select
    ActiveCell.FormulaR1C1 = "=SUM(RC[-30]:RC[-1])"
    Range("AS2").Select
    Selection.AutoFill Destination:=Range("AS2:AS46")
    Range("AS2:AS46").Select
    ActiveSheet.Calculate
    Selection.Copy
    Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
        :=False, Transpose:=False
    Application.CutCopyMode = False
End Sub

Answer 1

Я предполагаю, что вы хотите заполнить строки, где есть существующие данные слева, а не миллионы строк, которые существуют в вашей рабочей таблице.

Если это так, я считаю, что ваш код можно упростить доследующее:

Sub test1calc()

    '1 - UNSTRESSED POSTED PRODUCT LEVEL BREAKDOWN SUMMED AT NETTING SET

    Columns("AS:AS").Insert Shift:=xlToRight, CopyOrigin:=xlFormatFromLeftOrAbove

    With Range("AS1")
        .Interior.Pattern = xlSolid
        .Interior.PatternColorIndex = 2
        .Interior.Color = 65535
        .Value = "Unstressed Posted Total"
    End With

    With Range("AS2:AS" & Range("O" & Rows.Count).End(xlUp).Row)
         .FormulaR1C1 = "=SUM(RC[-30]:RC[-1])"
         .Value = .Value
    End With

End Sub