XSLT Преобразование элементов XML в таблицу HTML с различным количеством строк - PullRequest
Новая
       1

XSLT Преобразование элементов XML в таблицу HTML с различным количеством строк

0 голосов
/ 17 мая 2019

Я использовал сопоставление с шаблоном, чтобы извлечь мои элементы и отобразить их в виде таблицы HTML.Однако у меня возникают проблемы с моим текущим выводом, так как количество дочерних элементов не равно.

В приведенном ниже XML у второго родителя больше дочерних элементов, чем у первого.Если я преобразую его в таблицу HTML, как я могу сделать строку 4 столбца 1 пустой?

Я намереваюсь сначала поместить все элементы в <cells>, затем оттуда я преобразую его в таблицу, используя мюнхенскую группировку (отдельный код из XSLT ниже).

XML: 

<?xml version="1.0" encoding="utf-8" ?>
<Table>
  <Parent>
    <Head>Header 1</Head>
    <Children>
      <Node>Node 1</Node>
      <Node>Node 2</Node>
      <Node>Node 3</Node>
    </Children>
  </Parent>
  <Parent>
    <Head>Header 2</Head>
    <Children>
      <Node>Node 4</Node>
      <Node>Node 5</Node>
      <Node>Node 6</Node>
      <Node>Node 7</Node>
    </Children>
  </Parent>
</Table>

XSLT: 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output omit-xml-declaration="yes" indent="yes"/>
  <xsl:strip-space elements="*"/>

    <xsl:template match="Table">
        <cells>
            <xsl:apply-templates select="Parent[1]" mode="parent">
                <xsl:with-param name="row" select="1"/>
                <xsl:with-param name="col" select="1"/>
            </xsl:apply-templates>  
        </cells>
    </xsl:template>

    <xsl:template match="Parent" mode="parent">
        <xsl:param name="row"/>
        <xsl:param name="col"/>

        <xsl:apply-templates select="Children/Node[1]" mode="child">
            <xsl:with-param name="row" select="$row"/>
            <xsl:with-param name="col" select="$col"/>
        </xsl:apply-templates>

        <xsl:apply-templates select="following-sibling::*[1]" mode="parent">
            <xsl:with-param name="row" select="$row"/>
            <xsl:with-param name="col" select="$col + 1"/>
        </xsl:apply-templates>
    </xsl:template>

    <xsl:template match="Node" mode="child">
        <xsl:param name="row"/>
        <xsl:param name="col"/>

        <cell row="{$row}" col="{$col}">
            <xsl:value-of select="."/>
        </cell>
        <xsl:apply-templates select="following-sibling::*[1]" mode="child">
            <xsl:with-param name="row" select="$row + 1"/>
            <xsl:with-param name="col" select="$col"/>
        </xsl:apply-templates>  
    </xsl:template>
</xsl:stylesheet>

Ожидаемый результат (ячейки): 

<cells>
   <cell row="1" col="1">Node 1</cell>
   <cell row="2" col="1">Node 2</cell>
   <cell row="3" col="1">Node 3</cell>
   <cell row="4" col="1"> </cell>
   <cell row="1" col="2">Node 4</cell>
   <cell row="2" col="2">Node 5</cell>
   <cell row="3" col="2">Node 6</cell>
   <cell row="4" col="2">Node 7</cell>
</cells>

Ожидаемая таблица HTML: 

<table border="1">
   <tr>
      <td>Node 1</td>
      <td>Node 4</td>
   </tr>
   <tr>
      <td>Node 2</td>
      <td>Node 5</td>
   </tr>
   <tr>
      <td>Node 3</td>
      <td>Node 6</td>
   </tr>
   <tr>
      <td> </td>
      <td>Node 7</td>
   </tr>
</table>

Ответы [ 2 ]

1 голос
/ 17 мая 2019

Я бы начал с определения родителя с наибольшим количеством детей.Затем для каждого родителя создайте ячейку для каждого дочернего элемента родительского элемента с наибольшим количеством дочерних элементов и заполните его значением соответствующего дочернего элемента текущего родительского элемента:

XSLT 1.0 

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:key name="parent-by-id" match="Parent" use="generate-id()" />

<xsl:template match="/Table">
    <!-- find the parent with most children -->
    <xsl:variable name="max-parent-id">
        <xsl:for-each select="Parent">
            <xsl:sort select="count(Children/Node)" data-type="number" order="descending"/>
            <xsl:if test="position()=1">
                <xsl:value-of select="generate-id()" />
            </xsl:if>
        </xsl:for-each>
    </xsl:variable>
    <!-- output -->
     <cells>
         <xsl:for-each select="Parent">
            <xsl:variable name="current-parent" select="." />
            <xsl:variable name="i" select="position()" />
            <xsl:for-each select="key('parent-by-id', $max-parent-id)/Children/Node">
                <xsl:variable name="j" select="position()" />
                <cell row="{$j}" col="{$i}">
                    <xsl:value-of select="$current-parent/Children/Node[$j]"/>
                </cell>
            </xsl:for-each>
        </xsl:for-each>
    </cells>
