SAS - создание индикаторных переменных

Question

Я использую SAS и хотел бы создать переменную индикатора.

Данные, которые у меня есть, такие (ДАННЫЕ, КОТОРЫЕ Я ИМЕЮ):

, и я хочу изменить это на (ДАННЫЕ, КОТОРЫЕ Я ХОЧУ):

У меня фиксированное общее количествовремя, которое я хочу использовать, и время начала имеет двойное значение времени (в этом примере c1 и c2 оба начались в момент 3).Хотя пример, который я использую, небольшой с 5 именами и 12 значениями времени, фактические данные очень велики (около 40 000 имен и 100 000 значений времени - поэтому я хочу получить матрицу с 100 000 x 400 000).

Может ли кто-нибудь предоставить какие-либо советы / решения о том, как с этим справиться?

Answer 1

40 тыс. Переменных - это много. Будет интересно посмотреть, насколько хорошо это масштабируется. Как вы определяете время остановки?

data have;
    input starttime name :$32.;
    retain one 1;
    cards;
1 varx
3 c1
3 c2
5 c3x
10 c4
11 c5
;;;;
   run;
proc print;
   run;
proc transpose data=have out=have2(drop=_name_ rename=(starttime=time));
   by starttime;
   id name;
   var one;
   run;
data time;
   if 0 then set have2(drop=time);
   array _n[*] _all_;
   retain _n 0;
   do time=.,1 to 12;
      output;
      call missing(of _n[*]);
      end;
   run;
data want0 / view=want0;
   merge time have2;
   by time;
   retain dummy '1';
   run;
data want;
   length time 8;
   update want0(obs=0) want0;
   by dummy;
   if not missing(time);
   output;
   drop dummy;
   run;
proc print;
   run;

Answer 2

Я думаю, что код ниже будет работать:

%macro answer_macro(data_in, data_out);

/* Deduplication of initial dataset just to assure that every variable has a unique starting time*/
proc sort data=&data_in. out=data_have_nodup; by name starttime; run;
proc sort data=data_have_nodup nodupkey; by name; run;

/*Getting min and max starttime values - here I am assuming that there is only integer values form starttime*/
proc sql noprint;
    select min(starttime)
            ,max(starttime) 
    into :min_starttime /*not used. Use this (and change the loop on the next dataset) to start the time variable from the value where the first variable starts*/
        ,:max_starttime
    from data_have_nodup
;quit;

/*Getting all pairs of name/starttime*/
proc sql noprint;
    select name
            ,starttime
    into :name1 - :name1000000
        ,:time1 - :time1000000
    from data_have_nodup
;quit;

/*Getting total number of variables*/
proc sql noprint;
    select count(*) into :nvars
    from data_have_nodup
;quit;

/* Creating dataset with possible start values */
/*I'm not sure this step could be done with a single datastep, but I don't have SAS 
on my PC to make tests, so I used the method below*/

data &data_out.;
    do i = 1 to &max_starttime. + 1;
        time = i; output;
    end;
    drop i;
run;

data &data_out.;
    set &data_out.;
    %do i = 1 %to &nvars.;
        if time >= &&time&i then &&name&i = 1;
        else &&name&i = 0;
    %end;
run;

%mend answer_macro;

К сожалению, на моем компьютере сейчас нет SAS, поэтому я не могу подтвердить, что код работает. Но даже если это не так, вы можете использовать логику в этом.

Answer 3

Это будет работать. Может быть более простое решение, которое делает все это за один шаг данных. Мой шаг данных создает пошаговые результаты, которые нужно свернуть, что я делаю суммированием в сортировке / средних.

data have;
    input starttime name $;
    datalines;
3 c1
3 c2
5 c3
10 c4
11 c5
;
run;

data want(drop=starttime name);
    set have;
    array cols (*) c1-c5;
    do time=1 to 100;
        if starttime < time then cols(_N_)=1;
        else cols(_N_)=0;
        output;
    end;
run;

proc sort data=want;
    by time;
proc means data=want noprint;
    by time;
    var _numeric_;
    output out=want2(drop=_type_ _freq_) sum=;
run;

Я не рекомендую вам делать это таким образом. Вы не предоставили достаточно информации, чтобы сообщить нам, почему вы хотите матрицу такого размера. У вас могут возникнуть проблемы с обработкой, чтобы запустить его.

В строке do time=1 to 100 вы можете изменить это значение на 100000 или любую другую длину.