Цикл или оператор для добавления разрыва строки в ячейках выбора, если он находится в определенной строке

Question

Надеюсь, что название имеет смысл.

У меня есть выбор ячеек, к которым нужно добавить разрыв строки, но только если эта ячейка находится в определенных столбцах (C, E и H).Выбор будет скопирован в Outlook, но я уже понял эту часть.Пока это все, что у меня есть:

Sub Mail_Selected_Changes()

    Dim rng As Range
    Dim OutApp As Object
    Dim OutMail As Object
    Dim StrBody As String
    Dim Signature As String

    Set rng = Nothing
    On Error Resume Next
    'Only the visible cells in the selection
    Set rng = Selection.SpecialCells(xlCellTypeVisible)
    'You can also use a fixed range if you want
    'Set rng = Sheets("YourSheet").Range("D4:D12").SpecialCells(xlCellTypeVisible)
    On Error GoTo 0

    If rng Is Nothing Then
        MsgBox "The selection is not a range or the sheet is protected" & _
               vbNewLine & "please correct and try again.", vbOKOnly
        Exit Sub
    End If

    With Application
        .EnableEvents = False
        .ScreenUpdating = False
    End With

    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)

    'Body of message
    StrBody = "Hey Demi," & "<br>" & _
              " " & "<br>" & _
              "Here is a list of changes:" & "<br><br><br>"

    'Signature
    Signature = " " & "<br>" & _
                " " & "<br>" & _
                "Thanks!" & "<br>" & _
                " " & "<br>" & _
                " " & "<br><br><br>"

    On Error Resume Next
    With OutMail
        .To = "Email Address"
        .CC = ""
        .BCC = ""
        .Subject = "Changes"
        .HTMLBody = StrBody & RangetoHTML(rng) & Signature
        .Display   'or use .Send

    End With
    On Error GoTo 0

    With Application
        .EnableEvents = True
        .ScreenUpdating = True
    End With

    Set OutMail = Nothing
    Set OutApp = Nothing
End Sub


Function RangetoHTML(rng As Range)

    Dim fso As Object
    Dim ts As Object
    Dim TempFile As String
    Dim TempWB As Workbook

    TempFile = Environ$("temp") & "\" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"

    'Copy the range and create a new workbook to past the data in
    rng.Copy
    Set TempWB = Workbooks.Add(1)
    With TempWB.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial xlPasteValues, , False, False
        .Cells(1).PasteSpecial xlPasteFormats, , False, False
        .Cells(1).Select
        Application.CutCopyMode = False
        On Error Resume Next
        .DrawingObjects.Visible = True
        .DrawingObjects.Delete
        On Error GoTo 0
    End With

    'Publish the sheet to a htm file
    With TempWB.PublishObjects.Add( _
         SourceType:=xlSourceRange, _
         Filename:=TempFile, _
         Sheet:=TempWB.Sheets(1).Name, _
         Source:=TempWB.Sheets(1).UsedRange.Address, _
         HtmlType:=xlHtmlStatic)
        .Publish (True)
    End With

    'Read all data from the htm file into RangetoHTML
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
    RangetoHTML = ts.readall
    ts.Close
    RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
                          "align=left x:publishsource=")

    'Close TempWB
    TempWB.Close savechanges:=False

    'Delete the htm file we used in this function
    Kill TempFile

    Set ts = Nothing
    Set fso = Nothing
    Set TempWB = Nothing
End Function    

В основном мне нужно включить это:

В это:

Я буду добавлять этот цикл или оператор для кода из Рон де Брейн

У меня естьпытался понять это уже несколько недель, но не могу.Любая помощь будет высоко ценится!

Хотя это не правильно, я думал что-то вроде:

If Selection.cell Is In columns(A,C,D)
     Then Selection.cell = vbCrLf & Selection.cell

Answer 1

IMO Я никогда не был поклонником этой пользовательской функции - если у вас все в порядке с решением со статическим диапазоном, то это сработает:

Option Explicit
Sub Mail_Selected_Changes()

    Dim OutApp As Object
    Dim OutMail As Object
    Dim StrBody As String
    Dim Signature As String
    Dim mybody As String
    Dim i As Long

    With Application
        .EnableEvents = False
        .ScreenUpdating = False
    End With

    For i = 2 To Cells(Rows.Count, 3).End(xlUp).Row
        mybody = mybody & Cells(i, 3).Value & "<br>" & _
                Cells(i, 5).Value & "<br>" & _
                Cells(i, 8).Value & " " & Cells(i, 9).Value & " " & Cells(i, 10).Value & " " & Cells(i, 11).Value & " " & Cells(i, 12).Value & _
                "<br><br>"
    Next i

    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)

    'Body of message
    StrBody = "Hey Demi," & "<br>" & _
              " " & "<br>" & _
              "Here is a list of changes:" & "<br><br>"

    'Signature
    Signature = " " & "<br>" & _
                " " & "<br>" & _
                "Thanks!" & "<br>" & _
                " " & "<br>" & _
                " " & "<br><br><br>"

    On Error Resume Next
    With OutMail
        .to = "Email Address"
        .CC = ""
        .BCC = ""
        .Subject = "Changes"
        .HTMLBody = StrBody & mybody & Signature
        .Display   'or use .Send

    End With
    On Error GoTo 0

    With Application
        .EnableEvents = True
        .ScreenUpdating = True
    End With

    Set OutMail = Nothing
    Set OutApp = Nothing
End Sub

Этот код превращает это:

В это:

Просто обратите внимание, что это делает новыйраздел для каждой строки в этом разделе (не то, что выделено).Это не будет работать, если ваш предел строки превышает предел символа строки VBA, который, я думаю, составляет 2 ГБ?