</xsl:template>

</xsl:stylesheet>

Добавлено:

Учитывая ожидаемый вывод HTML в отредактированном вопросе, вы можете изменить порядок операций на:

XSLT 1.0 

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="/Table">
    <xsl:variable name="all-parents" select="Parent" />
    <!-- find the parent with most children -->
    <xsl:for-each select="Parent">
        <xsl:sort select="count(Children/Node)" data-type="number" order="descending"/>
        <xsl:if test="position()=1">
            <!-- output -->
            <table border="1">
                <xsl:for-each select="Children/Node">
                    <xsl:variable name="i" select="position()" />
                    <tr>
                        <xsl:for-each select="$all-parents">
                            <td>
                                <xsl:value-of select="Children/Node[$i]" />
                            </td>
                        </xsl:for-each>
                    </tr>
                </xsl:for-each>
            </table>
        </xsl:if>
    </xsl:for-each>
</xsl:template>

</xsl:stylesheet>

и получите ожидаемый результат напрямую, без необходимости промежуточной ступени.

0 голосов
/ 17 мая 2019

Возможно, это не самый элегантный код, но я могу отобразить мой HTML, как и ожидалось. Если у вас есть предложения о том, как сделать этот код чище и эффективнее, пожалуйста, дайте мне знать. Спасибо! 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output omit-xml-declaration="yes" indent="yes"/>
  <xsl:strip-space elements="*"/>

    <xsl:template match="Table">
        <xsl:for-each select="Parent/Children">
             <xsl:sort select="count(Node)" data-type="number" order="descending"/>
             <xsl:if test="position() = 1">
                <cells>
                    <xsl:apply-templates select="../../Parent[1]" mode="parent">
                        <xsl:with-param name="row" select="1"/>
                        <xsl:with-param name="col" select="1"/>
                        <xsl:with-param name="max-rows" select="count(Node)"/>
                    </xsl:apply-templates>  
                </cells>
             </xsl:if>
        </xsl:for-each>
    </xsl:template>

    <xsl:template match="Parent" mode="parent">
        <xsl:param name="row"/>
        <xsl:param name="col"/>
        <xsl:param name="max-rows"/>

        <xsl:apply-templates select="Children/Node[1]" mode="child">
            <xsl:with-param name="row" select="$row"/>
            <xsl:with-param name="col" select="$col"/>
            <xsl:with-param name="max-rows" select="$max-rows"/>
        </xsl:apply-templates>

        <xsl:apply-templates select="following-sibling::*[1]" mode="parent">
            <xsl:with-param name="row" select="$row"/>
            <xsl:with-param name="col" select="$col + 1"/>
            <xsl:with-param name="max-rows" select="$max-rows"/>
        </xsl:apply-templates>
    </xsl:template>

    <xsl:template match="Node" mode="child">
        <xsl:param name="row"/>
        <xsl:param name="col"/>
        <xsl:param name="max-rows"/>

        <cell row="{$row}" col="{$col}">
            <xsl:value-of select="."/>
        </cell>
        <xsl:choose>
            <xsl:when test="following-sibling::*">
                <xsl:apply-templates select="following-sibling::*[1]" mode="child">
                    <xsl:with-param name="row" select="$row + 1"/>
                    <xsl:with-param name="col" select="$col"/>
                    <xsl:with-param name="max-rows" select="$max-rows"/>
                </xsl:apply-templates>
            </xsl:when>
            <xsl:otherwise>
                 <xsl:call-template name="Placeholder">
                    <xsl:with-param name="row" select="$row + 1"/>
                    <xsl:with-param name="col" select="$col"/>
                    <xsl:with-param name="max-rows" select="$max-rows"/>
                </xsl:call-template>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

    <xsl:template name='Placeholder'>
        <xsl:param name="row"/>
        <xsl:param name="col"/>
        <xsl:param name="max-rows"/>

        <xsl:if test="$row &lt;= $max-rows">
            <cell row="{$row}" col="{$col}">
            </cell>
            <xsl:call-template name="Placeholder">
                <xsl:with-param name="row" select="$row + 1"/>
                <xsl:with-param name="col" select="$col"/>
                <xsl:with-param name="max-rows" select="$max-rows"/>
            </xsl:call-template>
        </xsl:if>
    </xsl:template>
</xsl:stylesheet>
Добро пожаловать на сайт PullRequest, где вы можете задавать вопросы и получать ответы от других членов сообщества.

Нет похожих вопросов

...