Перемещение элементов управления между компонентами Delphi

Question

Я пытаюсь создать невизуальный компонент Delphi, который может содержать некоторые визуальные компоненты.

Во время разработки я создаю собственный TPanel, чтобы я мог поместить в него свои визуальные компоненты, а затем я пытаюсь получить эти элементы управления из TPanel и сохранить их в другом компоненте.

Это моя пользовательская панель

  TDesignTimePanel = class(TPanel)
  private
    FPanel: TPanelDialogo;
  public
    constructor Create(AOwner: TComponent); override;
    destructor  Destroy; override;

    procedure GetChildren(Proc: TGetChildProc; Root: TComponent); override;
    function  GetChildOwner: TComponent; override;
  end

Метод GetChildren ничего не делает, так как я не хочу писать эту панель традиционным способом в файле DFM. Метод GetChildOwner возвращает TPanelDialogo, где я хочу сохранить визуальные элементы управления.

И это компонент, в котором я хочу сохранить элементы управления из TDesignTimePanel

  TPanelDialogo = class(TComponent)
  private
    FDesignPanel: TDesignTimePanel;
    procedure VolcarFrameEnLista();
  public
    constructor Create(AOwner: TComponent); override;
    destructor  Destroy; override;
    function  CrearPanel(AOwner: TComponent): TPanel;
    procedure GetChildren(Proc: TGetChildProc; Root: TComponent); override;
    function  GetChildOwner: TComponent; override;
  end;

Я создаю пользовательскую панель таким образом

function TPanelDialogo.CrearPanel(AOwner: TComponent): TPanel;
var
  i: integer;
  Componente : TControl;
begin
  if FDesignPanel = nil then
  begin
    FDesignPanel := TDesignTimePanel.Create(self);
    FDesignPanel.AsociarPanel( self );
  end;

  FDesignPanel.Name := Name + '_frame';
  FDesignPanel.Left := FX;
  // some other config
  FDesignPanel.Parent := Owner as TWinControl;

  FDesignPanel.Show;

  Result := FDesignPanel;
end;

Итак, мой метод GetChildren делает следующее, где VolcarFrameEnLista - это метод, в котором я беру элементы управления из объекта TDesignTimePanel и сохраняю их в TPanelDialogo (FListaComponentes - это TComponentList)

procedure TPanelDialogo.GetChildren(Proc: TGetChildProc; Root: TComponent);
var
  i: integer;
  OwnedComponent: TComponent;
begin
  if FDesignPanel <> nil then
  begin
    VolcarFrameEnLista();
    if Root = Self then
      for i := 0 to self.FListaComponentes.Count - 1 do
      begin
        OwnedComponent := FListaComponentes.Items[i];
        Proc(OwnedComponent);
      end;
  end;
end;

procedure TPanelDialogo.VolcarFrameEnLista( );
var
  i: integer;
  Componente: TControl;
begin
  for i := FDesignPanel.ControlCount - 1 downto 0 do
  begin
    Componente := FDesignPanel.Controls[i];
    if Pos( self.Name + '_', Componente.Name ) = 0 then
    begin
      Componente.Name := self.Name + '_' + Componente.Name;
    end;
    Componente.Parent := nil;
    if FListaComponentes.IndexOf(Componente) < 0 then
    begin
      FListaComponentes.Add( Componente );
    end;
  end;
end;

Я хочу, чтобы у моего DFM было что-то вроде этого:

object Form1: TForm1
  object PanelDialogo1: TPanelDialogo
    Left = 712
    // ...
    object PanelDialogo1_Label1: TLabel
      Left = 88
      // ..
    end
    object PanelDialogo1_Label2: TLabel
      Left = 40
      // ..
    end
  end
end

Но я получаю что-то вроде этого

object Form1: TForm1
  object PanelDialogo1: TPanelDialogo
    Left = 712
    // ...
  end
  object PanelDialogo1_Label1: TLabel
    Left = 88
    // ..
  end
  object PanelDialogo1_Label2: TLabel
    Left = 40
    // ..
  end
end

Что я должен сделать, чтобы TPanelDialogo стал «владельцем» компонентов, нарисованных на TDesignTimePanel.

Answer 1

Мне наконец удалось решить мою проблему.

Мне нужно было переписать метод GetChildren в моем родительском объекте, чтобы я мог получить все элементы временной панели в TComponentList.Затем я записываю каждый элемент этого списка в файл DFM.

При чтении файла DFM я получаю эти элементы в свойстве TPanelDialogo.Components, но хранение этих элементов вызывает у меня проблемы из-за дублированного элемента управления из Delphi.среда.Итак, в методе Loaded я снова поместил все эти компоненты в TComponentList.

Вот код

