Оповещение, если в таблицах Power Point найдена пустая ячейка и в которой скользить с помощью vba

Question

Я должен найти и предупредить, что если в каждой таблице в power point найдена пустая ячейка.

Я нашел нижеприведенный код здесь , но он не работает и его не нужно искать для всей таблицы, а не для выбранной.

    Sub CheckTableCells()

    Dim oCell As Cell
    Dim oRow As Row
    Dim MyRange As Range

    For Each oRow In Selection.Tables(1).Rows
        For Each oCell In oRow.Cells
            If Selection.Text = Chr(13) & Chr(7) Then
                oCell.Select
                MsgBox oCell.RowIndex & " " & oCell.ColumnIndex & " is empty."
            End If
        Next oCell
    Next oRow

    End Sub

Пожалуйстакто-нибудь, помогите мне в этом.

Answer 1

Этот код проходит по каждому слайду в активной презентации и на каждом слайде проверяет, содержит ли каждая фигура на слайде таблицу, и, если это так, проверяет, является ли каждая ячейка пустой.Приветствия.

Sub CheckTableCells()

    Dim vSlide As Slide
    Dim vShape As Shape
    Dim vRow As Long
    Dim vColumn As Long

    For Each vSlide In Application.ActivePresentation.Slides
        For Each vShape In vSlide.Shapes
            If vShape.HasTable Then
                For vRow = 1 To vShape.Table.Rows.Count
                    For vColumn = 1 To vShape.Table.Columns.Count
                        If vShape.Table.Cell(vRow, vColumn).Shape.TextFrame.TextRange.Text = "" Then
                            MsgBox vSlide.Name & " Table: """ & vShape.Name & """ cell (" & vRow & "," & vColumn & ") is blank."
                        End If
                    Next
                Next
            End If
        Next
    Next

End Sub