Использование курсора для обхода табличной переменной в SQL Server

Question

У меня есть параметр хранимой процедуры, который получает некоторые данные в формате

1/1/2018-2/1/2018,2/1/2018-3/1/2018,3/1/2018-4/1/2018,4/1/2018-5/1/2018,5/1/2018-6/1/2018,6/1/2018-7/1/2018,7/1/2018-8/1/2018,8/1/2018-9/1/2018,9/1/2018-10/1/2018,
10/1/2018-11/1/2018,11/1/2018-12/1/2018,12/1/2018-12/31/2018

У меня есть функция, которая разбивает данные на основе символа , и сохраняет результаты в табличную переменнуюкак показано здесь:

declare @SPlitDates table(ItemNumber int, Item nvarchar(max))

insert into @SPlitDates
    select * 
    from dbo.SPlitFunction(@RequestData, ',')

После этого мне нужно выполнить определенные операции с диапазоном данных, поэтому я использую курсоры для циклического перемещения по временной таблице, как показано ниже

DECLARE cur CURSOR FOR 
     SELECT Item 
     FROM @SPlitDates 
     ORDER BY ItemNumber

OPEN cur

FETCH NEXT FROM cur INTO @monthStart

WHILE @@FETCH_STATUS = 0 
BEGIN
     -- Some operation
END

Макс. данныеОчки, которые я получу во временной таблице, это диапазон дат за 12 месяцев.

Мой вопрос заключается в том, могу ли я использовать что-то еще, кроме курсоров, для повышения производительности, или не имеет значения, когда набор данных действительно такой маленький.

Спасибо

Редактировать- показать операцию внутри курсора

declare @SPlitDates table(ItemNumber int, Item nvarchar(max))

insert into @SPlitDates
    select * 
    from dbo.SPlitFunction(@RequestData, ',')

declare @SPlitDatesData table (ItemNumber varchar(100), Item nvarchar(max))
declare @SPlitDatesAvgData table(Code nvarchar(100), Val decimal(18,2))
declare @dataFilter as nvarchar(max),
        @SQL as nvarchar(max);

declare @monthStart nvarchar(100)
declare @count int

set @count = 0

--Declaring a cursor to loop through all the dates as defined in the requested quarter
DECLARE cur CURSOR FOR 
     SELECT Item 
     FROM @SPlitDates 
     ORDER BY ItemNumber

OPEN cur

FETCH NEXT FROM cur INTO @monthStart

WHILE @@FETCH_STATUS = 0 
BEGIN
    DECLARE @Period NVARCHAR(100)
    SET @Period = @monthStart

    INSERT INTO @SPlitDatesData
        --split the dates to get the start and the end dates
        SELECT * 
        FROM dbo.SPlitFunction(@Period, '-')

    DECLARE @PeriodStart NVARCHAR(100)
    DECLARE @PeriodEnd NVARCHAR(100)

    SET @PeriodStart = (SELECT Item FROM @SPlitDatesData WHERE ItemNumber = 1)
    SET @PeriodEnd = (SELECT Item FROM @SPlitDatesData WHERE ItemNumber = 2)

    DELETE FROM @SPlitDatesData

    --add the start and end dates to the filter
    SET @dataFilter = 'StatusDate between convert(datetime,('''+@PeriodStart+'''))  
    and DATEADD(dy, 1, convert(datetime,('''+@PeriodEnd+''')))'

    SET @count = @count +1;
    SET @SQL = 'INSERT INTO #BidAverageCycleCalculation (SortOrder, Code, Data)
                VALUES (@count,
    ''SL Payroll'',(select dbo.GetAverageCycleBetweenBids('''+@PeriodStart+''',
    '''+@PeriodEnd+''',''SL''))
     )'

    EXEC SP_ExecuteSQL @SQL, N'@count int', @count;

    SET @count = @count +1;
    SET @SQL = 'INSERT INTO #BidAverageCycleCalculation (SortOrder, Code, Data)
                VALUES (@count,
    ''GV Payroll'',(select dbo.GetAverageCycleBetweenBids('''+@PeriodStart+''',
    '''+@PeriodEnd+''',''GV''))
     )'

    EXEC SP_ExecuteSQL @SQL , N'@count int', @count;

    SET @count = @count +1;

    SET @SQL = 'Insert into #BidAverageCycleCalculation (SortOrder,Code,Data)
  Values (@count,
    ''Global Payroll'',(select dbo.GetAverageCycleBetweenBids('''+@PeriodStart+''',
    '''+@PeriodEnd+''',''GVS''))
     )'

    EXEC SP_ExecuteSQL @SQL, N'@count int', @count;

    SET @count = @count +1;

    SET @SQL = 'Insert into #BidAverageCycleCalculation (SortOrder,Code,Data)
  Values (@count,
    ''TimeHCM'',(select dbo.GetAverageCycleBetweenBids('''+@PeriodStart+''',
    '''+@PeriodEnd+''',''Time''))
     )' 

    EXEC SP_ExecuteSQL @SQL, N'@count int', @count;    

    delete from @SPlitDatesAVgData  

    FETCH NEXT FROM cur INTO @monthStart
END

CLOSE cur    
DEALLOCATE cur

Answer 1

Для этого используются две части - сначала преобразуйте строку в таблицу, а затем выполните массовые вставки в пункт назначения. Нет необходимости в курсорах.

** Прошу прощения за любые синтаксические ошибки, так как я делаю это без доступа к вашим фактическим таблицам или функциям, так что не могу проверить это, но вы поняли идею

declare @in varchar(max)
set @in= '1/1/2018-2/1/2018,2/1/2018-3/1/2018,3/1/2018-4/1/2018,4/1/2018-5/1/2018,5/1/2018-6/1/2018,6/1/2018-7/1/2018,7/1/2018-8/1/2018,8/1/2018-9/1/2018,9/1/2018-10/1/2018,10/1/2018-11/1/2018,11/1/2018-12/1/2018,12/1/2018-12/31/2018'

declare @xml xml;
set @xml= convert(xml,'<r><f>'+replace(replace(@in,',','</t></r><r><f>'),'-','</f><t>') +'</t></r>')

declare @t table(id int identity, f date, t date)
insert @t
select 
    Tbl.Col.value('f[1]', 'date') f, 
    Tbl.Col.value('t[1]', 'date') t
FROM  @xml.nodes('//r') Tbl(Col) 

select * from @t

declare @count int;
select @count=count(*) from @t

INSERT INTO #BidAverageCycleCalculation (SortOrder, Code, Data)
select id, 'SL Payroll',(select dbo.GetAverageCycleBetweenBids(f,t,'SL')) from @t

INSERT INTO #BidAverageCycleCalculation (SortOrder, Code, Data)
select id+@count,'GV Payroll',(select dbo.GetAverageCycleBetweenBids(f,t,'GV')) from @t

INSERT INTO #BidAverageCycleCalculation (SortOrder, Code, Data)
select id+@count*2,'Global Payroll',(select dbo.GetAverageCycleBetweenBids(f,t,'GVS')) from @t

INSERT INTO #BidAverageCycleCalculation (SortOrder, Code, Data)
select id+@count*3,'TimeHCM',(select dbo.GetAverageCycleBetweenBids(f,t,'Time')) from @t