Перья Huzzah MQTT - PullRequest
Новая
       16

Перья Huzzah MQTT

0 голосов
/ 23 июня 2018

Я пытаюсь подключить свою Feather Huzzah к локальному серверу MQTT, но программа продолжает взрываться и генерирует трассировку стека. Когда я пытаюсь декодировать трассировку стека, она просто пуста, чаще я получаю только часть трассировки стека. Вот код, который я выполняю, большая часть которого очень похожа на пример кода клиента pub / sub для Arduino. Я пытался стереть вспышку на устройстве, но это не помогло.

Даже странно, что это сработало один раз, но как только я попробовал снова, добавив обратный вызов, код перестал работать и взорвался. Если я попытаюсь удалить обратный вызов, ничего не изменится. Я попытался удалить большую часть кода, чтобы посмотреть, смогу ли я получить согласованное соединение с MQTT, но это тоже не работает. Сервер MQTT - это последняя версия Mosquitto из Ubuntu 18.04. 

#include <ESP8266WiFi.h>
#include <ArduinoJson.h>
#include <NTPClient.h>
#include <WiFiUdp.h>
#include <PubSubClient.h>

const char* ssid = "xxxxxxxx";
const char* password = "xxxxxxxxx";
const int hallPin = 14;
const int ledPin = 0;
const char* mqtt_server = "mosquitto.localdomain";
long lastMsg = 0;
char msg[100];
int value = 0;
int hallState = 0;

WiFiClient espClient;
PubSubClient client(espClient);
WiFiUDP ntpUDP;

// By default 'time.nist.gov' is used with 60 seconds update interval and
// no offset
NTPClient timeClient(ntpUDP);

// Setup and connect to the wifi
void setup_wifi() {
  delay(100);
  Serial.print("Connecting to: ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("Wifi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
  Serial.println("Gateway: ");
  Serial.println(WiFi.gatewayIP());
}

//Reconnect to the MQTT broker
void reconnect() {
  // Loop until we're reconnected
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    // Create a random client ID
    String clientId = "ESP8266Client-";
    clientId += String(random(0xffff), HEX);
    // Attempt to connect
    if (client.connect(clientId.c_str())) {
      Serial.println("connected");
      // Once connected, publish an announcement...
      client.publish("/homeassistant/devices/doorbell", "hello world");
      // ... and resubscribe
      client.subscribe("/homeassistant/doorbell/receiver");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      // Wait 5 seconds before retrying
      delay(5000);
    }
  }
}

//Process messages incoming from the broker
void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print("Message arrived [");
  Serial.print(topic);
  Serial.print("] ");
  for (int i = 0; i < length; i++) {
    Serial.print((char)payload[i]);
  }
}

void setup() {
  pinMode(ledPin, OUTPUT);
  pinMode(hallPin, INPUT);
  Serial.begin(115200);
  setup_wifi();
  timeClient.begin();
  client.setServer(mqtt_server, 1883);
  client.setCallback(callback);
}

void loop() {
  if (WiFi.status() != WL_CONNECTED) {
    setup_wifi();
  }
  if (!client.connected()) {
    reconnect();
  }
  hallState = digitalRead(hallPin);
  if (hallState == LOW) {
    digitalWrite(ledPin, HIGH);
    generateAndSendMessage(); 
    delay(1000); //Add in a delay so it doesn't send messages extremely rapidly
  } else {
    digitalWrite(ledPin, LOW);
  }
}

void generateAndSendMessage() {
  timeClient.update();
  StaticJsonBuffer<100> jsonBuffer;
  JsonObject& root = jsonBuffer.createObject();
  root["sensor"] = "doorbell";
  root["time"] = timeClient.getEpochTime();
  root["value"] = 1;
  root.printTo(msg);
  Serial.println(msg);
  client.publish("/homeassistant/devices/doorbell", msg);
}

1 Ответ

0 голосов
/ 24 июня 2018

Глядя на функцию generateAndSendMessage, я полагаю, что у вас возникла проблема из-за размера буфера MQTT.

По умолчанию для буфера MQTT установлено значение 128 байтов.Это включает в себя длину имени канала вместе с сообщением.

Длина вашего канала составляет 32 байта, а размер буфера json, который вы использовали для создания сообщения, составляет 100 байтов.Таким образом, вы можете просто превысить 128-байтную метку.

Просто объявите это перед включением PubSubClient.h 

#define MQTT_MAX_PACKET_SIZE  200

Этот макрос определяет размер буфера PubSubClient до 200. Вы можете изменитьэто то, что, как вы считаете, требуется.

Надеюсь, это поможет.

...