Как отправить номер через серийный номер в Arduino? - PullRequest
Новая
       78

Как отправить номер через серийный номер в Arduino?

0 голосов
/ 30 мая 2019

Я пытаюсь отправить числовое значение по серийному номеру в Arduino для управления индивидуально адресуемой светодиодной полосой. С помощью Arduino IDE "Serial Monitor" я могу отправить номер на световую полосу без проблем. Однако, когда я пытаюсь сделать это извне, читая текстовый файл при обработке, он не проходит.

После некоторой отладки я вижу, что Processing имеет номер права и хранится в переменной. Однако световой индикатор всегда будет светиться только на светодиоде, а не на указанном числе.

Код обработки: 

import processing.serial.*;
import java.io.*;


Serial myPort;  // Create object from Serial class

void setup() 
{
  size(200,200); //make our canvas 200 x 200 pixels big
  String portName = Serial.list()[0]; //change the 0 to a 1 or 2 etc. to match your port
  myPort = new Serial(this, portName, 9600);
}
void draw() 
{
  while(true) {
  // Read data from the file
  {
    String[] lines = loadStrings("Lifenumber.txt");
    int number = Integer.parseInt(lines[0]);
    println(number);
    myPort.write(number);
    delay(5000);
  }
  }
}

Arduino код: 

if ( Serial.available()) // Check to see if at least one character is available
  {
    char ch = Serial.read();
      if(index <  3 && ch >= '0' && ch <= '9'){
      strValue[index++] = ch; 
      }
      else
      {
        Lnum = atoi(strValue);
        Serial.println(Lnum);
        for(i = 0; i < 144; i++)
        {
          leds[i] = CRGB::Black; 
          FastLED.show(); 
          delay(1);

        }
        re = 1;
        index = 0;
        strValue[index] = 0; 
        strValue[index+1] = 0; 
        strValue[index+2] = 0; 
    }
  }

Я хочу, чтобы программа считывала число из текстового файла и загоралась этим количеством светодиодов на 144-полосной подсветке.

1 Ответ

0 голосов
/ 31 мая 2019

Вот пара комментариев к вашему коду, которые должны помочь в улучшении в будущем.Очень важно сформировать хорошие привычки кодирования на ранних этапах: это сделает вашу жизнь намного проще (я говорю в основном программистом-самоучкой, который начинал с флеш-памяти, поэтому я знаю, что такое беспорядок и хакерство;)) 

import processing.serial.*;
//import java.io.*; // don't include unused imports


Serial myPort;  // Create object from Serial class

void setup() 
{
  size(200,200); //make our canvas 200 x 200 pixels big
  String portName = Serial.list()[0]; //change the 0 to a 1 or 2 etc. to match your port
  // handle error initialising Serial
  try{
    myPort = new Serial(this, portName, 9600);
  }catch(Exception e){
    println("Error initializing Serial port " + portName);
    e.printStackTrace();
  }
}
void draw() 
{
  // don't use blocking while, draw() already gets called continuously
  //while(true) {
  // Read data from the file
  //{
    // don't load the file over and over again
    String[] lines = loadStrings("Lifenumber.txt");
    int number = Integer.parseInt(lines[0]);// int(lines[0]) works in Processing, but the Java approach is ok too
    println("parsed number: " + number);
    if(myPort != null){
      myPort.write(number);
    }
    // don't use blocking delays, ideally not even in Arduino
    //delay(5000);
  //}
  //}
}

Вот версия кода обработки, который загружает текстовый файл, анализирует целое число, а затем отправляет его в последовательный порт только один раз (если все в порядке, в противном случае базовая проверка ошибок должна выявить отладочную информацию): 

import processing.serial.*;
Serial myPort;  // Create object from Serial class

void setup() 
{
  size(200,200); //make our canvas 200 x 200 pixels big
  String portName = Serial.list()[0]; //change the 0 to a 1 or 2 etc. to match your port
  // handle error initialising Serial
  try{
    myPort = new Serial(this, portName, 9600);
  }catch(Exception e){
    println("Error initializing Serial port " + portName);
    e.printStackTrace();
  }
  // Read data from the file
  try{
    String[] lines = loadStrings("Lifenumber.txt");
    int number = Integer.parseInt(lines[0]);
    println("parsed number: " + number);
    // validate the data, just in case something went wrong
    if(number < 0 && number > 255){
      println("invalid number: " + number + ", expecting 0-255 byte sized values only");
      return;
    }
    if(myPort != null){
      myPort.write(number);
    }
  }catch(Exception e){
    println("Error loading text file");
    e.printStackTrace();
  }
}
void draw() 
{
  // display the latest value if you want
}

// add a keyboard shortcut to reload if you need to

Ваша полоса имеет 144 светодиода (менее 255), которые хорошо вписываются в один байт, и это то, что посылает эскиз обработки

На стороне Arduino нет ничего слишком сумасшедшего, если вы проверяете данныевсе должно быть в порядке: 

#include "FastLED.h"

#define NUM_LEDS 64 
#define DATA_PIN 7
#define CLOCK_PIN 13

// Define the array of leds
CRGB leds[NUM_LEDS];

int numLEDsLit = 0;

void setup() {
  Serial.begin(9600);
  Serial.println("resetting");
  LEDS.addLeds<WS2812,DATA_PIN,RGB>(leds,NUM_LEDS);
  LEDS.setBrightness(84);
}

void loop() {
  updateSerial();
  updateLEDs();
}

void updateSerial(){
  // if there's at least one byte to read
  if( Serial.available() > 0 )
  {
    // read it and assign it to the number of LEDs to light up
    numLEDsLit = Serial.read();
    // constrain to a valid range (just in case something goes funny and we get a -1, etc.)
    numLEDsLit = constrain(numLEDsLit,0,NUM_LEDS);
  }  
}

// uses blacking delay
void updateLEDs(){
  // for each LED
  for(int i = 0; i < 144; i++)
  {
    // light up only the number of LEDs received via Serial, turn the LEDs off otherwise
    if(i < numLEDsLit){
      leds[i] = CRGB::White;
    }else{
      leds[i] = CRGB::Black;
    }
    FastLED.show(); 
    delay(1);  
  }
}

Отрегулируйте контакты / светодиодные чипсеты / и т.д.в зависимости от ваших реальных физических настроек.

...