Как получить CSS-стиль переполнения текста в фреймворке робота - PullRequest
Новая
       6

Как получить CSS-стиль переполнения текста в фреймворке робота

0 голосов
/ 26 октября 2018

Как получить стиль CSS переполнение текста в каркасе робота.Для проверки текста с многоточием. 

<td _ngcontent-c5="" class="fontStyle" data-placement="top" title="123456789123456789qwertyuiasdfghjklzxcvbnmasdfghjkqwertyuiasdfghjkzxcvbnmertyui"> 123456789123456789qwertyuiasdfghjklzxcvbnmasdfghjkqwertyuiasdfghjkzxcvbnmertyui </td>

Ответы [ 2 ]

0 голосов
/ 26 октября 2018

Получение значения свойства CSS не поддерживается в SeleniumLibrary для Robot Framework. Однако в модуле Selenium Python есть метод с именем value_of_css_property, который делает именно это.

Для вызова метода элемента можно использовать стандартное ключевое слово Call Method для любой переменной или объекта робота. В приведенном ниже примере я создал собственное ключевое слово и несколько примеров, используя главную страницу Google. Они должны быть легко изменены для ваших целей. 

*** Settings ***
Library    SeleniumLibrary

Suite Teardown    Close All Browsers

*** Test Cases ***
TC
    Open Browser    http://www.google.com    Chrome

    # a CSS property from the element.
    ${element_prop}=    Get CSS Property Value    id=SIvCob    line-height
    Should Be Equal As Strings    ${element_prop}    28px

    # a CSS property inherited from the <body> tag.
    ${body_prop}=    Get CSS Property Value    id=SIvCob    font-family
    Should Be Equal As Strings    ${body_prop}    arial, sans-serif

*** Keywords ***
Get CSS Property Value
    [Documentation]
    ...    Get the CSS property value of an Element.
    ...    
    ...    This keyword retrieves the CSS property value of an element. The element
    ...    is retrieved using the locator.
    ...    
    ...    Arguments:
    ...    - locator           (string)    any Selenium Library supported locator xpath/css/id etc.
    ...    - property_name     (string)    the name of the css property for which the value is returned.
    ...    
    ...    Returns             (string)    returns the string value of the given css attribute or fails.
    ...        
    [Arguments]    ${locator}    ${attribute name}
    ${css}=         Get WebElement    ${locator}
    ${prop_val}=    Call Method       ${css}    value_of_css_property    ${attribute name}
    [Return]     ${prop_val}
0 голосов
/ 26 октября 2018

в каркасе робота, чтобы получить текст, который вы можете использовать, это будет хранить текст в переменной data

${data}    Get Text    xpath=*//td[@class='fontStyle' and @data-placement='top']

, что даст вам data переменную как 123456789123456789qwertyuiasdfghjklzxcvbnmasdfghjkqwertyuiasdfghjkzxcvbnmertyui

дляподтверждение вы можете использовать

для частичного совпадения: 

Element Should Contain    locator    text_should_check_with

для точного совпадения: 

Element Text Should Be    locator    text_should_check_with
Добро пожаловать на сайт PullRequest, где вы можете задавать вопросы и получать ответы от других членов сообщества.

Нет похожих вопросов

...