Определение динамического типа для поля Char с переменной длиной - PullRequest
Новая
       19

Определение динамического типа для поля Char с переменной длиной

0 голосов
/ 09 апреля 2019

Для внутреннего использования мне нужно определить структурированный тип с одним из полей, представляющих собой char-поле с переменной длиной.

Примерно так (надеюсь, этот пример прояснит мою проблему): 

DATA: lv_type TYPE char7.
lv_type = 'char128'. "The actual length will be determined during execution of the program

TYPES: BEGIN OF ty_satzcounter,
       satza TYPE zedist,
       addit TYPE (lv_type), "<----- Something like this (obviously, it doesn't work like 
                             "       this, but I think it clarifies my question)
       menge TYPE int1,
       END OF ty_satzcounter.

DATA: lt_satzcounter TYPE TABLE OF ty_satzcounter,
      ls_satzcounter TYPE ty_satzcounter.
...
...

Ответы [ 2 ]

2 голосов
/ 09 апреля 2019

Этот тип динамической типизации невозможен, но для вашей цели, тип символа с динамической длиной, есть тип string: 

TYPES: satza TYPE zedist,
       addit TYPE string,
...
1 голос
/ 09 апреля 2019

Я абсолютно согласен с решением JozsefSzikszai, но для демонстрации дополнительной сложности динамических структур и таблиц, вот возможное решение в качестве примера: 

"your input
DATA(lv_charlength) = 128.
"or
DATA(lv_type) = 'CHAR128'.

DATA:
      lro_structdescr TYPE REF TO cl_abap_structdescr,
      lro_tabledescr  TYPE REF TO cl_abap_tabledescr,
      lro_datadescr   TYPE REF TO cl_abap_datadescr,
      lro_typedescr   TYPE REF TO cl_abap_typedescr,
      lt_component    TYPE abap_component_tab,
      ls_component    TYPE LINE OF abap_component_tab,
      lro_wa          TYPE REF TO data.

    FIELD-SYMBOLS: <fs_wa> TYPE any.
    FIELD-SYMBOLS: <fs_tab> TYPE table.


* determine components of structure -> lt_component    
    ls_component-name = 'SATZA'.
    ls_component-type ?= cl_abap_elemdescr=>describe_by_name( 'ZEDIST' ).
    APPEND ls_component TO lt_component.

    ls_component-name = 'ADDIT'.
    ls_component-type ?= cl_abap_elemdescr=>get_c( p_length = lv_charlength ).
    APPEND ls_component TO lt_component.

    "or
*   ls_component-name = 'ADDIT'.
*   ls_component-type ?= cl_abap_elemdescr=>describe_by_name( lv_type ).
*   APPEND ls_component TO lt_component.

    ls_component-name = 'MENGE'.
    ls_component-type ?= cl_abap_elemdescr=>describe_by_name( 'INT1' ).
    APPEND ls_component TO lt_component.

* get structure descriptor -> lro_STRUCTDESCR
    lro_structdescr ?= cl_abap_structdescr=>create( lt_component ).

* create work area of structure lro_STRUCTDESCR -> lro_WA
    CREATE DATA lro_wa TYPE HANDLE lro_structdescr.
*    ASSIGN lro_wa->* TO <fs_wa>. "work area/structure to use

    lro_datadescr ?= lro_structdescr.
    lro_tabledescr ?= cl_abap_tabledescr=>create( lro_datadescr ).

* Create dynmaic internal table
    CREATE DATA et_range_tab TYPE HANDLE lro_tabledescr.
*    ASSIGN et_range_tab->* TO <fs_tab>. "table to use
...