Clojure.Зачем нужна обёртка lazy-seq?

Question

Зачем нужна обёртка ленивых минусов?Есть две функции с одинаковым результатом.

(defn seq1 [s]
  (lazy-seq
    (when-let [x (seq s)]
      (cons (first x) (seq1 (rest x))))))


(defn seq2 [s]
    (when-let [x (seq s)]
      (cons (first x) (seq2 (rest x)))))

В обоих случаях я получил один и тот же результат без чанкованных последовательностей.

repl.core=> (first (map println (seq1 (range 1000))))
0
nil
repl.core=> (first (map println (seq2 (range 1000))))
0
nil
repl.core=> (chunked-seq? (seq2 (range 1000)))
false
repl.core=> (chunked-seq? (seq1 (range 1000)))
false

Answer 1

Первый ленивый. Он только оценивает элементы последовательности по мере необходимости. Второй, однако, является строгим и проходит всю последовательность сразу. Это можно увидеть, добавив несколько println вызовов в каждый:

(defn seq1 [s]
  (lazy-seq
    (when-let [x (seq s)]
      (println "Seq1" (first x))
      (cons (first x) (seq1 (rest x))))))


(defn seq2 [s]
  (when-let [x (seq s)]
    (println "Seq2" (first x))
    (cons (first x) (seq2 (rest x)))))

(->> (range 10)
     (seq1)
     (take 5))
Seq1 0
Seq1 1
Seq1 2
Seq1 3
Seq1 4 ; Only iterated over what was asked for
=> (0 1 2 3 4) 

(->> (range 10)
     (seq2)
     (take 5))
Seq2 0
Seq2 1
Seq2 2
Seq2 3
Seq2 4
Seq2 5
Seq2 6
Seq2 7
Seq2 8
Seq2 9 ; Iterated over everything immediately
=> (0 1 2 3 4) 

Итак, чтобы ответить на вопрос, lazy-seq требуется только в том случае, если вы хотите, чтобы итерация последовательности происходила только по мере необходимости. Предпочитайте ленивые решения, если вам кажется, что вам не нужна вся последовательность, или последовательность бесконечна, или вы хотите упорядочить несколько преобразований, используя map или filter. Используйте строгое решение, если вам, вероятно, понадобится вся последовательность в какой-то момент и / или вам нужен быстрый произвольный доступ.