Создайте задание SQL Server автоматически - PullRequest
Новая
       47

Создайте задание SQL Server автоматически

3 голосов
/ 01 августа 2009

Я пишу сценарии развертывания SQL Server, которые автоматически создают задание SQL Server на определенном сервере / экземпляре SQL Server. Я обнаружил, что могу извлечь оператор SQL, который можно использовать для автоматического создания задания SQL Server, используя сценарий as => Create To.

Моя путаница заключается в том, что я считаю, что имя базы данных и имя учетной записи владельца жестко заданы в сгенерированных сценариях sql. Когда я использую sqlcmd для выполнения сценариев sql на другом компьютере для выполнения развертывания, имя базы данных и имя учетной записи владельца могут отличаться, поэтому мне нужен способ передачи имени базы данных и имени учетной записи владельца в сценарий создания задания SQL Server и разрешить сценарию использовать предоставленное имя базы данных и имя учетной записи владельца (кроме жестко заданных).

Есть идеи, как это сделать?

Ответы [ 5 ]

4 голосов
/ 01 августа 2009

Вам потребуется динамически создать сценарий задания и затем выполнить его. Вы можете попробовать что-то вроде следующего или изменить это на сохраненный процесс с входными параметрами для владельца задания и имени базы данных. 

DECLARE @JobName VARCHAR(20)  --Job Name
DECLARE @Owner VARCHAR(200)   --Job Owner
DECLARE @DBName VARCHAR(200)  --Database Name
DECLARE @JobCode VARCHAR(4000) --Create Statement for Job
SET @JobName = 'Test2'
SET @Owner = 'BrianD'
SET @DBName = 'master'
SET @JobCode = 'USE msdb
GO
BEGIN TRANSACTION
DECLARE @ReturnCode INT
SELECT @ReturnCode = 0
IF NOT EXISTS (SELECT name FROM msdb.dbo.syscategories WHERE name=N''[Uncategorized (Local)]'' AND category_class=1)
BEGIN
EXEC @ReturnCode = msdb.dbo.sp_add_category @class=N''JOB'', @type=N''LOCAL'', @name=N''[Uncategorized (Local)]''
IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback
END
DECLARE @jobId BINARY(16)
EXEC @ReturnCode =  msdb.dbo.sp_add_job @job_name=N''' + @JobName + ''', 
        @enabled=1, 
        @notify_level_eventlog=0, 
        @notify_level_email=0, 
        @notify_level_netsend=0, 
        @notify_level_page=0, 
        @delete_level=0, 
        @description=N''No description available.'', 
        @category_name=N''[Uncategorized (Local)]'', 
        @owner_login_name=N''' + @Owner + ''', @job_id = @jobId OUTPUT
IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback
EXEC @ReturnCode = msdb.dbo.sp_add_jobstep @job_id=@jobId, @step_name=N''Version and Prod Level'', 
        @step_id=1, 
        @cmdexec_success_code=0, 
        @on_success_action=1, 
        @on_success_step_id=0, 
        @on_fail_action=2, 
        @on_fail_step_id=0, 
        @retry_attempts=0, 
        @retry_interval=0, 
        @os_run_priority=0, @subsystem=N''TSQL'', 
        @command=N''select SERVERPROPERTY(''''productversion''''), SERVERPROPERTY(''''productlevel'''')'', 
        @database_name=N''' + @DBName + ''', 
        @flags=0
IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback
EXEC @ReturnCode = msdb.dbo.sp_update_job @job_id = @jobId, @start_step_id = 1
IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback
EXEC @ReturnCode = msdb.dbo.sp_add_jobserver @job_id = @jobId, @server_name = N''(local)''
IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback
COMMIT TRANSACTION
GOTO EndSave
QuitWithRollback:
    IF (@@TRANCOUNT > 0) ROLLBACK TRANSACTION
EndSave:
GO'
Exec (@JobCode)

Надеюсь, это поможет вам двигаться в правильном направлении. Если вам нужна дополнительная помощь, дайте мне знать.

3 голосов
/ 02 апреля 2012

Используя пример из BrainD, я хотел бы отметить, что его идея использования переменных просто прекрасна, однако передача их хранимым процедурам с использованием динамического SQL, безусловно, не является правильным подходом. Вместо этого используйте параметры хранимых процедур, чтобы напрямую передать переменные туда, где они нужны. 

DECLARE @JobName VARCHAR(20)  --Job Name
DECLARE @Owner VARCHAR(200)   --Job Owner
DECLARE @DBName VARCHAR(200)  --Database Name
DECLARE @JobCode VARCHAR(4000) --Create Statement for Job
SET @JobName = 'Test2'
SET @Owner = 'BrianD'
SET @DBName = 'master'

BEGIN TRANSACTION
DECLARE @ReturnCode INT
SELECT @ReturnCode = 0
IF NOT EXISTS (SELECT name FROM msdb.dbo.syscategories WHERE name=N'[Uncategorized (Local)]' AND category_class=1)
BEGIN
EXEC @ReturnCode = msdb.dbo.sp_add_category @class=N'JOB', @type=N'LOCAL', @name=N'[Uncategorized (Local)]'
IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback
END
DECLARE @jobId BINARY(16)
EXEC @ReturnCode =  msdb.dbo.sp_add_job @job_name= @JobName, 
        @enabled=1, 
        @notify_level_eventlog=0, 
        @notify_level_email=0, 
        @notify_level_netsend=0, 
        @notify_level_page=0, 
        @delete_level=0, 
        @description=N'No description available.', 
        @category_name=N'[Uncategorized (Local)]', 
        @owner_login_name= @Owner, 
        @job_id = @jobId OUTPUT
IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback
EXEC @ReturnCode = msdb.dbo.sp_add_jobstep @job_id=@jobId, @step_name=N'Version and Prod Level', 
        @step_id=1, 
        @cmdexec_success_code=0, 
        @on_success_action=1, 
        @on_success_step_id=0, 
        @on_fail_action=2, 
        @on_fail_step_id=0, 
        @retry_attempts=0, 
        @retry_interval=0, 
        @os_run_priority=0, @subsystem=N'TSQL', 
        @command=N'select SERVERPROPERTY(''productversion''), SERVERPROPERTY(''productlevel'')', 
        @database_name=@DBName, 
        @flags=0
IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback
EXEC @ReturnCode = msdb.dbo.sp_update_job @job_id = @jobId, @start_step_id = 1
IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback
EXEC @ReturnCode = msdb.dbo.sp_add_jobserver @job_id = @jobId, @server_name = N'(local)'
IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback
COMMIT TRANSACTION
GOTO EndSave
QuitWithRollback:
    IF (@@TRANCOUNT > 0) ROLLBACK TRANSACTION
EndSave:
GO
1 голос
/ 22 ноября 2012

Сегодня я столкнулся с той же проблемой, и как я ее решаю, это так просто. Сделайте следующее

  1. Создать сохраненный процесс, который создает задание с параметром @serverName nvarchar (128) 

    Create Proc CreateAJob(@serverName nvarchar(128))

  2. Теперь просто, вы можете получить имя сервера с помощью следующего 

    Declare @serverName nvarchar(128)
SELECT @servername=@@SERVERNAME

  3. Выполните сохраненный процесс для создания вашей работы 

    EXEC CreateJob @serverName

Вот и все.

Я использую проект Visual Studio DB и выполнил шаги 2 и 3 в сценарии после развертывания

1 голос
/ 02 августа 2009

Далее к ответу BrianD выше, вы можете определить переменные (на самом деле больше похоже на макросы препроцессора, чем переменные) на уровне sqlcmd; они заключены в круглые скобки с начальным знаком $: 

SET @JobName = '$(JobName)'
SET @Owner = '$(Owner)'

Это позволяет передавать информацию о командной строке в sqlcmd с ключом -v: 

sqlcmd -... -i create_jobs.sql -v JobName=Job1 -v Owner=BrianD
0 голосов
/ 27 ноября 2012

Мне даже стало лучше ... Создайте хранимую процедуру без параметра и внутри хранимой процедуры сделайте: 

   Declare @serverName nvarchar(128)
   SELECT @servername=@@SERVERNAME

Затем присвойте @servername параметру server_name в sp_add_jobserver, как показано ниже: 

msdb.dbo.sp_add_jobserver @job_id = @jobId, @server_name =@serverName

Чтобы создать хранимый процесс, который создает задание sql, сначала создайте его с помощью студии управления sql, а затем щелкните правой кнопкой мыши задание и выполните удаление и создание.

...