Excel UDF - VLOOKUP с частичным совпадением и объединением результатов в одной ячейке - PullRequest
Новая
       13

Excel UDF - VLOOKUP с частичным совпадением и объединением результатов в одной ячейке

0 голосов
/ 27 марта 2019

У меня есть 2 столбца данных и третий столбец условий запроса.Термины запроса имеют частичное, но точное совпадение в столбце 1 данных («Данные1»).Я хочу найти все совпадения для термина запроса в столбце «Данные1» и вернуть значения, разделенные запятыми, из столбца «Данные2».

См. Изображение.

Уже существует UDF для аналогичногопроблема на этом сайте, но это не совсем то, что я хочу.

Excel: возвращать несколько совпадений в одной ячейке при частичном совпадении

Большое спасибо затвоя помощь.С наилучшими пожеланиями, Маной Изображение данных

Я пробовал этот UDF: 

Public Function ConcatPartLookUp(rngInput As Range, rngSource As Range, Optional strDelimiter As String, Optional blCaseSensitive)
Dim rng As Range

If strDelimiter = "" Then strDelimiter = "|"
If IsMissing(blCaseSensitive) Then
    blCaseSensitive = False
Else
    blCaseSensitive = True
End If

For Each rng In rngSource
    If blCaseSensitive Then
        If InStr(1, rng.Value, rngInput.Value, vbBinaryCompare) > 0 Then ConcatPartLookUp = ConcatPartLookUp & strDelimiter & rng.Value
    Else
        If InStr(1, rng.Value, rngInput.Value, vbTextCompare) > 0 Then ConcatPartLookUp = ConcatPartLookUp & strDelimiter & rng.Value
    End If
Next

If Len(ConcatPartLookUp) > 0 Then ConcatPartLookUp = Mid(ConcatPartLookUp, 2, Len(ConcatPartLookUp))

End Function

Этот код будет возвращать совпадения из столбца «Данные1» (Очень голубое небо. | Голубое небонавсегда.).Я ищу, чтобы соответствовать на Data1, но вернуть значения из Data2.Спасибо

1 Ответ

0 голосов
/ 27 марта 2019

Если у вас Office 365 Excel, вы можете использовать TEXTJOIN в качестве формулы массива: 

 =TEXTJOIN(",",TRUE,IF(ISNUMBER(SEARCH(D2,$A$2:$A$6)),$B$2:$B$6,""))

Будучи формулой массива, ее необходимо подтвердить с помощью Ctrl-Shift-Enter вместо Enter при выходе из режима редактирования.,

Если у вас нет Office 365, поместите этот код в модуль и затем используйте формулу, как описано выше: 

Function TEXTJOIN(delim As String, skipblank As Boolean, arr)
    Dim d As Long
    Dim c As Long
    Dim arr2()
    Dim t As Long, y As Long
    t = -1
    y = -1
    If TypeName(arr) = "Range" Then
        arr2 = arr.Value
    Else
        arr2 = arr
    End If
    On Error Resume Next
    t = UBound(arr2, 2)
    y = UBound(arr2, 1)
    On Error GoTo 0

    If t >= 0 And y >= 0 Then
        For c = LBound(arr2, 1) To UBound(arr2, 1)
            For d = LBound(arr2, 1) To UBound(arr2, 2)
                If arr2(c, d) <> "" Or Not skipblank Then
                    TEXTJOIN = TEXTJOIN & arr2(c, d) & delim
                End If
            Next d
        Next c
    Else
        For c = LBound(arr2) To UBound(arr2)
            If arr2(c) <> "" Or Not skipblank Then
                TEXTJOIN = TEXTJOIN & arr2(c) & delim
            End If
        Next c
    End If
    TEXTJOIN = Left(TEXTJOIN, Len(TEXTJOIN) - Len(delim))
End Function
...