type

  TPanelDialogo = class;

  // especialización de Frame para pruebas
  TDesignTimePanel = class(TPanel)
  public
    constructor Create(AOwner: TComponent); override;
    destructor  Destroy; override;
    procedure GetChildren(Proc: TGetChildProc; Root: TComponent); override;
  end;

  TPanelDialogo = class(TComponent)
  private
    FDesignPanel: TDesignTimePanel;
    FGENPant: TGENPant;

    FListaComponentes : TComponentList;

    procedure CerrarPanel;
    procedure VolcarFrameEnLista();
  public
    constructor Create(AOwner: TComponent); override;
    destructor Destroy; override;

    function CrearPanel(AOwner: TComponent): TPanel;
    procedure GetChildren(Proc: TGetChildProc; Root: TComponent); override;
    function GetChildOwner: TComponent; override;
    procedure Loaded; override;

  published
    property ListaComponentes: TComponentList read FListaComponentes;
  end;

procedure Register;

implementation

uses
  ToolsApi,
  SysUtils, Graphics,
  Dialogs, StdCtrls,
  ComponentesGEN;

  { TDesignTimePanel }

constructor TDesignTimePanel.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);
end;

destructor TDesignTimePanel.Destroy;
begin
  inherited;
end;

procedure TDesignTimePanel.GetChildren(Proc: TGetChildProc; Root: TComponent);
begin
  exit;
end;

constructor TPanelDialogo.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);

  FListaComponentes := TComponentList.Create(True);
end;

destructor TPanelDialogo.Destroy;
begin
  inherited Destroy;
end;

procedure TPanelDialogo.VolcarFrameEnLista( );
var
  i: integer;
  Componente: TControl;
  OwnerName, ParentName: string;
begin
  // recorrer el frame y rescatar sus componentes
  if FDesignPanel = nil then
    exit;
  for i := FDesignPanel.ControlCount - 1 downto 0 do
  begin
    Componente := FDesignPanel.Controls[i];
    if Componente.Owner <> nil then
      OwnerName := Componente.Owner.Name;
    if Componente.Parent <> nil then
      ParentName := Componente.Parent.Name;
    if Pos( self.Name + '_', Componente.Name ) = 0 then
    begin
      Componente.Name := self.Name + '_' + Componente.Name;
    end;
    if FListaComponentes.IndexOf(Componente) < 0 then
    begin
      FListaComponentes.Add( Componente );
    end;
  end;
end;

procedure TPanelDialogo.CerrarPanel;
begin
  if FDesignPanel = nil then Exit;

  FDesignPanel.Visible := false;
end;

function TPanelDialogo.GetChildOwner: TComponent;
begin
  Result := self;
end;

procedure TPanelDialogo.GetChildren(Proc: TGetChildProc; Root: TComponent);
var
  i: integer;
  OwnedComponent: TComponent;
begin
  if FDesignPanel <> nil then
  begin
    VolcarFrameEnLista();
    for i := 0 to self.FListaComponentes.Count - 1 do
    begin
      OwnedComponent := FListaComponentes.Items[i];
      Proc(OwnedComponent);
    end;
  end;
end;

function TPanelDialogo.CrearPanel(AOwner: TComponent): TPanel;
var
  i: integer;
  Componente : TControl;
begin
  if FDesignPanel = nil then
  begin
    FDesignPanel := TDesignTimePanel.Create(self);
    FDesignPanel.AsociarPanel( self );
  end;

  FDesignPanel.Name := Name + '_frame';
  // ...

  try
    for i := 0 to FListaComponentes.Count - 1 do
    begin
      Componente := FListaComponentes.Items[i] as TControl;
      Componente.Parent := FDesignPanel;
    end;
  finally
    FDesignPanel.Parent := Owner as TWinControl;
  end;

  FDesignPanel.Visible := true;

  Result := FDesignPanel;
end;

procedure TPanelDialogo.Loaded;
var
  i: integer;
  OwnedComponent: TComponent;
begin
  inherited;  
  for i := 0 to self.ComponentCount - 1 do
  begin
    OwnedComponent := self.Components[i];
    self.FListaComponentes.Add(OwnedComponent);
  end;  
  for i := self.ComponentCount - 1 downto 0 do
  begin
    OwnedComponent := self.Components[i];
    self.RemoveComponent(OwnedComponent);
  end;
  self.FLoaded := true;
end;

Это то, что показано во время разработки:

А это DFM вида

object Form1: TForm1
  ...
  object PanelDialogo1: TPanelDialogo
    ...
    object PanelDialogo1_Label2: TLabel
      Caption = 'Another label right here'
    end
    object PanelDialogo1_Label1: TLabel
      Caption = 'A label in the top of the panel'
    end
    object PanelDialogo1_Edit1: TEdit
      Text = 'Write something here...'
    end
    object PanelDialogo1_Panel1: TPanel
      object PanelDialogo1_Button1: TButton
        Caption = 'OK'
      end
    end
    object PanelDialogo1_Label3: TLabel
      Caption = 'Some label just here'
    end
  end
end